Sources/Lexikon/Spannungs-Dehnungs-Beziehung (Stress-Strain-Relation)

Allgemeines Werkstoffgesetzt (3D)

Der Zusammenhang zwischen Dehnung un Spannung für isotropes, linear-elastisches Werkstoffverhalten wird durch

$\underset{\_}{\sigma }=\underset{\_}{\underset{\_}{E}}\cdot \underset{\_}{\epsilon }$

beschrieben. In Komponenten-Schreibweise ist dies

$\left[\begin{array}{c}{\sigma }_{xx}\\ {\sigma }_{yy}\\ {\sigma }_{zz}\\ {\sigma }_{yz}\\ {\sigma }_{xz}\\ {\sigma }_{xy}\end{array}\right]=\left[\begin{array}{cccccc}2\mu +\lambda & \lambda & \lambda & 0& 0& 0\\ \lambda & 2\mu +\lambda & \lambda & 0& 0& 0\\ \lambda & \lambda & 2\mu +\lambda & 0& 0& 0\\ 0& 0& 0& 2\mu & 0& 0\\ 0& 0& 0& 0& 2\mu & 0\\ 0& 0& 0& 0& 0& 2\mu \end{array}\right]\left[\begin{array}{c}{\epsilon }_{xx}\\ {\epsilon }_{yy}\\ {\epsilon }_{zz}\\ {\epsilon }_{yz}\\ {\epsilon }_{xz}\\ {\epsilon }_{xy}\end{array}\right]$,

wobei λ und μ die Lamé'schen Konstanten sind und zum Elastizitäts-Modul E und der Querkontraktion ν folgende Beziehung haben:

$\begin{array}{l}\lambda =\frac{E\nu }{(1+\nu )(1-2\nu )}\\ \mu =\frac{E}{2(1+\nu )}\end{array}$

/* Maxima */
/* version 5.38.1 */
/* general strain-displacement relation (sdr)*/
declare("σ", alphabetic);
declare("ε", alphabetic);

params: [%lambda=E*nu/((1+nu)*(1-2*nu)), mu=E/(2*(1+nu))];

sdr[3]: E = 2*mu*diagmatrix (6, 1) + 
            %lambda*matrix([1,1,1,0,0,0],
                           [1,1,1,0,0,0],
                           [1,1,1,0,0,0],
                           [0,0,0,0,0,0],
                           [0,0,0,0,0,0],
                           [0,0,0,0,0,0]);

σ : matrix([  sigma[xx]],[  sigma[yy]],[  sigma[zz]],[  sigma[yz]],[  sigma[xz]],[  sigma[xy]]);
ε : matrix([epsilon[xx]],[epsilon[yy]],[epsilon[zz]],[epsilon[yz]],[epsilon[xz]],[epsilon[xy]]);
print(σ," = ", subst(sdr[3],E),"∙",ε)$

Ebener Spannugnszustand

Alle anderen Werkstoff-Gesetze lassen sich daraus ableiten, z.B. für den ebenen Spannungszustand mit

${\sigma }_{zz}=0,{\sigma }_{xz}=0,{\sigma }_{yz}=0$

erhalten wir

${\sigma }_{{x}{x}}=\frac{2\lambda \mu {ϵ}_{{y}{y}}+(4{\mu }^2+4\lambda \mu ){ϵ}_{{x}{x}}}{2\mu +\lambda },{\sigma }_{{y}{y}}=\frac{(4{\mu }^2+4\lambda \mu ){ϵ}_{{y}{y}}+2\lambda \mu {ϵ}_{{x}{x}}}{2\mu +\lambda },{\sigma }_{{x}{y}}=2\mu {ϵ}_{{x}{y}},{ϵ}_{{z}{z}}=-\frac{\lambda {ϵ}_{{y}{y}}+\lambda {ϵ}_{{x}{x}}}{2\mu +\lambda },{ϵ}_{{y}{z}}=0,{ϵ}_{{x}{z}}=0$

In Matrixschreibweise erhalten wir

$\left(\begin{array}{c}{\sigma }_{xx}\\ {\sigma }_{yy}\\ {\sigma }_{xy}\end{array}\right)=\left(\begin{array}{ccc}\frac{4{\mu }^2+4\lambda \mu }{2\mu +\lambda }& \frac{2\lambda \mu }{2\mu +\lambda }& 0\\ \frac{2\lambda \mu }{2\mu +\lambda }& \frac{4{\mu }^2+4\lambda \mu }{2\mu +\lambda }& 0\\ 0& 0& 2\mu \end{array}\right)\cdot \left(\begin{array}{c}{\epsilon }_{xx}\\ {\epsilon }_{yy}\\ {\epsilon }_{xy}\end{array}\right)$

bzw mit E und ν

$\left(\begin{array}{c}{\sigma }_{xx}\\ {\sigma }_{yy}\\ {\sigma }_{xy}\end{array}\right)=\left(\begin{array}{ccc}\frac{E}{1-{\nu }^2}& \frac{E\nu }{1-{\nu }^2}& 0\\ \frac{E\nu }{1-{\nu }^2}& \frac{E}{1-{\nu }^2}& 0\\ 0& 0& \frac{E}{\nu +1}\end{array}\right)\cdot \left(\begin{array}{c}{\epsilon }_{xx}\\ {\epsilon }_{yy}\\ {\epsilon }_{xy}\end{array}\right)$.

/* Maxima */
/* version 5.38.1 */
/*ebener Spannungszustand*/
assumption: [sigma[zz]=0, sigma[yz]=0, sigma[xz]=0];
/* general strain-displacement relation (sdr)*/

equs: subst(assumption,makelist(σ[i][1] = (subst(sdr[3],E).ε)[i][1],i,1,6));
Q: [  sigma[xx],  sigma[yy],  sigma[xy],
    epsilon[zz],epsilon[yz],epsilon[xz]];

sol: ratsimp(solve(equs,Q))[1];

ACM: augcoefmatrix([-sol[1],-sol[2],-sol[3]],[epsilon[xx],epsilon[yy],epsilon[xy]]);
sdr[2] : submatrix(ACM,4);

sdr[2]: [sdr[2],ratsimp(subst(params,sdr[2]))];

Eindimensionaler Spannungszustand

Ganz entsprechend erhalten wir für

${\sigma }_{yy}=0,{\sigma }_{zz}=0,{\sigma }_{xz}=0,{\sigma }_{yz}=0,{\sigma }_{xy}=0$

die Ergebnisse

${\sigma }_{{x}{x}}=\frac{(2{\mu }^2+3\lambda \mu ){ϵ}_{{x}{x}}}{\mu +\lambda },{ϵ}_{{y}{y}}=-\frac{\lambda {ϵ}_{{x}{x}}}{2\mu +2\lambda },{ϵ}_{{z}{z}}=-\frac{\lambda {ϵ}_{{x}{x}}}{2\mu +2\lambda },{ϵ}_{{y}{z}}=0,{ϵ}_{{x}{z}}=0,{ϵ}_{{x}{y}}=0$

bzw.

${\sigma }_{{x}{x}}=E{ϵ}_{{x}{x}},{ϵ}_{{y}{y}}=-\nu {ϵ}_{{x}{x}},{ϵ}_{{z}{z}}=-\nu {ϵ}_{{x}{x}},{ϵ}_{{y}{z}}=0,{ϵ}_{{x}{z}}=0,{ϵ}_{{x}{y}}=0$

/* Maxima */
/* version 5.38.1 */
/*eindimensionaler Spannungszustand*/
assumption: [sigma[yy]=0, sigma[zz]=0, sigma[yz]=0, sigma[xz]=0, sigma[xy]=0];
/* general strain-displacement relation (sdr)*/

equs: subst(assumption,makelist(σ[i][1] = (subst(sdr[3],E).ε)[i][1],i,1,6));
Q: [  sigma[xx],
    epsilon[yy], epsilon[zz],epsilon[yz],epsilon[xz], epsilon[xy]];

sol: ratsimp(solve(equs,Q))[1];