Gelöste Aufgaben/Kw99

Aufgabenstellung

Ein Stab ABC ist durch eine lineare veränderliche Streckenlast q mit den Eckwerten q_A in A und q_B in B sowie dem Moment M_B in B belastet. Der Stab (E-Modul: E) besteht aus zwei Sektionen mit den Längen l₁ bzw. l₂ sowie den Flächenmomenten I₁ bzw. I₂. Der Stab ist in A durch ein gelenkiges Festlager, in C durch eine Schiebehülse gelagert, in B sind die beiden Sektionen fest miteinander verbunden. Die Feder in A ist eine Drehfester mit Steifigkeit K_A, die Federn in B und C sind Translationsfedern mit den Steifigkeiten k_B, k_C.

Lageplan

Gesucht ist die analytische Lösung für den Euler-Bernoulli-Balken. Im Vergleich zu Kw98 wird hier eine Lösung mit normierten Koordinaten verfolgt.

Ermitteln Sie für ein Euler-Bernoulli-Modell die analytischen Verläufe der Schnittgrößen und Verschiebungen im Balken für diese Parameter:

$\begin{array}{ll}{{E}{I}}_2& =\frac{{{E}{I}}_1}{2},\\ K_A& =\frac{{{E}{I}}_1}{{\ell }_1},\\ k_B& =0,\\ k_C& =\frac{{{E}{I}}_1}{{\ell }_1^3},\\ q_B& =4\cdot q_A,\\ {\ell }_2& =\frac{{\ell }_1}{2},\\ M_B& =5\cdot {\ell }_1^2\cdot q_A\end{array}$.

Lösung mit Maxima

Die Aufgabe ist ein klassisches Randwertproblem:

1. zwei Gebiete, in denen ein Euler-Bernoulli-Balken in AB und BC durch eine Streckenlast q belastet ist (in Bereich II ist die Streckenlast allerdings Null) und somit durch die Differentialbeziehung

   $E{I}_i{w}_i^{IV}(x_i)=q(x_i),i=\{1,2\}$

   berschrieben wird.
2. Rand- und Übergangsbedingungen in den Punkten A, B, C

Wir verwenden x_i und ξ_i als Koordinaten je Bereich, in der Übersicht sieht das Randwertproblem so aus:

Rand A	Bereich I	Übergang B	Bereich II	Rand C

Header

Diese Aufgabe wird mit der Methode der Finiten Elemente in KW96 gelöst. Und im Vergleich zu KW98 wird hier die analytische Lösung mit dimensionslosen Koordinaten angeschreiben.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 15.08.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2017-09-06                            */
/* ref: TM-C, Labor 1 - dimensionslos                  */
/* description: die Auslenkung w und die unabhängige   */
/*              Ortskoordinate werden dim'los gemacht  */
/*******************************************************/

Declarations

Wir definieren die Formfunktionen für die Streckenlast

$\begin{array}{l}{\varphi }_0\left(\xi \right):=1-\xi \\ {\varphi }_1\left(\xi \right):=\xi \end{array}\text{ mit }\xi =\frac{x_1}{{\ell }_1}$.

/* system parameter */
params: [EI[2]=EI[1]/2,
         K[A]=EI[1]/l[1],
         k[B]=0,
         k[C] = EI[1]/l[1]^3,
         q[B]=4*q[A],
         l[2]=l[1]/2,
         M[B] = 5*q[A]*l[1]^2];

/* form - functions  */
phi[0](xi) := 1 - xi;
phi[1](xi) :=     xi;

Integration of Differential Equation to Formfunction

In Bereich I und II gilt dieselbe Bewegungs-Differentialgleichung

$E{I}_i{w}_i^{IV}(x_i)=q(x_i),i=\{1,2\}\text{ mit }q(x_i)=q_0\cdot {\varphi }_0(\xi )+q_1\cdot {\varphi }_1(\xi )$,

die wir durch Integration lösen und dann bereichsweise an Rand- und Übergangsbedingungen anpassen. Diese Aufgabe wird etwas übersichtlicher, wenn wir die Auslenkung w und die Ortskoordinate x dimensionslos machen. So wählen wir:

$w={\ell }_{Bez}\cdot \tilde{w}$

und setzten für die Bezugslänge die Auslenkung eines Kragbalkens unter konstanter Streckenlast (hier q_A) an. Diese Auslenkung findet man in Standard-Lösungen unter "Kragbalken mit Streckenlast" zu:

${\ell }_{{B}{e}{z}}=\frac{q_A\cdot {\ell }_1^4}{8\cdot {{E}{I}}_1}$

Zusätzlich wählen wir zwei unabhängige, dimensionslose Ortskoordinaten für die Bereich I und II, die ihren Ursprung jeweils in den Punkten A und B haben.

${\xi }_i=\frac{x_i}{{\ell }_i}$

Mit

$\begin{array}{lll}{q}_0=q_A,& q_1=q_B& \text{ für Bereich I und}\\ q_0=0,& q_1=0& \text{ für Bereich II}\end{array}$

ist die allgemeine Lösung für

$\begin{array}{ll}\dots \text{ die Verdrehung: }& {\varphi }_i(x)=\frac{d{w}_i(x)}{d{x}_i}\\ \dots \text{ das Biege-Moment: }& M_i(x)=-E{I}_i\frac{d^2{w}_i(x)}{d{x}_i^2}\\ \dots \text{ die Querkraft: }& Q_i(x)=-E{I}_i\frac{d^3{w}_i(x)}{d{x}_i^3}\end{array}$

... für Bereich I:

$\begin{array}{ll}{w}_1\left(\xi \right):=& \frac{120\cdot C_{1,0}\cdot {\ell }_{{B}{e}{z}}+120\cdot C_{1,1}\cdot {\ell }_{{B}{e}{z}}\cdot \xi +60\cdot C_{1,2}\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^2+20\cdot C_{1,3}\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^3+(5\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^4-{\ell }_{{B}{e}{z}}\cdot {\xi }^5)\cdot q_A+{\ell }_{{B}{e}{z}}\cdot {\xi }^5\cdot q_B}{15\cdot q_A}\\ {\varphi }_1\left(\xi \right):=& \frac{120\cdot C_{1,1}\cdot {\ell }_{{B}{e}{z}}+120\cdot C_{1,2}\cdot {\ell }_{{B}{e}{z}}\cdot \xi +60\cdot C_{1,3}\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^2+(20\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^3-5\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^4)\cdot q_A+5\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^4\cdot q_B}{15\cdot {\ell }_1\cdot q_A}\\ M_1\left(\xi \right):=& -\frac{{{E}{I}}_1\cdot (120\cdot C_{1,2}\cdot {\ell }_{{B}{e}{z}}+120\cdot C_{1,3}\cdot {\ell }_{{B}{e}{z}}\cdot \xi +(60\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^2-20\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^3)\cdot q_A+20\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^3\cdot q_B)}{15\cdot {\ell }_1^2\cdot q_A}\\ Q_1\left(\xi \right):=& -\frac{{{E}{I}}_1\cdot (120\cdot C_{1,3}\cdot {\ell }_{{B}{e}{z}}+(120\cdot {\ell }_{{B}{e}{z}}\cdot \xi -60\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^2)\cdot q_A+60\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^2\cdot q_B)}{15\cdot {\ell }_1^3\cdot q_A}\end{array}$

... für Bereich II:

$\begin{array}{ll}{w}_2\left(\xi \right):=& \frac{24\cdot {{E}{I}}_1\cdot {\ell }_2^4\cdot C_{2,0}\cdot {\ell }_{{B}{e}{z}}+24\cdot {{E}{I}}_1\cdot {\ell }_2^4\cdot C_{2,1}\cdot {\ell }_{{B}{e}{z}}\cdot \xi +12\cdot {{E}{I}}_1\cdot {\ell }_2^4\cdot C_{2,2}\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^2+4\cdot {{E}{I}}_1\cdot {\ell }_2^4\cdot C_{2,3}\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^3}{3\cdot {\ell }_1^4\cdot {{E}{I}}_2\cdot q_A}\\ {\varphi }_2\left(\xi \right):=& \frac{24\cdot {{E}{I}}_1\cdot {\ell }_2^4\cdot C_{2,1}\cdot {\ell }_{{B}{e}{z}}+24\cdot {{E}{I}}_1\cdot {\ell }_2^4\cdot C_{2,2}\cdot {\ell }_{{B}{e}{z}}\cdot \xi +12\cdot {{E}{I}}_1\cdot {\ell }_2^4\cdot C_{2,3}\cdot {\ell }_{{B}{e}{z}}\cdot {\xi }^2}{3\cdot {\ell }_1^4\cdot {\ell }_2\cdot {{E}{I}}_2\cdot q_A}\\ M_2\left(\xi \right):=& -\frac{24\cdot {{E}{I}}_1\cdot {\ell }_2^4\cdot C_{2,2}\cdot {\ell }_{{B}{e}{z}}+24\cdot {{E}{I}}_1\cdot {\ell }_2^4\cdot C_{2,3}\cdot {\ell }_{{B}{e}{z}}\cdot \xi }{3\cdot {\ell }_1^4\cdot {\ell }_2^2\cdot q_A}\\ Q_2\left(\xi \right):=& -\frac{8\cdot {{E}{I}}_1\cdot {\ell }_2\cdot C_{2,3}\cdot {\ell }_{{B}{e}{z}}}{{\ell }_1^4\cdot q_A}\end{array}$.

/* solve ....*/
dimless : l[Bez] = q[A]*l[1]^4/(8*EI[1]);
dgl : EI[i]*l[Bez]*diff(w(xi),xi,4)/l[i]^4 = q[0]*phi[0](xi) + q[1]*phi[1](xi);
dgl: subst(dimless,dgl);

/* generic solution */
displ : solve(integrate(integrate(integrate(integrate(dgl,xi),xi),xi),xi),w(xi));
sections: [[i=1, %c4=C[1,0], %c3=C[1,1], %c2=C[1,2], %c1=C[1,3], q[0]=q[A], q[1]=q[B]],
           [i=2, %c4=C[2,0], %c3=C[2,1], %c2=C[2,2], %c1=C[2,3], q[0]= 0  , q[1]= 0  ]];

/* section I */
define(  w[1](xi),  ratsimp(subst(sections[1],subst(displ,l[Bez]*w(xi)))));
define(Phi[1](xi),        diff(w[1](xi),xi  )/l[1]^1);
define(  M[1](xi), -EI[1]*diff(w[1](xi),xi,2)/l[1]^2);
define(  Q[1](xi), -EI[1]*diff(w[1](xi),xi,3)/l[1]^3);

/* section II */
define(  w[2](xi),  ratsimp(subst(sections[2],subst(displ,l[Bez]*w(xi)))));
define(Phi[2](xi),        diff(w[2](xi),xi  )/l[2]^1);
define(  M[2](xi), -EI[2]*diff(w[2](xi),xi,2)/l[2]^2);
define(  Q[2](xi), -EI[2]*diff(w[2](xi),xi,3)/l[2]^3);

Boundary Conditions

Für die 2*4 = 8 Integrationskonstanten

$[C_{1,0},C_{1,1},C_{1,2},C_{1,3},C_{2,0},C_{2,1},C_{2,2},C_{2,3}]$

suchen wir jetzt die passenden Gleichungen aus Rand- und Übergangsbedingungen.

Zur besseren Übersicht nennen wir die Schnitt-Momente und -Kräfte nach den jeweiligen Knotenpunkten A, B, C und fügen als Index ein + / - hinzu, um die Seite (+: rechts vom Knoten, -: links vom Knoten) zu kennzeichnen.

Aus Rand "A"

Geometrische Randbedingungen $w_1(0)=0$ Kraft- und Momenten-Randbedingungen $K_A\cdot {\varphi }_A+M_{A,+}=0\text{ mit }{M}_{A,+}=-E{I}_1\cdot w^{″}(x){|}_{x=0}$

Aus Übergang "B"

Geometrische Randbedingungen $w_1({\ell }_1)=w_2({\ell }_1)$ ${\varphi }_1({\ell }_1)={\varphi }_2({\ell }_1)$ Kraft- und Momenten-Randbedingungen $-M_{B,-}-M_B+M_{B,+}=0$ $-Q_{B,-}-k_B\cdot w_B+-Q_{B,+}=0$

Aus Rand "C"

Geometrische Randbedingungen ${\varphi }_2({\ell }_2)=0$ Kraft- und Momenten-Randbedingungen $-Q_{C,-}-k_C\cdot w_C=0$

Und das liefert das Gleichungssystem aus 8 Gleichungen

$\begin{array}{ccc}{C}_{1,0}& =& 0\\ \frac{{\ell }_1\cdot C_{1,1}\cdot K_A}{{{E}{I}}_1}-C_{1,2}& =& 0\\ \frac{q_B}{120}+\frac{q_A}{30}+\frac{C_{1,3}}{6}+\frac{C_{1,2}}{2}+C_{1,1}+C_{1,0}& =& \frac{{{E}{I}}_1\cdot {\ell }_2^4\cdot C_{2,0}}{{\ell }_1^4\cdot {{E}{I}}_2}\\ \frac{q_B}{24}+\frac{q_A}{8}+\frac{C_{1,3}}{2}+C_{1,2}+C_{1,1}& =& \frac{{{E}{I}}_1\cdot {\ell }_2^3\cdot C_{2,1}}{{\ell }_1^3\cdot {{E}{I}}_2}\\ \frac{q_B}{2}-\frac{{\ell }_2^4\cdot C_{2,0}\cdot k_B}{{\ell }_1\cdot {{E}{I}}_2}+\frac{q_A}{2}-\frac{{\ell }_2\cdot C_{2,3}}{{\ell }_1}+C_{1,3}& =& 0\\ -\frac{M_B}{{\ell }_1^2}+\frac{q_B}{6}+\frac{q_A}{3}-\frac{{\ell }_2^2\cdot C_{2,2}}{{\ell }_1^2}+C_{1,3}+C_{1,2}& =& 0\\ \frac{{\ell }_2^3\cdot C_{2,3}}{2\cdot {\ell }_1^3}+\frac{{\ell }_2^3\cdot C_{2,2}}{{\ell }_1^3}+\frac{{\ell }_2^3\cdot C_{2,1}}{{\ell }_1^3}& =& 0\\ -\frac{{\ell }_2^4\cdot C_{2,3}\cdot k_C}{6\cdot {\ell }_1\cdot {{E}{I}}_2}-\frac{{\ell }_2^4\cdot C_{2,2}\cdot k_C}{2\cdot {\ell }_1\cdot {{E}{I}}_2}-\frac{{\ell }_2^4\cdot C_{2,1}\cdot k_C}{{\ell }_1\cdot {{E}{I}}_2}-\frac{{\ell }_2^4\cdot C_{2,0}\cdot k_C}{{\ell }_1\cdot {{E}{I}}_2}+\frac{{\ell }_2\cdot C_{2,3}}{{\ell }_1}& =& 0\end{array}$

für die Integrationskonstanten.

/* boundary conditions */
node[A]: [ w[1](0) = 0,
           K[A]*Phi[1](0)+M[1](0) = 0];
node[B]: [ w[1](1) = w[2](0),
           Phi[1](1) = Phi[2](0),
          -Q[1](1) -k[B]*w[2](0) +Q[2](0) = 0,
          -M[1](1) -M[B]+M[2](0) = 0];
node[C]: [ Phi[2](1) = 0,
          -Q[2](1) - k[C]*w[2](1) = 0];
BCs : expand(subst(dimless,append(node[A],node[B],node[C])));         
scale: [EI[1]/l[1]^4, 1/l[1]^2, EI[1]/l[1]^4, EI[1]/l[1]^3,1/l[1], 1/l[1]^2, EI[2]/l[1]^3, 1/l[1]];
BCs : expand(scale*BCs);

Prepare for Solver

Das Gleichungssystem wollen wir als

$\underset{\_}{\underset{\_}{A}}\cdot \underset{\_}{x}=\underset{\_}{b}$

schreiben, also - hier nach Einsetzen der System-Parameter

$\left(\begin{array}{cccccccc}1& 0& 0& 0& 0& 0& 0& 0\\ 0& 1& -1& 0& 0& 0& 0& 0\\ 1& 1& \frac{1}{2}& \frac{1}{6}& -\frac{1}{8}& 0& 0& 0\\ 0& 1& 1& \frac{1}{2}& 0& -\frac{1}{4}& 0& 0\\ 0& 0& 0& 1& 0& 0& 0& -\frac{1}{2}\\ 0& 0& 1& 1& 0& 0& -\frac{1}{4}& 0\\ 0& 0& 0& 0& 0& \frac{1}{8}& \frac{1}{8}& \frac{1}{16}\\ 0& 0& 0& 0& -\frac{1}{8}& -\frac{1}{8}& -\frac{1}{16}& \frac{23}{48}\end{array}\right)\cdot \underset{\_}{x}=\left(\begin{array}{c}0\\ 0\\ -\frac{q_A}{15}\\ -\frac{7\cdot q_A}{24}\\ -\frac{5\cdot q_A}{2}\\ 4\cdot q_A\\ 0\\ 0\end{array}\right)$

/* integration constants = unknowns */
ICs : [C[1,0],C[1,1],C[1,2],C[1,3],C[2,0],C[2,1],C[2,2],C[2,3]];
ACM: augcoefmatrix(BCs,ICs);
/* system matrix and rhs */
AA :   submatrix(ACM,9);
bb : - col(ACM,9);
/* print OLE */
print(subst(params,AA),"*",x,"=",subst(params,bb));

Solving

Das Lösen des Gleichungssystems liefert

$\begin{array}{l}{C}_{1,0}=0,\\ C_{1,1}=\frac{1331\cdot q_A}{1170},\\ C_{1,2}=\frac{1331\cdot q_A}{1170},\\ C_{1,3}=-\frac{257\cdot q_A}{1365},\\ C_{2,0}=\frac{57058\cdot q_A}{4095},\\ C_{2,1}=\frac{81007\cdot q_A}{8190},\\ C_{2,2}=-\frac{9994\cdot q_A}{819},\\ C_{2,3}=\frac{6311\cdot q_A}{1365}\end{array}$

/* solving */
D : ratsimp(determinant(AA))$
[ P, L, U] : ratsimp(get_lu_factors(lu_factor(AA)))$
cc : ratsimp(linsolve_by_lu(AA,bb)[1])$
sol : makelist(ICs[i] = cc[i][1],i,1,8)$

Post-Processing

Und die Ergebnisse können wir uns anschauen ...

... für w(x):

Biegelinie w(x)

... für Φ(x):

Kippung w'(x)

... für M(x):

Biegemoment M(x)

... für Q(x):

Querkraft Q(x)

... für die Lager-Reaktionskräfte:

$\begin{array}{ll}{A}_z& =\frac{257\cdot {\ell }_1\cdot q_A}{1365},\\ M_A& =\frac{1331\cdot {\ell }_1^2\cdot q_A}{1170},\\ B_z& =0,\\ C_z& =\frac{6311\cdot {\ell }_1\cdot q_A}{2730},\\ M_C& =\frac{31037\cdot {\ell }_1^2\cdot q_A}{16380}\end{array}$

/* bearing forces and moments */
reactForces: [A[z] = Q[1](0),
              M[A] = K[A]*Phi[1](0),
              B[z] = k[B]*w[2](0),
              C[z] = k[C]*w[2](1),
              M[C] = M[2](1)];

expand(subst(dimless,subst(params,subst(sol, reactForces))));

/* plot displacements */

fcts: [[ w [1](xi), w [2](xi)],
       [Phi[1](xi),Phi[2](xi)],
       [ M [1](xi), M [2](xi)],
       [ Q [1](xi), Q [2](xi)]];
facts: [1/l[Bez], l[1]/l[Bez], 1/(q[A]*l[1]^2), 1/(q[A]*l[1])];

textlabels : ["w(x)/(M[B]*l^2/EI[1])→", "w'(x)/(M[B]*l/EI[1])→", "M(x)/M[B]→", "Q(x)/(M[B]/l[1]→"];
for i: 1 thru 4 do(
  f : expand(subst(dimless,subst(params,facts[i]*[subst(sol, fcts[i][1]),
                                                  subst(sol, fcts[i][2])]))),
  r : subst(params,l[2]/l[1]),                                          
  preamble: if i<=2 then "set yrange [] reverse" else "set yrange []",
  plot2d([[parametric,     t, subst(t,xi,f[1]), [t,0,1]],
          [parametric, 1+r*t, subst(t,xi,f[2]), [t,0,1]]],
                             [legend, "sec. I", "sec. II"],
                             [gnuplot_preamble, preamble],
                             [xlabel, "x/l[1] ->"],
                             [ylabel, textlabels[i]]))$

---

Links

• ...

Literature

• ...