Gelöste Aufgaben/UEBA

Aufgabenstellung

Wie man die Sensoren eines Smartphones für Messungen einsetzt, zeigen wir hier.

Hier soll der Elastizitätsmodul des Stab-Materials mit Hilfe eines Biegeversuchs bestimmt werden. Der Stab der Länge ℓ hat einen quadratischen Querschnitt der Höhe h und die Masse m. Für die Messung nutzen Sie als Sensor ihr Smartphone, das Ihnen die statische Beschleunigung a_y, a_z in y- und z-Richtung angibt.

Sie haben Ihre Standard-Lösungen für den Euler-Bernoulli-Balken zu Hause vergessen und müssen sich mit einer Näherungslösung für den Balken nach dem Verfahren von Rayleigh-Ritz zufrieden geben.

Lageplan

Für den Versuch wird der Balken wird durch seine Gewichtskraft belastet. Er ist in A fest eingespannt, die Masse des Smartphones sei vernachlässigbar.

Gesucht ist die Lösung mit dem Ansatz von Rayleigh-Ritz und zwei Trial-Functions.

Gegeben: ℓ=3 m, m=28 kg, g=9.81 m/s², h=10 cm,

                 a_y = 0.9793658 m/s², a_z= 9.7609909 m/s²

Lösung mit Maxima

Smartphones haben eine Reihe von Sensoren eingebaut - und die man kann als Ingenieur prima gebrauchen ...

Ein Erklärungsvideo zu Beschleunigungs-Sensoren finden Sie hier.

Header

Das Rayleigh-Ritz-Verfahren ist hier ein bisschen unter der experimentellen Bestimmung von Parametern des Systems "vergraben".

Der Lösungsweg ist aber der gleiche wie gewohnt.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 15.08.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2020-01-13                            */
/* ref: TMC                                            */
/* description: Rayley-Ritz-Solution for EBB           */
/*              with "Smartphone"                      */
/* see https://youtu.be/KZVgKu6v808                    */
/*******************************************************/

/*******************************************************/
/* declare variational variables - see 6.3 Identifiers */
declare( "ℓ", alphabetic);
declare( "φ", alphabetic);
declare( "Φ", alphabetic);
declare( "ŵ", alphabetic);

System-Parameters

Die Streckenlast auf den Balken ist

$\displaystyle q_{0}={\frac {m\;g}{\ell }}$

und wir arbeiten mit der dimensionslosen Länge

$\displaystyle \xi ={\frac {x}{\ell }}$.

/* system parameters                                     */
params: [q[0]=m*g/ℓ];
dimless: [x = xi*ℓ];

/* make equations of motion dim'less with load case #1 from Gross e.a., same as UEBI */
reference : [ŵ = q[0]*ℓ^4/(8*EI), Phi[ref] = q[0]*ℓ^3/(6*EI), M[ref] = m*g*ℓ, Q[ref] = m*g];

Formfunctions

Formfunctions

Als Ansatzfunktion für die Näherungslösung verwenden wir

${\begin{array}{ll}\displaystyle w(x)=&&W\cdot \underbrace {\left(\xi ^{2}\cdot (3-2\cdot \xi )\right)} _{\displaystyle =:\phi _{1}}\\&+&\Phi \cdot \underbrace {\left(\xi ^{2}\,\ell \cdot (\xi -1)\right)} _{\displaystyle =:\phi _{2}}\end{array}}$.

Koordinaten

Die Trial-Functions ϕ_i erfüllen dabei die Bedingungen

$w(\ell )=W$

und

$w'(\ell )=\Phi$

/************************************************************/
/* Rayleigh-Ritz                                            */
/* trial function */
trial: w(xi) = sum(C[j]*xi^(j),j,2,3);
trial: expand(subst(solve([subst([xi=1],subst(trial,w(xi)))= W,subst([xi=1],diff(subst(trial,w(xi)),xi)/ℓ)= Φ],[C[2], C[3]])[1],trial));

X : [W,Φ];
phi : makelist(coeff(subst(trial,w(xi)),X[i]),i,1,2);
plot2d([phi[1],phi[2]/ℓ],[xi,0,1], [xlabel, "x/ℓ ->"], [ylabel, "ϕ ->"], [legend, "ϕ_1", "ϕ_2/ℓ"]);

Potential Energy

Für den Ritz-Ansatz brauchen wir die Terme der Potentiellen Energie des Systems

$U=\Pi -A$,

wobei Π die Formänderungsenergie ist und A die Arbeitsfunktion der äußeren Last q₀.

Es ist

${\begin{array}{ll}\Pi &=\displaystyle {\frac {1}{2}}\int _{\ell }EI\;(w'')^{2}\,dx\\A&=\displaystyle \int _{\ell }q(x)\cdot w(x)\,dx{\text{ mit }}q(x)={\frac {m\,g}{\ell }}\end{array}}$.

Π und A setzen wir in U ein und schreiben die skalare Gleichung in Matrizenform an. Dabei müssen wir

$\displaystyle {\frac {d\phi _{i}}{x}}={\frac {d\phi _{i}}{\xi }}\cdot \underbrace {\displaystyle {\frac {d\xi }{x}}} _{\displaystyle ={\frac {1}{\ell }}}$

beachten. Mit den gesuchten Größen

${\underline {Q}}=\left({\begin{array}{c}W\\\Phi \end{array}}\right)$

erhalten wir für das Potential

$U={\frac {1}{2}}EI\cdot \displaystyle {\underline {Q}}^{T}\cdot {\underline {\underline {K}}}\cdot {\underline {Q}}-{\underline {Q}}^{T}\cdot {\underline {P}}$

wobei für die Koeffizienten der Matrix K

$k_{i,j}=\displaystyle {\frac {EI}{\ell ^{3}}}\cdot \displaystyle \int _{0}^{1}\phi _{i}''(\xi )\cdot \phi _{j}''(\xi )\,d\xi {\text{ Achtung! Hier mit }}(.)'={\frac {d(.)}{d\xi }}$

gilt und die rechten Seite P

$\displaystyle p_{i}=q_{0}\ell \cdot \int _{0}^{1}\phi _{i}(\xi )\,d\xi$.

✔ Matlab© und Polynome:

Alle verwendeten Funktionen in diesem Beispiel sind Polynome. Matlab© bietet für die Manipulation von Polynomen eine Klasse von Functions an, die hier sehr hilfreich sind: Matlab©: Polynomials

/* define potential energy of system                          */
PMPE : [U  = Pi - A,
        Pi = 1/2*ℓ*'integrate(EI*'diff(w(xi),xi,2)^2/ℓ^4,xi,0,1),
        A  = ℓ*'integrate(q[0]*w(xi),xi,0,1)];
PMPE: subst(dimless,subst(params,subst(trial,PMPE)));
PMPE: subst(PMPE[3],subst(PMPE[2], PMPE[1]));
PMPE : ev(PMPE,nouns);

Solving

Die Gleichgewichtsbedingungen

$\displaystyle {\frac {dU}{dQ_{i}}}{\stackrel {!}{=}}0$

sind erfüllt, wenn

$\displaystyle {\frac {EI}{\ell ^{3}}}\cdot {\begin{pmatrix}12&-6\ell \\-6\ell &4\ell ^{2}\end{pmatrix}}\cdot {\begin{pmatrix}W\\\Phi \end{pmatrix}}=m\;g\cdot {\begin{pmatrix}\displaystyle {\frac {1}{2}}\\\displaystyle {\frac {\ell }{12}}\end{pmatrix}}$.

Dieses lineare Gleichungssystem hat die Lösung

$\left({\begin{array}{c}W\\\Phi \end{array}}\right)=\displaystyle {\frac {m\,g\,\ell ^{3}}{EI}}\left({\begin{array}{c}\displaystyle {\frac {1}{8}}\\\displaystyle {\frac {1}{6\,\ell }}\end{array}}\right)$.

Zum Vergleich schauen wir jetzt bei der analytischen Lösung des Problems nach:

${\begin{array}{lll}{\hat {w}}&=w_{max}&=\displaystyle {\frac {\ell ^{4}}{8\,EI}}\cdot q_{0}\\{\hat {\varphi }}&=w'_{B}&=\displaystyle {\frac {\ell ^{3}}{6\,EI}}\cdot q_{0}\end{array}}$.

Und sehen: unsere Lösung nach Rayleigh-Ritz stimmt am Rand exakt mit der analytischen Lösung überein, es ist

${\begin{array}{ccc}W&=&{\hat {w}}\\\Phi &=&{\hat {\phi }}\end{array}}$!

/*******************************************************/
/* equilibreium condition                              */
equilibrium : makelist(diff(subst(PMPE, U),X[j]) = 0,j,1,2);
ACM : augcoefmatrix(equilibrium,X);
print(submatrix(ACM,3),"*",transpose(X),"=",-col(ACM,3))$

/*******************************************************/
/* solve                                               */
sol: ratsimp(solve(equilibrium,X))[1];

Post-Processing

Lösungsverläufe für w, φ, M, Q

Die Näherungslösung für Auslenkung w(x), Kippwinkel ϕ(x), Moment M(x) und Querkraft Q(x) können wir jetzt auftragen. Dafür verwenden wir die weiteren Referenzgrößen

${\begin{array}{ll}M_{ref}&=m\,g\,\ell \\Q_{ref}&=m\,g\end{array}}$

und tragen die Lösungen dimensionslos auf:

Für unsere Fragestellung schreiben wir die Lösung um als

${\begin{array}{ll}EI&=\displaystyle {\frac {m\,g\,\ell ^{2}}{6\,\Phi }}\\W&=\displaystyle {\frac {3\,\Phi \ell }{4}}\end{array}}$

und bestimmen uns den Drehwinkel aus den gemessenen statischen Beschleunigungen (vgl. Bild oben). Dabei ist

$a_{y}=g\cdot \sin(\Phi )$.

🧨 Warum nehmen wir nicht die z-Komponente der Beschleunigung?:

Die az-Komponente können wir nicht gebrauchen weil $\displaystyle \left.{\frac {\partial a_{z}}{\partial \Phi }}\right\vert _{\Phi =0}=0$

Da für kleine Winkel sin(Φ) ≈ Φ gilt, ist

$\Phi =0.1$

Wir berechnen die gesuchte Materialkonstante mit

$\displaystyle I={\frac {h^{4}}{12}}$

zu

$\displaystyle E=878.976.000{\frac {N}{m^{2}}}$.

/************************************************************/
/* post-processing                                          */
fcts: ratsimp( subst(params,subst(reference,subst(sol,subst(trial,w(xi)/ŵ)))));
fcts: makelist( [ŵ,ŵ,-EI*ŵ,-EI*ŵ][i+1]*diff(fcts,xi,i)/ℓ^i,i,0,3);

fcts: makelist(fcts[i]/[ŵ, Phi[ref], M[ref], Q[ref]][i], i,1,4);
fcts: subst(params,subst(reference,fcts));

plot2d(fcts, [xi,0,1], [xlabel, "x/ℓ ->"], [ylabel, " ->"],
             [legend, "w/ŵ", "φ/Φ_ref", "M/M_ref", "Q/Q_ref"]);

---

Links

• ...

Literature

• ...