Gelöste Aufgaben/SKER

Aufgabenstellung

Die Bewegung des Dehnstabes wird durch das Zusammenspiel von elastischen Verformungen und Trägheitskräften bestimmt. Man nennt das "Schwingungen von Kontinua" - diese untersuchen wir hier. Der zentrale Aufgabe besteht in der Berechnung der homogenen Lösung - und der Anpassung der Lösungsanteile an die Anfangsbedingungen.

Caption

Gesucht ist analytische Lösung für Schwingungen des Euler-Bernoulli-Balkens beim Loslassen aus der enspannten Ruhelage.

Lösung mit Maxima

Header

Für die mathematische Behandlung - insbesondere der Auflösung quadratischer Gleichungen - setzen wir in Maxima voraus, dass

$E>0,\;\;\;A>0,\;\;\;\ell _{0}>0;$.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 16.04.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2018-01-17                            */
/* ref: oscillations of continuous media               */
/* description: analytic solutioun for Extension Rod   */
/*******************************************************/
 
/* settings */
workdir: "C:\\Users\\X...X\\plots\\";
 
/* assumptions */
assume(E>0,A>0,l[0]>0);

Equations of Motion

In der Gleichgewichtsbeziehung für den Dehnstab setzen wir als eingeprägte, äußere Streckenlast n(x,t) die D'Alembert'sche Trägheitskraft und die Gewichtskraft an, also

$n(x,t)=\varrho \;A\cdot g-\varrho \;A\cdot {\ddot {u}}(x,t)$

Die Lösung der partiellen Bewegungsgleichung

$\varrho \,A\cdot {\ddot {u}}-E\,A\cdot u''=\varrho \,A\cdot g$

setzt sich dann aus zwei Lösungsanteilen, der partikularen Lösung u_p und der homogenen Lösung u_h, zusammen; wir schreiben

$u_{t}(x,t)=u_{p}(x,t)+u_{h}(x,t)$.

/*******************************************************/
/* analytical solution for equations of motion               */
eom : 'E*A*diff(u(x,t),x,2)-rho*A*'diff(u(x,t),t,2) = rho*A*g;

Particular Solution

Die partikulare Lösung u_p erfüllt die "rechte Seite" der Bewegungsgleichung, also -ϱ A⋅g:

$E\,A\cdot {u}''_{p}=-\varrho \,A\cdot g$.

Die rechte Seite ist zeit-unveränderlich - so auch die partikulare Lösung:

Wir integrieren die Bewegungsgleichung zwei Mal und erhalten

$\displaystyle A\,E\,\operatorname {u} (x)=-{\frac {A\,g\,\rho \,{{x}^{2}}}{2}}+{{C}_{1}}\,x+{{C}_{0}}$.

Die zwei Integrationskonstanten C_i müssen wir nun an die Randbedingungen

${\begin{array}{rl}u_{p}(0)&=0\\E\,A\,u_{p}'(\ell )&=0\end{array}}$

anpassen, wir erhalten aus dem linearen Gleichungssystem

${\begin{array}{l}0={{C}_{0}}\\0=-A\,g\,\varrho \,x+C_{1}\end{array}}$

und damit die partikulare Lösung

$\displaystyle E\,A\,u_{p}(x)=\varrho \,A\,g\,\ell ^{2}\left(\xi -{\frac {\xi ^{2}}{2}}\right)$

Partikulare Lösung

Die maximale Auslenkung - am rechten Rand - nutzen wir als Bezugslänge

$\displaystyle u_{s}={\frac {\varrho \,A\,g\,\ell ^{2}}{2\;E\,A}}$

Und so sieht u_p aus:

/***************************************************************************/
/* p a r t i c u l a r   s o l u t i o n                                   */
/***************************************************************************/
u[p] : subst([%c1=C[1],%c2=C[0]],integrate(integrate(E*A*diff(u(x),x,2)=-rho*A*g,x),x));
u[p] : subst(solve([subst([x= 0  ,      u(0)         =0], u[p]),
             subst([x=l[0], diff(u(l[0]),l[0])=0],diff(u[p],x))],[C[0],C[1]])[1],u[p]);
u[p] : solve(u[p],u(x));


/* system parameters and dimensionless time tau */
params: [t = T*tau, u[s] = subst([x=l[0]],subst(u[p],u(x)))];

plot2d(ratsimp(subst([x=xi*l[0]],subst(params,subst(u[p],u(x))/u[s]))),[xi,0,1], [y,-0.1,1.1],
                        [legend, "static solution"],
                        [style, [lines,3,1]], [xlabel, "ξ →"], [ylabel, "u →"])$

Homogeneous Solution

Die homogene Bewegungsgleichung

$\varrho \,A\cdot {\ddot {u}}-E\,A\cdot u''=0$

lässt Lösungen vom Typ

$\displaystyle u_{h}(x,t)=U\cdot \sin(\kappa \,x)\cdot \cos(\omega _{0}\,t)$

zu, die alle Rand- und Anfangsbedingungen erfüllen. Eigentlich müsste hier ein $U\cdot e^{j\,\omega _{0}\,t}\cdot e^{\kappa _{0}\,t}$-Ansatz stehen, beim dem auch U komplex wäre. Mit etwas Erfahrung dürfen wir es uns hier einfacher machen.

Einsetzten unseres speziellen Ansatzes liefert

$\displaystyle \kappa ^{2}={\frac {\varrho \,A}{E\,A}}\omega _{0}^{2}$.

Die Anpassung an die Randbedingungen

${\begin{array}{rl}u_{h}(0,t)&=0\\E\,A\,u_{h}(\ell ,,t)&=0\end{array}}$

gestaltet sich einfach: unser besonderer Ansatz erfüllt bereits die erste Randbedingung (sin(0)=0), die zweite Randbedingung cos(κl)=0 ist erfüllt, wenn

$\displaystyle \kappa ={\frac {2\pi \;i-\pi }{2\,\ell }}$,

wir bekommen für jedes i eine Lösung, also unendlich viele.

Zu jedem κ gehört eine Eigenkreisfrequenzen

$\displaystyle \omega _{0}^{2}={\frac {\pi ^{2}\,E}{\varrho \,\ell ^{2}}}\cdot \left(i-{\frac {1}{2}}\right)^{2}$.

Die unterste Eigenfrequenz nutzen wir, um eine Bewegungsgleichungen dimensionslos zu machen: die längste Schwingungsperiode ist damit die Bezugs-Zeit

${\begin{array}{ll}T_{ref}&\displaystyle ={\frac {2\pi }{\omega _{0,1}}}\\&\displaystyle =4\,\ell \,{\sqrt {\frac {\varrho }{E}}}\end{array}}$

Die Lösungen

$\displaystyle {\frac {u_{h,i}(t)}{U_{i}}}=\underbrace {\sin(\kappa _{i}\,x))} _{\displaystyle :=\phi _{i}(x)}\cdot \cos(\omega _{0,i}\,t)$

mit Ihren Modal-Formen ϕ_i und Eigenkreisfreuquenzen ω_0,i sind hier aufgetragen.

Mode	Modalform ϕj	Mode	Modalform ϕj
#1 $\displaystyle \omega _{0,1}=1\cdot {\frac {2\pi }{T}}$		#2 $\displaystyle \omega _{0,2}=3\cdot {\frac {2\pi }{T}}$
#3 $\displaystyle \omega _{0,3}=5\cdot {\frac {2\pi }{T}}$		#4 $\displaystyle \omega _{0,4}=7\cdot {\frac {2\pi }{T}}$
#5 $\displaystyle \omega _{0,5}=9\cdot {\frac {2\pi }{T}}$		#6 $\displaystyle \omega _{0,6}=11\cdot {\frac {2\pi }{T}}$

/***************************************************************************/
/* h o m o g e n e o u s   s o l u t i o n                                 */
/***************************************************************************/
ansatz: u(x,t) = U * sin(kappa*x) * cos(omega[0]*t);
eom : subst(ansatz,eom);
eom : ratsimp(subst(ansatz,ev(eom,nouns)/u(x,t)));
/* boundary conditions */
sol[1] : solve(kappa*l[0] = (2*i-1)*%pi/2,kappa)[1];
sol[1] : [sol[1],ratsimp(solve(subst(sol[1],eom),omega[0]^2)[1])];
 
/* abbreviations */
abbrev : [omega[0,0]=2*%pi/T, omega[0,0]^2= subst([i=1],subst(sol[1],omega[0]^2))];
abbrev : append(abbrev, solve(abbrev,[omega[0,0],T])[2]);
 
/* plot snapshots for animation */
/* create png-figures for animation */
toPlot : makelist(subst([E=1,i=j],subst(abbrev,subst([x=xi*l[0], t=T*tau],
                  subst([omega[0]=sqrt(subst(sol[1],omega[0]^2))],
                                 subst(sol[1],subst([omega[0]*t=2*%pi*tau], 
                                     subst(ansatz,u(x,t)/U))))))),j,1,6);
titles : makelist(simplode(["ω=",sqrt(ratsimp(subst([i=j],subst(abbrev,
                                          subst(sol[1],omega[0]^2*T^2)))))/%pi,"Π"]),j,1,6);
fpprintprec: 3$
NSteps : 19$
for mode:1 thru 6 do
   for j:0 thru NSteps-1 do
      (tstep : simplode([if j<10 then "0" else "",j]),
       plot2d(subst([tau=j/NSteps],toPlot[mode]),[xi,0,1], [y,-1.1,1.1],
                        [title, titles[1]], [legend, simplode(["t/T=",float(j/NSteps+0.01)])],
                        [style, [lines,3,1]], [xlabel, "ξ →"], [ylabel, "u →"],
                        [png_file,simplode([workdir,"mode-",mode,"-step-",tstep,".png"])]))$
 
/* lowest eigenfreuquency */
print(omega[0,0] = sqrt(subst([i=1],subst(sol[1],omega[0]^2))));

Adapt to Initial Conditions

Animation: Loslassen des Systems aus der unverformten Rugelage.

Zum Zeitpunkt t=0 soll

$\underbrace {u_{h}(x,0)} _{\displaystyle =\sum _{i=1}^{\infty }U_{i}\cdot \phi _{i}(x)}+u_{p}(x)=0$

gelten. Das kriegen wir hin, indem wir die (unendlich vielen) U_i der homogenen Lösung passend wählend. Das klingt komplizierter als es ist - die Mathematik bereitet uns den Weg.

⚠ Spezieller Lösungsansatz:

Wir können unseren speziellen Lösungsansatz mit $\cos(\omega _{0}\,t)$ übrigens nur deshalb an die Anfangsbedingungen anpassen, weil die Anfangsgeschwindigkeit des Stabes Null ist - das liefert der cos. Für eine von Null verschiedene Anfangsgeschwindigkeit bräuchten wir den sin-Anteil der Lösung.

Die Beziehung oben multiplizieren wir mit einer der Modalformen ϕ_k und bilden das Integral über die Balken-Lange ℓ, also

$\displaystyle \left(\sum _{i=1}^{\infty }U_{i}\cdot \int _{0}^{\ell }\phi _{j}(x)\cdot \phi _{k}(x)\;dx\right)+\int _{0}^{\ell }u_{p}(x)\cdot \phi _{k}(x)\;dx=0$.

Wir projizieren also die Modalformen auf sich selbst und auf die partikulare Lösung. Und nutzen aus, dass diese Faltungs-Integrale der Modalformen eine besondere Eigenschaft haben:

$\displaystyle \int _{0}^{\ell }\phi _{j}\cdot \phi _{k}\;dx\left\{{\begin{array}{l}=0{\text{ für }}j\neq k\\\neq 0{\text{ für }}j=k\end{array}}\right.$

Man sagt: die Funktionen sind zueinander verallgemeinert orthogonal. Damit berechnen wir

$\displaystyle U_{i}={\frac {32}{\pi ^{3}\left(8{{i}^{3}}-12{{i}^{2}}+6i-1\right)}}$,

Animation: Loslassen des Systems aus der unverformten Rugelage.

Anhand der numerischen Werte der Koeffizienten

${\begin{array}{l}U_{1}=-1.03,\\U_{2}=-0.0382,\\U_{3}=-0.00826,\\U_{4}=-0.00301,\\U_{5}=-0.00142,\\U_{6}=-7.75\cdot 10^{-4}\end{array}}$

sehen wir, dass nur die erste Modalform einen signifikanten Beitrag bei der Anpassung an die Anfangsbedingungen liefert. Wir nehmen bei der Auftragung der Gesamtlösung w_t(x,t) trotzdem die ersten sechs Modalformen mit:

In der Animation sehen Sie das Loslassen des Stabes aus der unverformten, geraden Referenzlage für genau eine Periodenlänge T₁ der ersten Modalform. Die Schwingung, die entsteht ist T₁-periodisch - die anderen Modalformen leisten einen (kleinen) Beitrag, dessen Schwingungsperiode genau ein Vielfaches der Grundschwingung ist - die Darstellung der aneinandergestückelten Lösungen geht "ruckfrei" nach einer Periode ineinander über.

✔ Tipp:

Die Grundform der homogenen Differentialgleichung ${\ddot {u}}-c^{2}\cdot u''=0\;\;\;\;{\text{ hier mit }}\displaystyle c^{2}={\frac {E}{\varrho }}$ ist Basis für alle Musik-Instrumente - ob Saiten- oder Blas-Instrument.  Denn die Bewegungsgleichung von Saiten- und Luft-in-Rohr-Resonanzen führen auf genau diese Bewegungsgleichung. Überlegen Sie, welche Eigenschaft der homogenen Lösung dieser Bewegungsgleichung ihre besondere Bedeutug ausmacht!

/***************************************************************************/
/* t o t a l   ( c o m p o s e d )   s o l u t i o n                       */
/***************************************************************************/
declare(i,integer);
u[p] : append(u[p],
ratsimp(solve(subst(sol[1],integrate(subst(params,subst(u[p],u(x)/u[s]))*sin(kappa*x) + U[i]*sin(kappa*x)*sin(kappa*x)=0,x,0,l[0])),U[i])));

/* analytiv solution */
analytic : append(sol[1],
           [omega[0]*t = sqrt(ratsimp(subst(abbrev,(subst(sol[1],omega[0]^2*T^2)))))*tau,
            x=l[0]*xi]);
sol[2] : append([ratsimp(subst([x=xi*l[0]],subst(params,subst(u[p],u(x)/u[s]))))],
makelist(subst([i=j],subst(u[p],subst(analytic,U[i]*sin(kappa*x)*cos(omega[0]*t)))),j,1,10));

/* plot snapshots for animation of total solution */
NSteps : 19$
fpprintprec: 4$
for j:0 thru 1*NSteps-1 do
   (tstep : simplode([if j<10 then "00" elseif j<100 then "0" else "",j]),
    plot2d(subst([tau=j/NSteps],sum(sol[2][i],i,1,length(sol[2]))),[xi,0,1], [y,-0.1,2.1],
                     [title, simplode(["t/T=",float(j/NSteps+0.01)])], [legend, "analytic"],
                     [style, [lines,1,1]], [xlabel, "ξ →"], [ylabel, "u →"],
                     [png_file,simplode([workdir,"initial-value-solution-step-",tstep,".png"])]))$

---

Links

• Schwingungen von Kontinua eines Euler-Bernoulli-Balkens (SKEB)

Literature

• ...