Gelöste Aufgaben/Kw98

Aufgabenstellung

Ein Stab ABC ist durch eine lineare veränderliche Streckenlast q mit den Eckwerten q_A in A und q_B in B sowie dem Moment M_B in B belastet. Der Stab (E-Modul: E) besteht aus zwei Sektionen mit den Längen l₁ bzw. l₂ sowie den Flächenmomenten I₁ bzw. I₂. Der Stab ist in A durch ein gelenkiges Festlager, in C durch eine Schiebehülse gelagert, in B sind die beiden Sektionen fest miteinander verbunden. Die Feder in A ist eine Drehfester mit Steifigkeit K_A, die Federn in B und C sind Translationsfedern mit den Steifigkeiten k_B, k_C.

Gesucht ist die analytische Lösung für den Euler-Bernoulli-Balken.

Ermitteln Sie für ein Euler-Bernoulli-Modell die analytischen Verläufe der Schnittgrößen und Verschiebungen im Balken für diese Parameter:

Lösung mit Maxima

Die Aufgabe ist ein klassisches Randwertproblem:

zwei Gebiete, in denen ein Euler-Bernoulli-Balken in AB und BC durch eine Streckenlast q belastet ist (in Bereich II ist die Streckenlast allerdings Null) und somit durch die Differentialbeziehung
$E I_{i} w_{i}^{I V} (x_{i}) = q (x_{i}), i = {1, 2}$
berschrieben wird.
Rand- und Übergangsbedingungen in den Punkten A, B, C

Wir verwenden x_i und ξ_i als Koordinaten je Bereich, in der Übersicht sieht das Randwertproblem so aus:

Rand A	Bereich I	Übergang B	Bereich II	Rand C

Header

Diese Aufgabe mit der Methode der Finiten Elemente in KW96 gelöst.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 15.08.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2017-09-06                            */
/* ref: TM-C, Labor 1                                  */
/* description                                         */
/*                                                     */
/*******************************************************/

Declarations

Wir definieren die Parameter

\begin{array}{l} q_{A} = \frac{3 \cdot k N}{m}, \\ l_{1} = \frac{7 \cdot m}{10}, \\ E I_{1} = 33600 N m^{2}, \\ l_{2} = \frac{21 m}{40}, \\ E I_{2} = 16800 N m^{2}, \\ K_{A} = 96 k N m, \\ k_{C} = \frac{22 k N}{m}, \\ k_{B} = \frac{98 k N}{m}, \\ q_{B} = \frac{12 N}{m m}, \\ M_{B} = 1470 N m \end{array}

.

und die Formfunktionen für die Streckenlast

\begin{array}{l} ϕ_{0} (ξ) : = 1 - ξ \\ ϕ_{1} (ξ) : = ξ \end{array}

.

/* system parameter */
units  : [mm = m/1000, cm = m/100];
params : [q[A]=3*N/mm, l[1]=700*mm, EI[1] = 2.1*10^11*N/m^2 * 3*cm*(4*cm)^3/12];
simple : [l[2] = 3/4*l[1], EI[2] = EI[1]/2,
          K[A]=2*EI[1]/l[1], k[C] = 512/229*EI[1]/l[1]^3, k[B] = EI[1]/l[1]^3, 
          q[B] = 4*q[A], M[B] = q[A]*l[1]^2];

params : append(params,makelist(lhs(simple[i])=subst(params,rhs(simple[i])),i,1,length(simple)));
params : subst(units,params);

/* form - functions  */
phi[0](xi) := 1 - xi;
phi[1](xi) :=     xi;

Formfunctions

In Bereich I und II gilt dieselbe Bewegungs-Differentialgleichung

E I_{i} w_{i}^{I V} (x_{i}) = q (x_{i}), i = {1, 2} mit q (x_{i}) = q_{0} \cdot ϕ_{0} (ξ) + q_{1} \cdot ϕ_{1} (ξ)

,

die wir durch Integration lösen und dann bereichsweise anpassen.

So gilt für Bereich II: q₀ = 0 und q₁ = 0.

Die allgemeine Lösung ist mit

ϕ_{i} (x) = \frac{d w (x)}{d x}

... für Bereich I:

\begin{array}{l} w_{1} (x) : = \frac{120 \cdot l_{1} \cdot C_{1, 0} + 120 \cdot l_{1} \cdot C_{1, 1} \cdot x + 60 \cdot l_{1} \cdot C_{1, 2} \cdot x^{2} + 20 \cdot l_{1} \cdot C_{1, 3} \cdot x^{3} + 5 \cdot l_{1} \cdot x^{4} \cdot q_{A} + x^{5} \cdot (q_{B} - q_{A})}{120 \cdot l_{1} \cdot {E I}_{1}} \\ ϕ_{1} (x) : = \frac{120 \cdot l_{1} \cdot C_{1, 1} + 120 \cdot l_{1} \cdot C_{1, 2} \cdot x + 60 \cdot l_{1} \cdot C_{1, 3} \cdot x^{2} + 20 \cdot l_{1} \cdot x^{3} \cdot q_{A} + 5 \cdot x^{4} \cdot (q_{B} - q_{A})}{120 \cdot l_{1} \cdot {E I}_{1}} \\ M_{1} (x) : = - \frac{120 \cdot l_{1} \cdot C_{1, 2} + 120 \cdot l_{1} \cdot C_{1, 3} \cdot x + 60 \cdot l_{1} \cdot x^{2} \cdot q_{A} + 20 \cdot x^{3} \cdot (q_{B} - q_{A})}{120 \cdot l_{1}} \\ Q_{1} (x) : = - \frac{120 \cdot l_{1} \cdot C_{1, 3} + 120 \cdot l_{1} \cdot x \cdot q_{A} + 60 \cdot x^{2} \cdot (q_{B} - q_{A})}{120 \cdot l_{1}} \end{array}

... für Bereich II:

\begin{array}{l} w_{2} (x) : = \frac{120 \cdot l_{2} \cdot C_{2, 0} + 120 \cdot l_{2} \cdot C_{2, 1} \cdot x + 60 \cdot l_{2} \cdot C_{2, 2} \cdot x^{2} + 20 \cdot l_{2} \cdot C_{2, 3} \cdot x^{3}}{120 \cdot l_{2} \cdot {E I}_{2}} \\ ϕ_{2} (x) : = \frac{120 \cdot l_{2} \cdot C_{2, 1} + 120 \cdot l_{2} \cdot C_{2, 2} \cdot x + 60 \cdot l_{2} \cdot C_{2, 3} \cdot x^{2}}{120 \cdot l_{2} \cdot {E I}_{2}} \\ M_{2} (x) : = - \frac{120 \cdot l_{2} \cdot C_{2, 2} + 120 \cdot l_{2} \cdot C_{2, 3} \cdot x}{120 \cdot l_{2}} \\ Q_{2} (x) : = - C_{2, 3} \end{array}

.

/* solve ....*/
dgl : EI[i]*diff(w(x),x,4) = q[0]*phi[0](x/l[i]) + q[1]*phi[1](x/l[i]);
/* generic solution */
displ : solve(integrate(integrate(integrate(integrate(dgl,x),x),x),x),w(x));
sections: [[i=1, %c4=C[1,0], %c3=C[1,1], %c2=C[1,2], %c1=C[1,3], q[0]=q[A], q[1]=q[B]],
           [i=2, %c4=C[2,0], %c3=C[2,1], %c2=C[2,2], %c1=C[2,3], q[0]= 0  , q[1]= 0  ]];

/* section I */
define(  w[1](x),  subst(sections[1],subst(displ,w(x))));
define(Phi[1](x),  diff(w[1](x),x  ));
define(  M[1](x), -EI[1]*diff(w[1](x),x,2));
define(  Q[1](x), -EI[1]*diff(w[1](x),x,3));

/* section II */
define(  w[2](x),  subst(sections[2],subst(displ,w(x))));
define(Phi[2](x),  diff(w[2](x),x  ));
define(  M[2](x), -EI[2]*diff(w[2](x),x,2));
define(  Q[2](x), -EI[2]*diff(w[2](x),x,3));

Boundary Conditions

Für die 2*4 = 8 Integrationskonstanten

[C_{1, 0}, C_{1, 1}, C_{1, 2}, C_{1, 3}, C_{2, 0}, C_{2, 1}, C_{2, 2}, C_{2, 3}]

suchen wir jetzt die passenden Gleichungen aus Rand- und Übergangsbedingungen.

Zur besseren Übersicht nennen wir die Schnitt-Momente und -Kräfte nach den jeweiligen Knotenpunkten A, B, C und fügen als Index ein + / - hinzu, um die Seite (+: rechts vom Knoten, -: links vom Knoten) zu kennzeichnen.

Aus Rand "A"

	Geometrische Randbedingungen $w_{1} (0) = 0$ Kraft- und Momenten-Randbedingungen $K_{A} \cdot ϕ_{A} + M_{A, +} = 0 mit M_{A, +} = - E I_{1} \cdot w^{″} (x) \|_{x = 0}$

Aus Übergang "B"

	Geometrische Randbedingungen $w_{1} (ℓ_{1}) = w_{2} (ℓ_{1})$ $ϕ_{1} (ℓ_{1}) = ϕ_{2} (ℓ_{1})$ Kraft- und Momenten-Randbedingungen $- M_{B, -} - M_{B} + M_{B, +} = 0$ $- Q_{B, -} - k_{B} \cdot w_{B} + - Q_{B, +} = 0$

Aus Rand "C"

	Geometrische Randbedingungen $ϕ_{2} (ℓ_{2}) = 0$ Kraft- und Momenten-Randbedingungen $- Q_{C, -} - k_{C} \cdot w_{C} = 0$

Und das liefert das Gleichungssystem aus 8 Gleichungen

(\begin{matrix} \frac{C_{1, 0}}{{E I}_{1}} = 0 \\ \frac{C_{1, 1} \cdot K_{A}}{{E I}_{1}} - C_{1, 2} = 0 \\ \frac{ℓ_{1}^{4} \cdot q_{B}}{120 \cdot {E I}_{1}} + \frac{ℓ_{1}^{4} \cdot q_{A}}{30 \cdot {E I}_{1}} + \frac{ℓ_{1}^{3} \cdot C_{1, 3}}{6 \cdot {E I}_{1}} + \frac{ℓ_{1}^{2} \cdot C_{1, 2}}{2 \cdot {E I}_{1}} + \frac{ℓ_{1} \cdot C_{1, 1}}{{E I}_{1}} + \frac{C_{1, 0}}{{E I}_{1}} = \frac{C_{2, 0}}{{E I}_{2}} \\ \frac{ℓ_{1}^{3} \cdot q_{B}}{24 \cdot {E I}_{1}} + \frac{ℓ_{1}^{3} \cdot q_{A}}{8 \cdot {E I}_{1}} + \frac{ℓ_{1}^{2} \cdot C_{1, 3}}{2 \cdot {E I}_{1}} + \frac{ℓ_{1} \cdot C_{1, 2}}{{E I}_{1}} + \frac{C_{1, 1}}{{E I}_{1}} = \frac{C_{2, 1}}{{E I}_{2}} \\ \frac{ℓ_{1} \cdot q_{B}}{2} - \frac{C_{2, 0} \cdot k_{B}}{{E I}_{2}} + \frac{ℓ_{1} \cdot q_{A}}{2} - C_{2, 3} + C_{1, 3} = 0 \\ - M_{B} + \frac{ℓ_{1}^{2} \cdot q_{B}}{6} + \frac{ℓ_{1}^{2} \cdot q_{A}}{3} - C_{2, 2} + ℓ_{1} \cdot C_{1, 3} + C_{1, 2} = 0 \\ \frac{ℓ_{2}^{2} \cdot C_{2, 3}}{2 \cdot {E I}_{2}} + \frac{ℓ_{2} \cdot C_{2, 2}}{{E I}_{2}} + \frac{C_{2, 1}}{{E I}_{2}} = 0 \\ - \frac{ℓ_{2}^{3} \cdot C_{2, 3} \cdot k_{C}}{6 \cdot {E I}_{2}} - \frac{ℓ_{2}^{2} \cdot C_{2, 2} \cdot k_{C}}{2 \cdot {E I}_{2}} - \frac{ℓ_{2} \cdot C_{2, 1} \cdot k_{C}}{{E I}_{2}} - \frac{C_{2, 0} \cdot k_{C}}{{E I}_{2}} + C_{2, 3} = 0 \end{matrix})

.

für die Integrationskonstanten.

/* integration constants */
ICs : [C[1,0],C[1,1],C[1,2],C[1,3],C[2,0],C[2,1],C[2,2],C[2,3]];
/* boundary conditions */
node[A]: [ w[1](0) = 0,
           K[A]*Phi[1](0)+M[1](0) = 0];
node[B]: [ w[1](l[1]) = w[2](0),
           Phi[1](l[1]) = Phi[2](0),
          -Q[1](l[1]) -k[B]*w[2](0) +Q[2](0) = 0,
          -M[1](l[1]) -M[B]+M[2](0) = 0];
node[C]: [ Phi[2](l[2]) = 0,
          -Q[2](l[2]) - k[C]*w[2](l[2]) = 0];
BCs : expand(append(node[A],node[B],node[C]));

Prepare for Solver

Das Gleichungssystem wollen wir als

\underline{\underline{A}} \cdot \underline{x} = \underline{b}

schreiben, also

(\begin{matrix} \frac{1}{{E I}_{1}} & 0 & 0 & 0 & 0 & 0 & 0 & 0 \\ 0 & \frac{K_{A}}{{E I}_{1}} & - 1 & 0 & 0 & 0 & 0 & 0 \\ \frac{1}{{E I}_{1}} & \frac{ℓ_{1}}{{E I}_{1}} & \frac{ℓ_{1}^{2}}{2 \cdot {E I}_{1}} & \frac{ℓ_{1}^{3}}{6 \cdot {E I}_{1}} & - \frac{1}{{E I}_{2}} & 0 & 0 & 0 \\ 0 & \frac{1}{{E I}_{1}} & \frac{ℓ_{1}}{{E I}_{1}} & \frac{ℓ_{1}^{2}}{2 \cdot {E I}_{1}} & 0 & - \frac{1}{{E I}_{2}} & 0 & 0 \\ 0 & 0 & 0 & 1 & - \frac{k_{B}}{{E I}_{2}} & 0 & 0 & - 1 \\ 0 & 0 & 1 & ℓ_{1} & 0 & 0 & - 1 & 0 \\ 0 & 0 & 0 & 0 & 0 & \frac{1}{{E I}_{2}} & \frac{ℓ_{2}}{{E I}_{2}} & \frac{ℓ_{2}^{2}}{2 \cdot {E I}_{2}} \\ 0 & 0 & 0 & 0 & - \frac{k_{C}}{{E I}_{2}} & - \frac{ℓ_{2} \cdot k_{C}}{{E I}_{2}} & - \frac{ℓ_{2}^{2} \cdot k_{C}}{2 \cdot {E I}_{2}} & - \frac{ℓ_{2}^{3} \cdot k_{C} - 6 \cdot {E I}_{2}}{6 \cdot {E I}_{2}} \end{matrix}) \cdot \underline{x} = (\begin{matrix} 0 \\ 0 \\ - \frac{ℓ_{1}^{4} \cdot q_{B}}{120 \cdot {E I}_{1}} - \frac{ℓ_{1}^{4} \cdot q_{A}}{30 \cdot {E I}_{1}} \\ - \frac{ℓ_{1}^{3} \cdot q_{B}}{24 \cdot {E I}_{1}} - \frac{ℓ_{1}^{3} \cdot q_{A}}{8 \cdot {E I}_{1}} \\ - \frac{ℓ_{1} \cdot q_{B}}{2} - \frac{ℓ_{1} \cdot q_{A}}{2} \\ M_{B} - \frac{ℓ_{1}^{2} \cdot q_{B}}{6} - \frac{ℓ_{1}^{2} \cdot q_{A}}{3} \\ 0 \\ 0 \end{matrix})

Die Matrix-Elemente sind für die Koeffizientenmatrix

\begin{array}{l} a_{1, 1} = 1 / E I_{1} \\ a_{2, 2} = K_{A} / E I_{1} \\ a_{2, 3} = - 1 \\ a_{3, 1} = 1 / E I_{1} \\ a_{3, 2} = ℓ_{1} / E I_{1} \\ a_{3, 3} = ℓ_{1}^{2} / (2 \cdot E I_{1}) \\ a_{3, 4} = ℓ_{1}^{3} / (6 \cdot E I_{1}) \\ a_{3, 5} = - 1 / E I_{2} \\ a_{4, 2} = 1 / E I_{1} \\ a_{4, 3} = ℓ_{1} / E I_{1} \\ a_{4, 4} = ℓ_{1}^{2} / (2 \cdot E I_{1}) \\ a_{4, 6} = - 1 / E I_{2} \\ a_{5, 4} = 1 \\ a_{5, 5} = - k_{B} / E I_{2} \\ a_{5, 8} = - 1 \\ a_{6, 3} = 1 \\ a_{6, 4} = ℓ_{1} \\ a_{6, 7} = - 1 \\ a_{7, 6} = 1 / E I_{2} \\ a_{7, 7} = ℓ_{2} / E I_{2} \\ a_{7, 8} = ℓ_{2}^{2} / (2 \cdot E I_{2}) \\ a_{8, 5} = - k_{C} / E I_{2} \\ a_{8, 6} = - (ℓ_{2} \cdot k_{C}) / E I_{2} \\ a_{8, 7} = - (ℓ_{2}^{2} \cdot k_{C}) / (2 \cdot E I_{2}) \\ a_{8, 8} = - (ℓ_{2}^{3} \cdot k_{C} - 6 \cdot E I_{2}) / (6 \cdot E I_{2}) \end{array}

und für die rechte Seite

\begin{array}{l} b_{1} = 0 \\ b_{2} = 0 \\ b_{3} = (- (ℓ_{1}^{4} \cdot q_{B}) / (120 \cdot E I_{1})) - (ℓ_{1}^{4} \cdot q_{A}) / (30 \cdot E I_{1}) \\ b_{4} = (- (ℓ_{1}^{3} \cdot q_{B}) / (24 \cdot E I_{1})) - (ℓ_{1}^{3} \cdot q_{A}) / (8 \cdot E I_{1}) \\ b_{5} = (- (ℓ_{1} \cdot q_{B}) / 2) - (ℓ_{1} \cdot q_{A}) / 2 \\ b_{6} = M_{B} - (ℓ_{1}^{2} \cdot q_{B}) / 6 - (ℓ_{1}^{2} \cdot q_{A}) / 3 \\ b_{7} = 0 \\ b_{8} = 0 \end{array}

.

/* augmented coeff matrix */
ACM: augcoefmatrix(BCs,ICs);
AA :   submatrix(ACM,9);
bb : - col(ACM,9);

for i: 1 thru 8 do
   print(simplode(["b[",i,"] = ", string(bb[i][1])]))$
for i: 1 thru 8 do
   for j: 1 thru 8 do
      if not AA[i][j] = 0 then
          print(simplode(["A[",i,",",j,"] = ", string(AA[i][j])]))$

Solving

Das Lösen des Gleichungssystems liefert

\begin{array}{l} C_{1, 0} = 0, \\ C_{1, 1} = 246.1 N m^{2}, \\ C_{1, 2} = 703.2 N m, \\ C_{1, 3} = - 2404.3 N, \\ C_{2, 0} = 127.6 N m^{3}, \\ C_{2, 1} = 224.7 N m^{2}, \\ C_{2, 2} = - 979.8 N m, \\ C_{2, 3} = 2101.8 N \end{array}

.

/* solving */
D : ratsimp(determinant(AA))$
[ P, L, U] : ratsimp(get_lu_factors(lu_factor(AA)))$
cc : ratsimp(linsolve_by_lu(AA,bb)[1])$
sol : makelist(ICs[i] = cc[i][1],i,1,8)$

Post-Processing

Und die Ergebnisse können wir uns anschauen ...

... für w(x):

... für Φ(x):

... für M(x):

... für Q(x):

... für die Lager-Reaktionskräfte:

\begin{array}{l} A_{z} = 2404.3 N, \\ M_{A} = 703.2 N m, \\ B_{z} = 743.9 N, \\ C_{z} = 2101.8 N, \\ M_{C} = - 123.7 N m \end{array}

/* bearing forces and moments */
reactForces: [A[z]=Q[1](0),
              M[A] = K[A]*Phi[1](0),
              B[z] = k[B]*w[2](0),
              C[z] = k[C]*w[2](l[2]),
              M[C] = M[2](l[2])];

expand(subst(params,subst(sol, reactForces)));

/* plot displacements */

fcts: [[ w [1](x), w [2](x-l[1])],
       [Phi[1](x),Phi[2](x-l[1])],
       [ M [1](x), M [2](x-l[1])],
       [ Q [1](x), Q [2](x-l[1])]];
facts: [EI[1]/(l[1]^4*q[A]),EI[1]/(l[1]^3*q[A]),1/(l[1]^2*q[A]),1/(l[1]^1*q[A])];
subst(M[B]/l[1]^2,q[A],facts);
textlabels : ["w(x)/(M[B]*l^2/EI[1])→", "w'(x)/(M[B]*l/EI[1])→", "M(x)/M[B]→", "Q(x)/(M[B]/l[1]→"];
for i: 1 thru 4 do(
  f : expand(subst(simple,subst(xi*l[1],x,facts[i]*[subst(sol, fcts[i][1]),
                                                    subst(sol, fcts[i][2])]))),
  f1 : f[1],  f2 : f[2],
  toplot : [if xi<=1 then f1 else 0,
            if xi < 1 then 0 else f2],
  plot2d(toplot,[xi,0,1+subst(simple,l[2]/l[1])], [legend, "sec. I", "sec. II"],
                             [gnuplot_preamble, "set yrange [] reverse"] ,
                             [xlabel, "x/l[1] ->"],
                             [ylabel, textlabels[i]]))$

Links

...

Literature

...

Gelöste Aufgaben/Kw98

Inhaltsverzeichnis

Aufgabenstellung

Lösung mit Maxima

Header

Declarations

Formfunctions

Boundary Conditions

Aus Rand "A"

Aus Übergang "B"

Aus Rand "C"

Prepare for Solver

Solving

Post-Processing

... für w(x):

... für Φ(x):

... für M(x):

... für Q(x):

... für die Lager-Reaktionskräfte:

Navigationsmenü

Gelöste Aufgaben/Kw98

Aufgabenstellung

Lösung mit Maxima

Header

Declarations

Formfunctions

Boundary Conditions

Aus Rand "A"

Aus Übergang "B"

Aus Rand "C"

Prepare for Solver

Solving

Post-Processing

... für w(x):

... für Φ(x):

... für M(x):

... für Q(x):

... für die Lager-Reaktionskräfte:

Navigationsmenü

Suche