Gelöste Aufgaben/StaF

Aufgabenstellung

Wir untersuchen die Belastung eines ebenen Stabwerks. Die Stäbe haben wie skizziert die Länge ℓ bzw. ℓ/2. Die Struktur wird mit der Kraft F belastet.

Stabwerk mit in den Knoten fest verbundenen Stäben.

Gesucht ist ein Vergleich zwischen der klassischen Stabwerkstheorie und einer Herangehensweise, bei der wir eine feste Verbindung der Stäbe in den Knoten ansetzten. Grundlage des Modells ist die FEM-Lösung der Felddifferentialgleichung im Vergleich zur Lösung in Problemstellung „StaB“.

Wir stellen das Modell des Stabwerks mit dem Prinzip der virtuellen Verrückungen auf und vergleichen, wie sich diese von der Herangehensweise aus „Aufgabe StaB“ mit der analytischen Lösung unterscheidet.

Lösung mit Maxima

Wir nutzen das Computer-Algebra-System Maxima zur Lösung. Das macht hier Sinn, weil wir die Herangehensweise mit der aus Stab vergleichen wollen – für die wir ebenfalls Maxima eingesetzt haben.

Declarations

Wir übernehmen alle Vereinbarungen und Parameter aus der Problemformulierung „Stab“.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 21.05.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2024-09-20                            */
/* ref: NMM, Labor 2, dimensionsbehaftete              */
/*                           Vorgehensweise            */
/* description: finds the FEM solution for             */
/*              lab problem #2                         */
/*******************************************************/

assume(A>0,H>h,h>0, a>0);

/*-----------------------------------------------------*/
/* Euler-Matrix                                        */
DR(α) := matrix([ cos(α),sin(α), 0],
                [-sin(α),cos(α), 0],
		[   0   ,   0  , 1]);
/* inverse of Euler-Matrix                                        */
DI(α) := transpose(DR(α));
/* compose transforation matrix for rod (two ends ....)*/
DE(α) := matrix([ cos(α),-sin(α), 0,   0   ,  0    , 0],
                [ sin(α), cos(α), 0,   0   ,  0    , 0],
                [   0   ,    0  , 1,   0   ,  0    , 0],
                [   0   ,    0  , 0, cos(α),-sin(α), 0],
                [   0   ,    0  , 0, sin(α), cos(α), 0],
                [   0   ,    0  , 0,   0   ,  0    , 1]);

/* for each rod, define
            * angle α, and
	    * node-IDs
   at its start and end                                */
index : [[ 0  ,[1,3]],  /* rod #1*/
         [α[2],[2,3]],  /* rod #2*/
	 [α[3],[3,4]],  /* rod #3*/
	 [ 0  ,[2,4]]   /* rod #4*/];
/* node - reference locations                          */
nodes: [[0,0],[0,sqrt(3)/2],[1/2,0],[0,sqrt(3)/2]]$

/*-----------------------------------------------------*/
/* system parameters                                   */
params: [ℓ[1]=ℓ[0]/2, ℓ[2]=ℓ[0], ℓ[3]=ℓ[0], ℓ[4]=ℓ[0],
         α[2]=%pi/3,α[3]= -%pi/3,
	 EA = E*A, EI = E*I, I=η*A^2/12];

moreParams: [A = a^2, ℓ[0]= 100*a];

Gleichgewichtsbedingungen

Für die Gleichgewichtsbedingung nach dem Prinzip der virtuellen Verrückungen

$\begin{array}{ccc}\delta W& \stackrel{!}{=}& 0\\ & =& \delta \mathrm{\Pi }-\delta W^a\end{array}$

benötigen wir die virtuelle Formänderungsenergie $\delta \mathrm{\Pi }$ und die virtuelle Arbeit der äußeren Kraft $\delta W^a$ der äußeren Kräfte und Momente.

Mit den Konventionen für die Knoten-Verschiebungen aus Aufgabe StaB ist

$\delta W^a=+\delta W_{4,0}\cdot F$.

Für $\delta \mathrm{\Pi }$ gilt

$\delta \mathrm{\Pi }=\sum _{i=0}^4\delta {\mathrm{\Pi }}_i$

mit den virtuellen Formänderungsarbeiten der vier Stäbe.

Dabei haben wir Anteile der Arbeit aus der Biegung und der Längs-Dehnung des Stabes.

Für den Stab k mit den Knoten I und J haben wir als Koodinaten der Knoten

$U_{I,k},W_{I,k},{\mathrm{\Phi }}_{I,k}$ und $U_{J,k},W_{J,k},{\mathrm{\Phi }}_{J,k}$.

Damit haben wir

$\delta {\mathrm{\Pi }}_k=(\delta W_{I,k},\delta {\mathrm{\Phi }}_{I,k},\delta {\mathrm{\Phi }}_{J,k},\delta W_{J,k})\cdot \frac{EI}{{\ell }_i^3}\cdot \left(\begin{array}{cccc}12& 6{\ell }_i& -12& 6{\ell }_i\\ 6{\ell }_i& 4{\ell }_i^2& -6{\ell }_i& 2{\ell }_i^2\\ -12& -6{\ell }_i& 12& -6{\ell }_i\\ 6{\ell }_i& 2{\ell }_i^2& -6{\ell }_i& 4{\ell }_i^2\end{array}\right)\cdot \left(\begin{array}{c}{W}_{I,k}\\ {\mathrm{\Phi }}_{I,k}\\ W_{J,k}\\ {\mathrm{\Phi }}_{J,k}\end{array}\right)+(\delta U_{I,k},\delta U_{J,k})\cdot \frac{EA}{{\ell }_i}\cdot \left(\begin{array}{cc}1& -1\\ -1& 1\end{array}\right)\cdot \left(\begin{array}{c}{U}_{I,k}\\ U_{J,k}\end{array}\right)$

Für den Stab k definieren wir

${\underset{\_}{Q}}_{k,k}=\left(\begin{array}{c}{U}_{I,k}\\ W_{I,k}\\ {\mathrm{\Phi }}_{I,k}\\ U_{J,k}\\ W_{J,k}\\ {\mathrm{\Phi }}_{J,k}\\ \end{array}\right)$ sowie $\delta {\underset{\_}{Q}}_{k,k}=\left(\begin{array}{c}\delta U_{I,k}\\ \delta W_{I,k}\\ \delta {\mathrm{\Phi }}_{I,k}\\ \delta U_{J,k}\\ \delta W_{J,k}\\ \delta {\mathrm{\Phi }}_{J,k}\\ \end{array}\right)$

und finden damit

$\delta {\mathrm{\Pi }}_k=\delta {\underset{\_}{Q}}_{k,k}^T\cdot {\underset{\_}{\underset{\_}{K}}}_{k,k}\cdot {\underset{\_}{Q}}_{k,k}$

mit der Element-Steifigkeitsmatrix des Elements k im k-Koordinatensystem

${\underset{\_}{\underset{\_}{K}}}_{k,k}=\frac{EI}{{\ell }_i^3}\cdot \left(\begin{array}{cccccc}0& 0& 0& 0& 0& 0\\ 0& 12& 6{\ell }_i& 0& -12& 6{\ell }_i\\ 0& 6{\ell }_i& 4{\ell }_i^2& 0& -6{\ell }_i& 2{\ell }_i^2\\ 0& 0& 0& 0& 0& 0\\ 0& -12& -6{\ell }_i& 0& 12& -6{\ell }_i\\ 0& 6{\ell }_i& 2{\ell }_i^2& -0& 6{\ell }_i& 4{\ell }_i^2\end{array}\right)+\frac{EA}{{\ell }_i}\cdot \left(\begin{array}{cccccc}1& 0& 0& -1& 0& 0\\ 0& 0& 0& 0& 0& 0\\ 0& 0& 0& 0& 0& 0\\ -1& 0& 0& 1& 0& 0\\ 0& 0& 0& 0& 0& 0\\ 0& 0& 0& 0& 0& 0\end{array}\right)$

/*-----------------------------------------------------*/
/* nodal coordinates                                   */
nodalCoord : flatten(makelist([U[k,0],W[k,0],Φ[k,0]],k,1,4));
/*****************************************************/
/* Element-Striffness Matrix in local coordinates    */
kI : (EI/ℓ[i]^3)*matrix([ 0,   0  ,     0  , 0,    0  ,     0  ],
                        [ 0,  12  ,  6*ℓ[i], 0,  -12  ,  6*ℓ[i]],			
                        [ 0,6*ℓ[i],4*ℓ[i]^2, 0,-6*ℓ[i],2*ℓ[i]^2],
			[ 0,   0  ,     0  , 0,    0  ,     0  ],
                        [ 0, -12  , -6*ℓ[i], 0,   12  , -6*ℓ[i]],
                        [ 0,6*ℓ[i],2*ℓ[i]^2, 0,-6*ℓ[i],4*ℓ[i]^2])+
     (EA/ ℓ[i] )*matrix([ 1,   0  ,	0  ,-1,    0  ,     0  ],
			[ 0,   0  ,  	0  , 0,    0  ,     0  ],
			[ 0,   0  ,	0  , 0,    0  ,     0  ],
			[-1,   0  ,	0  , 1,    0  ,     0  ],
			[ 0,   0  ,	0  , 0,    0  ,     0  ],
			[ 0,   0  ,	0  , 0,    0  ,     0  ]);

Transformation der Koordinaten in das globale System

In den Ausdrücken der virtuellen Formänderungsenergie stehen die Koordinaten des lokalen Koordinatensystems von k. Die müssen wir, wie in Aufgabe StaB mit der Euler-Drehmatrix ineinander überführen.

Dafür haben wir

$\left(\begin{array}{c}{U}_{I,0}\\ W_{I,0}\\ {\mathrm{\Phi }}_{I,0}\end{array}\right)={\underset{\_}{\underset{\_}{D}}}_R({\alpha }_k)\cdot \left(\begin{array}{c}{U}_{I,k}\\ W_{I,k}\\ {\mathrm{\Phi }}_{I,k}\end{array}\right)$

mit der Transformationsmatrix

${\underset{\_}{\underset{\_}{D}}}_R({\alpha }_k)=\left(\begin{array}{ccc}\cos ({\alpha }_k)& \sin ({\alpha }_k)& 0\\ -\sin ({\alpha }_k)& \cos ({\alpha }_k)& 0\\ 0& 0& 1\end{array}\right).$

Es ist praktisch, an dieser Stelle die Abkürzung

${\underset{\_}{q}}_{I,0}=\left(\begin{array}{c}{U}_{I,0}\\ W_{I,0}\\ {\mathrm{\Phi }}_{I,0}\end{array}\right)$

für die Koordinaten eines Knoten im Referenzsystem einzuführen. Also ist

$\left(\begin{array}{c}{U}_{I,k}\\ W_{I,k}\\ {\mathrm{\Phi }}_{I,k}\end{array}\right)={\underset{\_}{\underset{\_}{D}}}_R^T({\alpha }_k)\cdot {\underset{\_}{q}}_{I,0}.$

Damit wir für die Elementsteifigkeitsmatrix - mit beiden Anfangs- und Endknoten des Elements - vom "0"-System ins "k"-System transformieren, brauchen wir die neue Transformations-Matrix

$\underset{\_}{\underset{\_}{T}}({\alpha }_k):=\left(\begin{array}{cc}{\underset{\_}{\underset{\_}{D}}}_R^T({\alpha }_k)& \underset{\_}{\underset{\_}{0}}\\ \underset{\_}{\underset{\_}{0}}& {\underset{\_}{\underset{\_}{D}}}_R^T({\alpha }_k)\end{array}\right)$

Mit diesen ist

$\delta \mathrm{\Pi }=\sum _{k=1}^4\delta {\underset{\_}{Q}}_{k,0}^T\cdot \underset{:={\underset{\_}{\underset{\_}{K}}}_{k,0}}{\underbrace{{\underset{\_}{\underset{\_}{T}}}^T({\alpha }_k)\cdot {\underset{\_}{\underset{\_}{K}}}_{k,k}\cdot \underset{\_}{\underset{\_}{T}}({\alpha }_k)}}\cdot {\underset{\_}{Q}}_{k,0}$

Die resultierenden Element-Steifigkeitsmatrizen sind im folgenden aufgeschreiben:

Element-Steigigkeitsmatrizen mit globalen Koordinaten
Element #1
${\underset{\_}{\underset{\_}{K}}}_{1,0}=\left(\begin{array}{cccccc}\frac{8A^{2}E\eta }{{\ell }_0^3}& 0& \frac{2A^{2}E\eta }{{\ell }_0^2}& -\left(\frac{8A^{2}E\eta }{{\ell }_0^3}\right)& 0& \frac{2A^{2}E\eta }{{\ell }_0^2}\\ 0& \frac{2AE}{{\ell }_0}& 0& 0& -\left(\frac{2AE}{{\ell }_0}\right)& 0\\ \frac{2A^{2}E\eta }{{\ell }_0^2}& 0& \frac{2A^{2}E\eta }{3{\ell }_0}& -\left(\frac{2A^{2}E\eta }{{\ell }_0^2}\right)& 0& \frac{A^{2}E\eta }{3{\ell }_0}\\ -\left(\frac{8A^{2}E\eta }{{\ell }_0^3}\right)& 0& -\left(\frac{2A^{2}E\eta }{{\ell }_0^2}\right)& \frac{8A^{2}E\eta }{{\ell }_0^3}& 0& -\left(\frac{2A^{2}E\eta }{{\ell }_0^2}\right)\\ 0& -\left(\frac{2AE}{{\ell }_0}\right)& 0& 0& \frac{2AE}{{\ell }_0}& 0\\ \frac{2A^{2}E\eta }{{\ell }_0^2}& 0& \frac{A^{2}E\eta }{3{\ell }_0}& -\left(\frac{2A^{2}E\eta }{{\ell }_0^2}\right)& 0& \frac{2A^{2}E\eta }{3{\ell }_0}\end{array}\right)$
Element #2
${\underset{\_}{\underset{\_}{K}}}_{2,0}=\left(\begin{array}{cccccc}\frac{A^{2}E\eta +3{\ell }_0^{2}AE}{4{\ell }_0^3}& \frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}& \frac{A^{2}E\eta }{4{\ell }_0^2}& -\left(\frac{A^{2}E\eta +3{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& -\left(\frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{A^{2}E\eta }{4{\ell }_0^2}\\ \frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}& \frac{3A^{2}E\eta +{\ell }_0^{2}AE}{4{\ell }_0^3}& \frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}& -\left(\frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& -\left(\frac{3A^{2}E\eta +{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\\ \frac{A^{2}E\eta }{4{\ell }_0^2}& \frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}& \frac{A^{2}E\eta }{3{\ell }_0}& -\left(\frac{A^{2}E\eta }{4{\ell }_0^2}\right)& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\right)& \frac{A^{2}E\eta }{6{\ell }_0}\\ -\left(\frac{A^{2}E\eta +3{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& -\left(\frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& -\left(\frac{A^{2}E\eta }{4{\ell }_0^2}\right)& \frac{A^{2}E\eta +3{\ell }_0^{2}AE}{4{\ell }_0^3}& \frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}& -\left(\frac{A^{2}E\eta }{4{\ell }_0^2}\right)\\ -\left(\frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& -\left(\frac{3A^{2}E\eta +{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\right)& \frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}& \frac{3A^{2}E\eta +{\ell }_0^{2}AE}{4{\ell }_0^3}& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\right)\\ \frac{A^{2}E\eta }{4{\ell }_0^2}& \frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}& \frac{A^{2}E\eta }{6{\ell }_0}& -\left(\frac{A^{2}E\eta }{4{\ell }_0^2}\right)& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\right)& \frac{A^{2}E\eta }{3{\ell }_0}\end{array}\right)$
Element #3
${\underset{\_}{\underset{\_}{K}}}_{3,0}=\left(\begin{array}{cccccc}\frac{A^{2}E\eta +3{\ell }_0^{2}AE}{4{\ell }_0^3}& -\left(\frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{A^{2}E\eta }{4{\ell }_0^2}& -\left(\frac{A^{2}E\eta +3{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}& \frac{A^{2}E\eta }{4{\ell }_0^2}\\ -\left(\frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{3A^{2}E\eta +{\ell }_0^{2}AE}{4{\ell }_0^3}& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\right)& \frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}& -\left(\frac{3A^{2}E\eta +{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\right)\\ \frac{A^{2}E\eta }{4{\ell }_0^2}& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\right)& \frac{A^{2}E\eta }{3{\ell }_0}& -\left(\frac{A^{2}E\eta }{4{\ell }_0^2}\right)& \frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}& \frac{A^{2}E\eta }{6{\ell }_0}\\ -\left(\frac{A^{2}E\eta +3{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}& -\left(\frac{A^{2}E\eta }{4{\ell }_0^2}\right)& \frac{A^{2}E\eta +3{\ell }_0^{2}AE}{4{\ell }_0^3}& -\left(\frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& -\left(\frac{A^{2}E\eta }{4{\ell }_0^2}\right)\\ \frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}& -\left(\frac{3A^{2}E\eta +{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}& -\left(\frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{3A^{2}E\eta +{\ell }_0^{2}AE}{4{\ell }_0^3}& \frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\\ \frac{A^{2}E\eta }{4{\ell }_0^2}& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\right)& \frac{A^{2}E\eta }{6{\ell }_0}& -\left(\frac{A^{2}E\eta }{4{\ell }_0^2}\right)& \frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}& \frac{A^{2}E\eta }{3{\ell }_0}\end{array}\right)$
Element #4
${\underset{\_}{\underset{\_}{K}}}_{4,0}=\left(\begin{array}{cccccc}\frac{A^{2}E\eta }{{\ell }_0^3}& 0& \frac{A^{2}E\eta }{2{\ell }_0^2}& -\left(\frac{A^{2}E\eta }{{\ell }_0^3}\right)& 0& \frac{A^{2}E\eta }{2{\ell }_0^2}\\ 0& \frac{AE}{{\ell }_0}& 0& 0& -\left(\frac{AE}{{\ell }_0}\right)& 0\\ \frac{A^{2}E\eta }{2{\ell }_0^2}& 0& \frac{A^{2}E\eta }{3{\ell }_0}& -\left(\frac{A^{2}E\eta }{2{\ell }_0^2}\right)& 0& \frac{A^{2}E\eta }{6{\ell }_0}\\ -\left(\frac{A^{2}E\eta }{{\ell }_0^3}\right)& 0& -\left(\frac{A^{2}E\eta }{2{\ell }_0^2}\right)& \frac{A^{2}E\eta }{{\ell }_0^3}& 0& -\left(\frac{A^{2}E\eta }{2{\ell }_0^2}\right)\\ 0& -\left(\frac{AE}{{\ell }_0}\right)& 0& 0& \frac{AE}{{\ell }_0}& 0\\ \frac{A^{2}E\eta }{2{\ell }_0^2}& 0& \frac{A^{2}E\eta }{6{\ell }_0}& -\left(\frac{A^{2}E\eta }{2{\ell }_0^2}\right)& 0& \frac{A^{2}E\eta }{3{\ell }_0}\end{array}\right)$

Wir sammeln nun alle Koordianten der Knoten im 0-System in

${\underset{\_}{Q}}_0^T=({\underset{\_}{q}}_{1,0}^T,{\underset{\_}{q}}_{2,0}^T,{\underset{\_}{q}}_{3,0}^T,{\underset{\_}{q}}_{4,0}^T)$

und schreiben die Gleichgewichtsbedingungen in der Form

$\delta W=\delta {\underset{\_}{Q}}_0^T\cdot ({\underset{\_}{\underset{\_}{K}}}_0\cdot {\underset{\_}{Q}}_0-\underset{\_}{P})\stackrel{!}{=}0$

an. Dabei kommen die Beiträge zur Gesamt-Steifigkeitsmatrix (hier noch in der Fassung ohne Berücksichtigung der Randbedingungen) aus den vier Beiträgen der virtuellen Formänderungsenergie - die wir hier farblich gekennzeichnet haben:

Einsortieren der Anteile der virtuellen Formänderungsenergie nach den Knoten.

/* apply transformation to global coordinates         */
elemStiffMat: ratsimp(subst(params,makelist(transpose(DE(index[k][1])).subst(i=k,kI).DE(index[k][1]),k,1,4)))$
for i:1 thru 4 do
    print(k[i],"=",elemStiffMat[i])$
    
K: zeromatrix(length(nodalCoord),length(nodalCoord))$
for elem: 1 thru 4 do
   (pivot:append(3*(index[elem][2][1]-1)*[1,1,1],
                 3*(index[elem][2][2]-1)*[1,1,1])+[1,2,3,1,2,3],
    for row: 1 thru 6 do
        for col: 1 thru 6 do
       	    K[pivot[row],pivot[col]] : K[pivot[row],pivot[col]]+elemStiffMat[elem][row,col])$
        
B: zeromatrix(length(nodalCoord),1)$
B[11,1]:F$

Einarbeitung der Randbedingungen

Die Randbedingungen arbeiten wir hier durch das Streichen der passenden Zeilen für $\delta U_{1,0},\delta W_{1,0},\delta U_{2,0},\delta W_{2,0}$ sowie der passenden Spalten für $U_{1,0},W_{1,0},U_{2,0},W_{2,0}$ ein.

Das resultierende Gleichungssystem ist dies:

$\left(\begin{array}{cccccccc}\frac{2A^{2}E\eta }{3{\ell }_0}& 0& 0& -\left(\frac{2A^{2}E\eta }{{\ell }_0^2}\right)& \frac{A^{2}E\eta }{3{\ell }_0}& 0& 0& 0\\ 0& \frac{2A^{2}E\eta }{3{\ell }_0}& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\right)& -\left(\frac{A^{2}E\eta }{4{\ell }_0^2}\right)& \frac{A^{2}E\eta }{6{\ell }_0}& 0& -\left(\frac{A^{2}E\eta }{2{\ell }_0^2}\right)& \frac{A^{2}E\eta }{6{\ell }_0}\\ 0& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\right)& \frac{3A^{2}E\eta +{\ell }_0^{2}AE}{2{\ell }_0^3}+\frac{2AE}{{\ell }_0}& 0& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{2{\ell }_0^2}\right)& -\left(\frac{3A^{2}E\eta +{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\right)\\ -\left(\frac{2A^{2}E\eta }{{\ell }_0^2}\right)& -\left(\frac{A^{2}E\eta }{4{\ell }_0^2}\right)& 0& \frac{A^{2}E\eta +3{\ell }_0^{2}AE}{2{\ell }_0^3}+\frac{8A^{2}E\eta }{{\ell }_0^3}& -\left(\frac{2A^{2}E\eta }{{\ell }_0^2}\right)& \frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}& -\left(\frac{A^{2}E\eta +3{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{A^{2}E\eta }{4{\ell }_0^2}\\ \frac{A^{2}E\eta }{3{\ell }_0}& \frac{A^{2}E\eta }{6{\ell }_0}& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{2{\ell }_0^2}\right)& -\left(\frac{2A^{2}E\eta }{{\ell }_0^2}\right)& \frac{4A^{2}E\eta }{3{\ell }_0}& \frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}& -\left(\frac{A^{2}E\eta }{4{\ell }_0^2}\right)& \frac{A^{2}E\eta }{6{\ell }_0}\\ 0& 0& -\left(\frac{3A^{2}E\eta +{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}& \frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}& \frac{3A^{2}E\eta +{\ell }_0^{2}AE}{4{\ell }_0^3}+\frac{AE}{{\ell }_0}& -\left(\frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\\ 0& -\left(\frac{A^{2}E\eta }{2{\ell }_0^2}\right)& \frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}& -\left(\frac{A^{2}E\eta +3{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& -\left(\frac{A^{2}E\eta }{4{\ell }_0^2}\right)& -\left(\frac{\sqrt{3}{A}^{2}E\eta -\sqrt{3}{\ell }_0^{2}AE}{4{\ell }_0^3}\right)& \frac{A^{2}E\eta +3{\ell }_0^{2}AE}{4{\ell }_0^3}+\frac{A^{2}E\eta }{{\ell }_0^3}& -\left(\frac{3A^{2}E\eta }{4{\ell }_0^2}\right)\\ 0& \frac{A^{2}E\eta }{6{\ell }_0}& -\left(\frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}\right)& \frac{A^{2}E\eta }{4{\ell }_0^2}& \frac{A^{2}E\eta }{6{\ell }_0}& \frac{\sqrt{3}{A}^{2}E\eta }{4{\ell }_0^2}& -\left(\frac{3A^{2}E\eta }{4{\ell }_0^2}\right)& \frac{2A^{2}E\eta }{3{\ell }_0}\end{array}\right)\cdot \left(\begin{array}{c}{\mathrm{\Phi }}_{1,0}\\ {\mathrm{\Phi }}_{2,0}\\ W_{3,0}\\ U_{3,0}\\ {\mathrm{\Phi }}_{3,0}\\ W_{4,0}\\ U_{4,0}\\ {\mathrm{\Phi }}_{4,0}\end{array}\right)=\left(\begin{array}{c}0\\ 0\\ 0\\ 0\\ 0\\ F\\ 0\\ 0\end{array}\right)$

/*-----------------------------------*/
/* boundary conditions */
K: submatrix(1,2,4,5,K,1,2,4,5)$
X: submatrix(1,2,4,5,transpose(nodalCoord))$
B: submatrix(1,2,4,5,B)$
print(K,"*",X,"=",B)$

Solving

Das Ergebnis ist - für die gleichen Parameter wie in Aufgabe StaB:

$\begin{array}{l}{U}_{1,0}=0\\ W_{1,0}=0\\ {\mathrm{\Phi }}_{1,0}=3.97\frac{F}{E{a}^2}\\ U_{2,0}=0\\ W_{2,0}=0\\ {\mathrm{\Phi }}_{2,0}=2.45\frac{F}{E{a}^2}\\ U_{3,0}=57.7\frac{F}{Ea}\\ W_{3,0}=1.67\cdot 10^2\frac{F}{Ea}\\ {\mathrm{\Phi }}_{3,0}=2.06\frac{F}{E{a}^2}\\ U_{4,0}=-57.7\frac{F}{Ea}\\ W_{4,0}=3.67\cdot 10^2\frac{F}{Ea}\\ {\mathrm{\Phi }}_{4,0}=3.12\frac{F}{E{a}^2}\end{array}$

/*-----------------------------------*/
/* solving                           */
sol: ratsimp(linsolve_by_lu(K,B)[1]);
sol: append(makelist([U[1,0],W[1,0],U[2,0],W[2,0]][i]=0,i,1,4),makelist(X[i][1]=sol[i][1],i,1,length(X)));
sol: makelist(nodalCoord[i]=subst(sol,nodalCoord[i]),i,1,length(nodalCoord));

fpprintprec: 3;
print(transpose(float(subst(η=1,subst(moreParams,sol)))))$

Post-Processing

Mit diesen Ergebnissen können wir nun das Stabwerk in seiner verformten Konfiguration zeichnen.

Stabwerk in verformter Konfiguration.

Für die Darstellung müssen wir die Koodinaten der Verschiebung in die lokalen Koordinatensysteme zurücktransformieren - und das geht wieder über die Euler-Drehmatrizen (s.o.).

Da die Koordinaten der Verschiebung im globalen Koordinatensystem die gleichen sind wie in Aufgabe StaB, sind auch die Verläufe der Schnittlasten in den Stäben identisch - wir brauchen also die Ergebnisse nicht noch einmal aufzutragen.

/*-----------------------------------*/
/*-----------------------------------------------------*/
/* post-processing: show deformed structure            */

/* employ these Trial-Functions - shared from FEM      */
φ : [      (ξ-1)^2*(2*ξ+1),
      ℓ[i]* ξ     *(  ξ-1)^2,
     -      ξ^2   *(2*ξ-3), 
      ℓ[i]* ξ^2   *(  ξ-1)];

/* construct u[i](x[i]),w[i](x[i])                     */
/* step 1: re-construct local nodal-coordinates (DI(α))*/
/* step 2: use trial function to derive u[i],w[i]      */
/* step 3: transform into global coordinates (DR(α))   */
sol: ratsimp(subst([η=1],subst(moreParams,sol)))$

fct:[]$
for e:1 thru 4 do
   (I: index[e][2][1],
    J: index[e][2][2],
    locals: [subst(params,matrix([U[I,e]],[W[I,e]],[Φ[I,e]])=DI(index[e][1]).matrix([U[I,0]],[W[I,0]],[Φ[I,0]])),
             subst(params,matrix([U[J,e]],[W[J,e]],[Φ[J,e]])=DI(index[e][1]).matrix([U[J,0]],[W[J,0]],[Φ[J,0]]))],
    trafo: flatten(makelist(makelist(lhs(locals[j])[i][1]=rhs(locals[j])[i][1],i,1,3),j,1,2)),
    /* ξ for x-Axis .....                              */
    localFct:matrix([ξ*ℓ[i]/ℓ[0] + U[I,e]*(1-ξ)+ U[J,e]  *ξ ],
                    [              W[I,e]*φ[1] + Φ[I,e]*φ[2]+W[J,e]*φ[3]+Φ[J,e]*φ[4]],[1]),
    localFct: subst(trafo,localFct),	    
    localFct: subst(params,subst([i=e],DR(index[e][1]).localFct)),
    fct: append(fct,[flatten(makelist(localFct[i],i,1,2))]))$

/* choose scale of deflection                          */
scale: [E=1000*F/a];
fct: float(expand(subst([scale],subst(moreParams,subst(params,subst(sol,fct))))));

/* and plot .....                                      */
toPlot: makelist([parametric, nodes[i][1] + fct[i][1],
                              nodes[i][2] + fct[i][2], [ξ,0,1]],i,1,4);
plot2d(toPlot, [legend,"Stab 1","Stab 2","Stab 3","Stab 4"]);

---

Links

• * Gelöste_Aufgaben / StaB

Literature

• ...