Gelöste Aufgaben/W8Zu

Aufgabenstellung

Zu den tabellierten Standardlösungen für den Euler-Bernoulli-Blaken berechnen wir eine Näherungslösung für einen beidseitig gelenkig gelagerten Euler-Bernoulli-Balken:

Caption

Gesucht ist eine Lösung in Anlehnung an das Verfahren von Ryleigh-Ritz.

Die Lösung nach einer Variante zu diesem Standardverfahren finden Sie hier in W8Zt.

Lösung mit Maxima

Mit dem Föppl-Symbol "<>", sowie

$\alpha =a/\ell$, $\beta =1-\alpha$ und $\xi =x/\ell$

ist die analytische Lösung:

$EIw(x)=\frac{F{\ell }^3}{6}[\beta \xi (1-{\beta }^2-{\xi }^2)+<\xi -\alpha {>}^3]$.

Bei dieser Lösung hat die unabhängige Koordinate x ihren Ursprung in A - wir verwenden unten einen anderen Ursprung!

Mit den passenden Ansatzfunktionen nach Ritz berechnen Sie eine Näherungslösung des Problems nach dem Prinzip vom Minimum der Potentiellen Energie.

Header

Wir lösen das Problem mit Maxima.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 15.08.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2017-10-14                            */
/* ref: TM-C, Labor 3 - aus Gross, Augf. TM 2, Biegetab*/
/* description: finds the approx. solution for         */
/*              problem #1 using PMPE                  */
/*******************************************************/

Declarations

In Maxima treffen wir die Annahme ℓ>0, damit einige Integrale richtig gelöst werden.

/* declarations */
assume(l>0);

Formfunctions

Als unabhängige Koordinaten des Balkens wählen wir "x" entlang der Neutralen Faser mit Ursprung in der Mitte zwischen A und B.

Wir entscheiden uns zunächst für zwei abhängige Koordinaten des Systems

$\underset{\_}{q}=\left(\begin{array}{c}V\\ \mathrm{\Psi }\end{array}\right)$

Trial-Functions

und wählen V und ψ  als die Verschiebung und Verdrehung (=Neigung) des Querschnitts im Punkt x=0 des Balkens.

Jetzt brauchen wir zwei Ansatzfunktionen, die unseren Koordinaten V und ψ entsprechen. Wir wollen diese beiden anschaulich denken können - wir wählen einfache Polynome: eine achsensymmetrische und eine punktsymmetrische Funktion mit den noch unbestimmten Konstanten c_ij:

• $v_1\left(x\right):=c_{1,2}\cdot x^2+c_{1,0}$
• $v_2(x):=c_{2,3}\cdot x^3+c_{2,1}\cdot x$

Diese beiden Funktionen müssen

1. Geometrische Randbedingungen erfüllen und
2. jeweils mit den Koordinaten V und ψ verknüpft werden.

Die zugehörigen Gleichungen (= die Randbedingungen) sind

• $c_{1,0}=V,\frac{c_{1,2}\cdot {\ell }^2}{4}+c_{1,0}=0$ und
• $c_{2,1}=\mathrm{\Psi },\frac{c_{2,3}\cdot {\ell }^3}{8}+\frac{c_{2,1}\cdot \ell }{2}=0$

mit der Lösung

$\begin{array}{l}{c}_{1,0}=V,\\ c_{1,2}=-\frac{4\cdot V}{{\ell }^2},\\ c_{2,1}=\mathrm{\Psi },\\ c_{2,3}=-\frac{4\cdot \mathrm{\Psi }}{{\ell }^2}\end{array}$

Anstatt der exakten, bekannten Lösung, verwenden wir in diesem Näherungsansatz also nun die Funktion

$w\left(x\right)=-\frac{4\cdot x^2\cdot V}{{\ell }^2}+V-\frac{4\cdot \mathrm{\Psi }\cdot x^3}{{\ell }^2}+\mathrm{\Psi }\cdot x$,

mit den beiden Koordinaten V und ψ. die wir nun bestimmen müssen. Anschaulich können wir nun

$w(\xi )=V\cdot {\varphi }_1(\xi )+\mathrm{\Phi }\cdot {\varphi }_2(\xi )$

mit

$\begin{array}{ll}{\varphi }_1(\xi )& =1-4\cdot {\xi }^2\\ {\varphi }_2(\xi )& =\ell \cdot \xi -4\cdot \ell \cdot {\xi }^3\end{array}$

Trial-Functions ϕ₁, ϕ₂

schreiben. So sehen die beiden Trial-Funktionen aus:

Klar ist: die exakte Lösung dieses Lastfalls ist eine Funktion, die im Querkraftverlauf am Kraftangriffspunkt (x=a - ℓ/2) einen Sprung hat. Dagegen ist der Querkraftverlauf unserer Näherungslösung stetig differenzierbar und obendrauf noch konstant!

/**** define form functions ***/
/* coordinates */
q : [V,Psi];

/* generic polynomials */
define(v[1](x),sum(c[1,2*i]*x^(2*i),i,0,1));
define(v[2](x),sum(c[2,(2*i+1)]*x^(2*i+1),i,0,1));

/* solve for c's to comply with geometric boundary conditions      */
coeffs : append(solve([v[1](0)=V,v[1](+l/2)=0],[c[1,0],c[1,2]])[1],
                solve([subst([x=0],diff(v[2](x),x))=Psi,v[2](+l/2)=0],[c[2,1],c[2,3]])[1]);

/* employ in polynomials */
forms : [w(x)  = expand(subst(coeffs, sum(v[i](x),i,1,2)))];

trials: subst([x=l*xi],makelist(coeff(subst(forms,w(x)), q[i]),i,1,2));

plot2d( [trials[1],trials[2]/l],[xi,-1/2,+1/2], [legend, "ϕ[1]","ϕ[2]"]);

Equilibrium Conditions

Mit dem Prinzip vom Minimum der Potentiellen Energie sind die Gleichgewichtsbedingungen

$\frac{\partial U}{\partial q_i}\stackrel{!}{=}0\text{ für alle Koordinaten }i.$,

dabei ist

$U=\mathrm{\Pi }-A,\text{ mit }\mathrm{\Pi }\text{: elastisches Potential und }A\text{: Arbeit der Kraft F.}$.

Einsetzen der Trial-Funktionen liefert

$\begin{array}{l}A=F\cdot (-{\alpha }^2\cdot V+V-\frac{{\alpha }^3\cdot \ell \cdot \mathrm{\Psi }}{2}+\frac{\alpha \cdot \ell \cdot \mathrm{\Psi }}{2})\\ \mathrm{\Pi }={E}{I}\cdot \underset{-\frac{\ell }{2}}{\overset{\frac{\ell }{2}}{\int }}{(\frac{d^2}{d{x}^2}\cdot (\mathrm{\Psi }\cdot x-\frac{4\cdot \mathrm{\Psi }\cdot x^3}{{\ell }^2}+V-\frac{4\cdot x^2\cdot V}{{\ell }^2}))}^{2}dx\end{array}$

und wir finden nach dem Ausführen der Differentiation und Integration

$U=-\frac{64\cdot {E}{I}\cdot V^2}{{\ell }^3}-{\alpha }^2\cdot F\cdot V+F\cdot V-\frac{{\alpha }^3\cdot \ell \cdot \mathrm{\Psi }\cdot F}{2}+\frac{\alpha \cdot \ell \cdot \mathrm{\Psi }\cdot F}{2}-\frac{48\cdot {\mathrm{\Psi }}^2\cdot {E}{I}}{\ell }$

Achtung: hier bezeichnet nun α=-1 den Punkt A, α=+1 den Punkt B.

Die Koordinaten fassen wir zu

$\underset{\_}{q}=\left(\begin{array}{c}V\\ \mathrm{\Psi }\end{array}\right)$

zusammen und schreiben damit

$U(\underset{\_}{q})=\frac{1}{2}{\underset{\_}{q}}^T\cdot \underset{\_}{\underset{\_}{A}}\cdot \underset{\_}{q}-{\underset{\_}{q}}^T\cdot \underset{\_}{b}$

mit

$\underset{\_}{\underset{\_}{A}}=\left(\begin{array}{cc}-\frac{64\cdot {E}{I}}{{\ell }^3}& 0\\ 0& -\frac{48\cdot {E}{I}}{\ell }\end{array}\right)$

und

$\underset{\_}{b}=\left(\begin{array}{c}{\alpha }^2\cdot F-F\\ \frac{{\alpha }^3\cdot \ell \cdot F}{2}-\frac{\alpha \cdot \ell \cdot F}{2}\end{array}\right)$

Mit dieser Formulierung sind wir bei den Minimum Prinzipen angekommen, die Lösung kommt aus dem linearen Gleichungssystem

$\underset{\_}{\underset{\_}{A}}\cdot \underset{\_}{q}=\underset{\_}{b}$

/* potential energy of system */
PMPE : U = A-Pi;

parts : [/*virt. strain energy */
         A = F*w(x[F]),
         /* work of implied external force F*/
         Pi = integrate(EI*diff(w(x),x,2)^2,x,-l/2,+l/2)];
parts : subst([w(x[F]) = subst([x=\alpha*l/2], subst(forms,w(x)))],parts);
parts : subst(forms,parts);

/* substitute .... */
PMPE : subst(forms,subst(parts,PMPE));
/* execute differntiation and integration of δW */
PMPE : expand(ev(PMPE,nouns));

/* pick individual equations */
OLE: [b = - makelist([coeff(subst(PMPE,U),q[i])],i,1,2),
      A = [[coeff(subst(PMPE,U),q[1],2),0],[0,coeff(subst(PMPE,U),q[2],2)]]];

Solve

Die Lösung für die Koordinaten q ist

$\begin{array}{l}V=-\frac{({\alpha }^2-1)\cdot {\ell }^3\cdot F}{64\cdot {E}{I}}\\ \mathrm{\Psi }=-\frac{({\alpha }^3-\alpha )\cdot {\ell }^2\cdot F}{96\cdot {E}{I}}\end{array}$

/* solve .... */
K: funmake('matrix,subst(OLE,A));
f : funmake('matrix,subst(OLE,b));
print(K,transpose(q)=f)$

equs : makelist((K.q)[i][1]=f[i][1],i,1,2);
sol: solve(equs,q)[1];

Post-Process

Die Lösung normieren wir noch für das Post-Processing mit der analytischen maximalen Auslenkung im symmetrischen Belastungsfall (wenn F in der Mitte zwischen A und B angreift):

Wir tragen sie für verschiedene Kraft-Angriffspunkte (α=-1,...α=+1) auf:

Auslenkung w(x) am Kraftangriffspunkt

⚠ Wissen Sie ...:

... warum A hier eine Diagonalmatrix ist? Schauen Sie sich die Formel zur Berechnung der Koeffizienten aij an - was erkennen Sie?

/* plot results */
m : 2; scale : F*l^3/(EI*48);
leg : append([legend],makelist(simplode(["α=",(-m+i)/m]),i,0,2*m));
plotfct : expand(subst([x=xi*l],subst(sol,subst(forms,w(x)/scale))));
toplot : makelist(subst([alpha=(-m+i)/m],plotfct),i,0,2*m);
plot2d(subst([alpha=0],toplot),[xi,-1/2,+1/2], [y,-0.05,1.0], leg);

Post-Process: Compare with Analytic Solution

Und wir schauen uns für α=1/2 die Verschiebung der Ritz- und analytischen-Lösung im Vergleich an:

Vergleich von analytischer / numerischer Lösung für w(x)

✔ Und wissen Sie auch ...:

... wie der Verlauf der Querkraft im Vergleich Ritz / analytisch aussieht?

/* Vergleich mit analytischer Lösung */
foppl(xi,alpha) := if (xi < alpha) then 0 else xi-alpha;
anplot : F*l^3/(6*EI)*(beta*xi*(1-beta^2-xi^2)+foppl(xi,alpha)^3)/scale;
anplot : subst([beta=1-alpha],anplot);
ritz: subst([xi=xi-1/2],subst(alpha=1/2,expand(subst(sol,makelist(trials[i]*q[i]/scale,i,1,2)))));

plot2d([subst([alpha=3/4],anplot),ritz[1]+ritz[2], ritz[1],ritz[2]],[xi,0,1],
       [legend, "analytic", "Ritz", "V-part", "Ψ-part"],
       [title, "Vergleich analytytische / Ritz - Lösung"])

---

Links

• ...

Literature

• ...