Gelöste Aufgaben/FEC1/FEC1 - Teil II: Das Modell erstellen

⬅ Zurück zu Teil I

Mathematisches Modell formulieren

Die Bewegungsgleichungen leiten wir mit dem Prinzip der virtuellen Verrückungen her, die Gleichgewichtsbedingung lautet also

$\begin{array}{lcl}\delta W& =& \delta W^a-\delta \mathrm{\Pi }\\ & \stackrel{!}{=}& 0\end{array}$.

Die Anteile ergeben sich jeweils aus der Summe der Teilsysteme

$\delta W^a=\sum _i{W}_i^a,\delta \mathrm{\Pi }=\sum _i{\mathrm{\Pi }}_i$

mit

$i\in \{S,I,T,B_B,B_C,U_A,U_D\}$ .

Auf keines der Teilsysteme wirkt eine äußere, eingeprägte Last (keine Kraft, kein Moment) - es treten also nur die Anteile der d'Alembert'schen Kräfte und der Formänderungsenergie auf.

Impeller- und Turbinen-Rad sowie die Unwuchten erfassen wir als Starrkörper - ihre virtuelle Formänderungsenergie ist Null:

$\begin{array}{lc}\delta {\mathrm{\Pi }}_I& =0\\ \delta {\mathrm{\Pi }}_T& =0\\ \delta {\mathrm{\Pi }}_{U,A}& =0\\ \delta {\mathrm{\Pi }}_{U,D}& =0\end{array}$ .

Für die beiden Lager berücksichtigen wir keine Massen, hier ist also

$\begin{array}{lc}\delta W_{B,B}& =0\\ \delta W_{B,C}& =0\end{array}$ .

Die verbleibenden virtuellen Arbeiten des Systems schreiben wir an, sortieren nach den Koordinaten und deren Variation und formen daraus das System von Bewegungsgleichungen.

tmp

Diskretisierung der Welle

Die Welle ist ein elastisches Kontinuum. Wir können sie als Stab (als eindimensionales Kontinuum) modellieren. Dabei passen

• ein Euler-Bernoulli-Balken oder
• ein Timoshenko-Balken.

Der Einfachheit halber wählen wir den klassischen Euler-Bernoulli-Balken. Die Ansatzfunktionen und Element-Steifigkeits-Matrizen nehmen wir aus der FEM-Formulierung für den Euler-Bernoulli-Balken.

Für die Komplexität des Modells ist die Anzahl der Finiten Elemente entscheidend. Jeder Knoten eines Finite Elements für diesen 3D-Euler-Bernoulli-Ballken hat die vier Koordinaten

$\begin{array}{c}{V}_i(t)\\ {\mathrm{\Psi }}_i(t)\\ W_i(t)\\ {\mathrm{\Phi }}_i(t)\end{array}$.

Die Anzahl der Koordinaten K ist also mit N als Anzahl der Elemente

$K=4\cdot (N+1)$

Uns geht es hier primär um die Anschaulichkeit - wir approximieren die Bewegung der Welle mit einem Finiten Element.

Damit sind die Koordinaten der Welle - und damit des Gesamt-Systems

Hier steht der Index 0 für Punkt A und Index 1 für Punkt B.

/*******************************************************/
/******************* PART   I **************************/
/*******************************************************/

/* define trial functions */
trial: w(x,t) = sum(a[i]*xi^i,i,0,3);
nodal : [W[0](t)  = subst([xi=0],subst(trial,w(x,t))),
         Φ[0](t)  = subst([xi=0],diff(subst(trial,w(x,t)),xi)/ℓ),
         W[1](t)  = subst([xi=1],subst(trial,w(x,t))),
         Φ[1](t)  = subst([xi=1],diff(subst(trial,w(x,t)),xi)/ℓ)];
trial: ratsimp(subst(solve(nodal,makelist(a[i],i,0,3))[1],trial));
/* translate to y-direction */
trial: [trial, subst([w(x,t)=v(x,t),W[0](t)=V[0](t),W[1](t)=V[1](t), Φ[0](t)=Ψ[0](t), Φ[1](t)=Ψ[1](t)],trial)];

/* shaft nodal coordinates */
Q: [[ V[0](t),  Ψ[0](t),  W[0](t),  Φ[0](t),  V[1](t),  Ψ[1](t),  W[1](t),  Φ[1](t),  V[i](t),  Ψ[i](t),  W[i](t),  Φ[i](t)], 
    [δV[0]   , δΨ[0]   , δW[0]   , δΦ[0]   , δV[1]   , δΨ[1]   , δW[1]   , δΦ[1]   , δV[i]   , δΨ[i]   , δW[i]   , δΦ[i]   ]];
/* variation of coordinates            */
varia: makelist(Q[1][i]=Q[2][i],i,1,8);
/* null-reference for linearization   */
nuller : makelist(Q[1][i]=0,i,1,12);

Virtuelle Arbeit von D'Alembert'schen Trägheitkräften

Allgemein ist die Virtuelle Arbeit von D'Alembert'schen Trägheitkräften definiert als

$\delta W^a=\underset{V}{\int }(-\rho \ddot{\overrightarrow{r}})\cdot \delta \overrightarrow{r}dV$.

Wir brauchen also nur einen Ortsvektor zu den materiellen Punkten der Körper als Funktion der Koordinaten der Bewegung - den wir dann in die Beziehung oben einsetzen und über das Volumen des Körpers integrieren.

tmp

Virtuelle Arbeit von D'Alembert'schen Trägheitkräften der Welle

Wir beschreiben den Ort "x₁" der neutralen Faser der Welle durch die funktionalen Koordinaten v(x₁,t) und w(x₁,t) im rotierenden Koordinatensystem. In diesem ist

$\begin{array}{ll}{\overrightarrow{r}}_N(x_1,t)& =x_1\cdot {\overrightarrow{e}}_{x,1}+v(x,t)\cdot {\overrightarrow{e}}_{y,1}+w(x,t)\cdot {\overrightarrow{e}}_{z,1}\\ & =(x_1,v,w)\cdot \left(\begin{array}{c}{\overrightarrow{e}}_{x,1}\\ {\overrightarrow{e}}_{y,1}\\ {\overrightarrow{e}}_{z,1}\end{array}\right)\\ & =(x_1,v,w)\cdot {\underset{\_}{\overrightarrow{e}}}_1\end{array}$

mit den Einheits-Vektoren des rotierenden Koordinatensystems

${\overrightarrow{e}}_{x,1}(t),{\overrightarrow{e}}_{y,1}(t),{\overrightarrow{e}}_{z,1}(t))$.

In Kurzform schrieben wir den Ortsvektor als

${\overrightarrow{r}}_N={\underset{\_}{r}}_N\cdot {\underset{\_}{\overrightarrow{e}}}_1$.

mit

${\underset{\_}{r}}_N^T=\left(\begin{array}{c}{x}_1\\ v(x_1,t)\\ w(x_1,t)\end{array}\right)$ und ${\underset{\_}{\overrightarrow{e}}}_1=\left(\begin{array}{c}{\overrightarrow{e}}_{x,1}\\ {\overrightarrow{e}}_{y,1}\\ {\overrightarrow{e}}_{z,1}\end{array}\right)$.

Um vom  

$\begin{array}{ll}{\underset{\_}{\overrightarrow{e}}}_0& \dots \text{ Inertialsystem in das}\\ {\underset{\_}{\overrightarrow{e}}}_1& \dots \text{ rotierende Koordinatensystem}\end{array}$

zu transformieren, arbeiten wir mit der Eulerschen Drehmatrix in der Form

${\underset{\_}{\overrightarrow{e}}}_1={\underset{\_}{\underset{\_}{D}}}_1(\mathrm{\Omega }t)\cdot {\underset{\_}{\overrightarrow{e}}}_0$

Die Beschleunigung eines Schwerpunkts des Querschnitts "x" erhalten wir dann durch die zweite Ableitung des Ortsvektors nach der Zeit. Das ist nicht ganz trivial, weil wir nun die Ableitung der Einheitsvektoren im rotierenden Koordinatensystem berücksichtigen müssen. Wir starten deshalb mit der ersten Zeitableitung, der Geschwindigkeit. Hier ist - mit der Produktregel -

${\dot{\overrightarrow{r}}}_N={\dot{\underset{\_}{r}}}_N\cdot {\underset{\_}{\overrightarrow{e}}}_1+{\underset{\_}{r}}_N\cdot \dot{{\underset{\_}{\overrightarrow{e}}}_1}$

mit

$\dot{{\underset{\_}{\overrightarrow{e}}}_1}={\dot{\underset{\_}{\underset{\_}{D}}}}_1(\mathrm{\Omega }t)\cdot {\underset{\_}{\overrightarrow{e}}}_0$.

Ausführlich geschrieben steht dort

$\begin{array}{lc}\frac{{\overrightarrow{r}}_N(x_1,t)}{dt}:={\dot{\overrightarrow{r}}}_N(x_1,t)=& \underset{=0}{\underbrace{\frac{d}{dt}(x_1\cdot {\overrightarrow{e}}_{x,1})}}\\ & +\underset{=\dot{v}(x,t)\cdot {\overrightarrow{e}}_{y,1}+v(x,t)\cdot {\dot{\overrightarrow{e}}}_{y,1}}{\underbrace{\frac{d}{dt}(v(x,t)\cdot {\overrightarrow{e}}_{y,1})}}\\ & +\underset{=\dot{w}(x,t)\cdot {\overrightarrow{e}}_{z,1}+w(x,t)\cdot {\dot{\overrightarrow{e}}}_{z,1}}{\underbrace{\frac{d}{dt}(w(x,t)\cdot {\overrightarrow{e}}_{z,1})}}\end{array}$.

Einsetzten liefert für die Einheitsvektoren im gedrehten "1"-System (s.o.)

$\underset{:={\underset{\_}{\overrightarrow{e}}}_1}{\underbrace{\left(\begin{array}{c}{\overrightarrow{e}}_{x,1}\\ {\overrightarrow{e}}_{y,1}\\ {\overrightarrow{e}}_{z,1}\end{array}\right)}}=\left(\begin{array}{c}{\overrightarrow{e}}_{x,0}\\ \cos \left(\mathrm{\Omega }t\right)\cdot {\overrightarrow{e}}_{y,0}-\sin \left(\mathrm{\Omega }t\right)\cdot {\overrightarrow{e}}_{z,0}\\ \cos \left(\mathrm{\Omega }t\right)\cdot {\overrightarrow{e}}_{z,0}+\sin \left(\mathrm{\Omega }t\right)\cdot {\overrightarrow{e}}_{y,0}\end{array}\right)$

Und damit ist z.B.

${\dot{\overrightarrow{e}}}_{y,1}=-\mathrm{\Omega }\cos \left(\mathrm{\Omega }t\right){\overrightarrow{e}}_{z,0}-\mathrm{\Omega }\sin \left(\mathrm{\Omega }t\right){\overrightarrow{e}}_{y,0}$und

${\dot{\overrightarrow{\underset{\_}{e}}}}_1=\left(\begin{array}{c}0\\ -\mathrm{\Omega }\cos \left(\mathrm{\Omega }t\right){\overrightarrow{e}}_{z,0}-\mathrm{\Omega }\sin \left(\mathrm{\Omega }t\right){\overrightarrow{e}}_{y,0}\\ +\mathrm{\Omega }\cos \left(\mathrm{\Omega }t\right){\overrightarrow{e}}_{y,0}-\mathrm{\Omega }\sin \left(\mathrm{\Omega }t\right){\overrightarrow{e}}_{z,0}\end{array}\right)$.

Die zweite Ableitung nach der Zeit liefert analog

${\ddot{\overrightarrow{\underset{\_}{e}}}}_1=\left(\begin{array}{c}0\\ +{\mathrm{\Omega }}^2\sin \left(\mathrm{\Omega }t\right)\cdot {\overrightarrow{e}}_{z,0}-{\mathrm{\Omega }}^2\cos \left(\mathrm{\Omega }t\right)\cdot {\overrightarrow{e}}_{y,0}\\ -{\mathrm{\Omega }}^2\cos \left(\mathrm{\Omega }t\right)\cdot {\overrightarrow{e}}_{z,0}-{\mathrm{\Omega }}^2\sin \left(\mathrm{\Omega }t\right)\cdot {\overrightarrow{e}}_{y,0}\end{array}\right)$

Die Variation des Ortsvektors erhalten wir, indem wir im Ausdruck für

${\overrightarrow{r}}_N$

• die Terme zu Null setzen, die wir nicht variieren dürfen und
• die Koordinaten v(x,t), w(x,t) durch ihre Variation δv(x), δw(x) ersetzen, also
  $\delta {\overrightarrow{r}}_N(x_1)=0+\delta v(x)\cdot {\overrightarrow{e}}_{y,1}+\delta w(x)\cdot {\overrightarrow{e}}_{z,1}$.

Einsetzten in die Formel für die Virtuelle Arbeit von D'Alembert'schen Trägheitkräften liefert zunächst

$-{\ddot{\overrightarrow{r}}}_N\cdot \delta {\overrightarrow{r}}_N=-\ddot{v}\cdot \delta v-\ddot{w}\cdot \delta w-2\mathrm{\Omega }(\dot{v}\cdot \delta w-\dot{w}\cdot \delta v)+{\mathrm{\Omega }}^2(v\cdot \delta v+w\cdot \delta w)$

Wir setzen nun die Trial-Functions für kubische Ansatz-Polynome für v(x,t), w(x,t) ein, führen die Integration über die Länge ℓ der Welle und den Querschnitt A aus - wobei wir die Trägheitsmomente aus dem Kippen der Querschnitte vernachlässigen - und erhalten

$\delta W_S^a=\delta {\underset{\_}{Q}}^T\cdot ({\underset{\_}{\underset{\_}{M}}}_S\cdot \underset{\_}{\ddot{Q}}+{\underset{\_}{\underset{\_}{G}}}_S\cdot \underset{\_}{\dot{Q}}+{\underset{\_}{\underset{\_}{K}}}_S\cdot \underset{\_}{Q})$

mit

${\underset{\_}{\underset{\_}{M}}}_S=m_S\left(\begin{array}{cccccccc}\frac{13}{35}& \frac{11\ell }{210}& 0& 0& \frac{9}{70}& -\frac{13\ell }{420}& 0& 0\\ \frac{11\ell }{210}& \frac{{\ell }^2}{105}& 0& 0& \frac{13\ell }{420}& -\frac{{\ell }^2}{140}& 0& 0\\ 0& 0& \frac{13}{35}& \frac{11\ell }{210}& 0& 0& \frac{9}{70}& -\frac{13\ell }{420}\\ 0& 0& \frac{11\ell }{210}& \frac{{\ell }^2}{105}& 0& 0& \frac{13\ell }{420}& -\frac{{\ell }^2}{140}\\ \frac{9}{70}& \frac{13\ell }{420}& 0& 0& \frac{13}{35}& -\frac{11\ell }{210}& 0& 0\\ -\frac{13\ell }{420}& -\frac{{\ell }^2}{140}& 0& 0& -\frac{11\ell }{210}& \frac{{\ell }^2}{105}& 0& 0\\ 0& 0& \frac{9}{70}& \frac{13\ell }{420}& 0& 0& \frac{13}{35}& -\frac{11\ell }{210}\\ 0& 0& -\frac{13\ell }{420}& -\frac{{\ell }^2}{140}& 0& 0& -\frac{11\ell }{210}& \frac{{\ell }^2}{105}\end{array}\right)$,

${\underset{\_}{\underset{\_}{G}}}_S=m_S\mathrm{\Omega }\left(\begin{array}{cccccccc}0& 0& \frac{26}{35}& \frac{11\ell }{105}& 0& 0& \frac{9}{35}& -\frac{13\ell }{210}\\ 0& 0& \frac{11\ell }{105}& \frac{2{\ell }^2}{105}& 0& 0& \frac{13\ell }{210}& -\frac{{\ell }^2}{70}\\ -\frac{26}{35}& -\frac{11\ell }{105}& 0& 0& -\frac{9}{35}& \frac{13\ell }{210}& 0& 0\\ -\frac{11\ell }{105}& -\frac{2{\ell }^2}{105}& 0& 0& -\frac{13\ell }{210}& \frac{{\ell }^2}{70}& 0& 0\\ 0& 0& \frac{9}{35}& \frac{13\ell }{210}& 0& 0& \frac{26}{35}& -\frac{11\ell }{105}\\ 0& 0& -\frac{13\ell }{210}& -\frac{{\ell }^2}{70}& 0& 0& -\frac{11\ell }{105}& \frac{2{\ell }^2}{105}\\ -\frac{9}{35}& -\frac{13\ell }{210}& 0& 0& -\frac{26}{35}& \frac{11\ell }{105}& 0& 0\\ \frac{13\ell }{210}& \frac{{\ell }^2}{70}& 0& 0& \frac{11\ell }{105}& -\frac{2{\ell }^2}{105}& 0& 0\end{array}\right)$,

${\underset{\_}{\underset{\_}{K}}}_S=m_S{\mathrm{\Omega }}^2\left(\begin{array}{cccccccc}-\frac{13}{35}& -\frac{11\ell }{210}& 0& 0& -\frac{9}{70}& \frac{13\ell }{420}& 0& 0\\ -\frac{11\ell }{210}& -\frac{{\ell }^2}{105}& 0& 0& -\frac{13\ell }{420}& \frac{{\ell }^2}{140}& 0& 0\\ 0& 0& -\frac{13}{35}& -\frac{11\ell }{210}& 0& 0& -\frac{9}{70}& \frac{13\ell }{420}\\ 0& 0& -\frac{11\ell }{210}& -\frac{{\ell }^2}{105}& 0& 0& -\frac{13\ell }{420}& \frac{{\ell }^2}{140}\\ -\frac{9}{70}& -\frac{13\ell }{420}& 0& 0& -\frac{13}{35}& \frac{11\ell }{210}& 0& 0\\ \frac{13\ell }{420}& \frac{{\ell }^2}{140}& 0& 0& \frac{11\ell }{210}& -\frac{{\ell }^2}{105}& 0& 0\\ 0& 0& -\frac{9}{70}& -\frac{13\ell }{420}& 0& 0& -\frac{13}{35}& \frac{11\ell }{210}\\ 0& 0& \frac{13\ell }{420}& \frac{{\ell }^2}{140}& 0& 0& \frac{11\ell }{210}& -\frac{{\ell }^2}{105}\end{array}\right)$,

und der Wellen-Masse

$m_S=\rho A\ell$.

Im rotierenden Koordinatensystem kommen wir zusätzlich zur gewohnten Massenmatrix M_S nun also die Gyroskopie-Matrix G_S und die Zentrifugal-Matrix K_S.

Hier steht bereits die Grundform der System-Matrizen von oben - es fehlen nur noch die Anteile der starren Teilsysteme Impeller,Turbine und Unwucht.

/*******************************************************/
/******************* PART  II **************************/
/*******************************************************/
/* virtuel work of d'Alembert forces                   */
/*******************************************************/

/***********************************/
/* matrices from d'Alembert forces
                           of shaft*/
 r : expand(subst(trial,matrix([0,v(x,t),w(x,t)]).D[1](Omega*t)));
δr : sum(subst(nuller,diff(r,Q[1][i]))*Q[2][i],i,1,8);
δW[S] :-expand(ℓ*integrate(expand(rho*A*   diff(r,t,2).   δr   ),xi,0,1))$
δW[S] : subst(solve(params[1][3],A),δW[S])$

MS : trigsimp(funmake('matrix,makelist(makelist(coeff(coeff(-δW[S],Q[2][j]),diff(Q[1][k],t,2)),j,1,8),k,1,8)))$
GS : trigsimp(funmake('matrix,makelist(makelist(coeff(coeff(-δW[S],Q[2][j]),diff(Q[1][k],t,1)),j,1,8),k,1,8)))$
KS : trigsimp(funmake('matrix,makelist(makelist(coeff(coeff(-δW[S],Q[2][j]),diff(Q[1][k],t,0)),j,1,8),k,1,8)))$

tmp

Virtuelle Arbeit von D'Alembert'schen von Impeller- und Turbinen-Rad

Impeller-und Turbinen-Rad modellieren wir als Starrkörper.

Eine Verschiebung in Wellen-Längsachse betrachten wir nicht, der Drehwinkel Ω t ist fest gegeben - es bleiben also  für jeden Knoten i = A, D noch die Freiheitsgrade

${\underset{\_}{Q}}_i=\left(\begin{array}{c}{V}_i(t)\\ {\mathrm{\Psi }}_i(t)\\ W_i(t)\\ {\mathrm{\Phi }}_i(t)\end{array}\right)$

Die Virtuelle Arbeit von d'Alembert'schen Trägheitskräften des Impeller- oder Turbinen-Rades "i" erhalten wir nun wieder aus dem Integral der Beiträge über alle seine materiellen Punkte. Um zu einem beliebigen Punkt auf dem Rad - hier dem Impeller - zu kommen, brauchen wir zuerst den Ortsvektor zu Punkt A:

${\overrightarrow{r}}_A(t)=(0,V_A(t),W_A(t)).{\underset{\_}{\overrightarrow{e}}}_1$

Koordinaten zu einem materiellen Punkt P auf dem Impeller.

Von Punkt A zu Punkt P kommen wir im Impeller-festen Koordinatensystem

$\mathrm{\Delta }{\overrightarrow{r}}_{AP}=(x_2,y_2,z_2)\cdot {\underset{\_}{\overrightarrow{e}}}_2$ mit ${\underset{\_}{\overrightarrow{e}}}_2={\underset{\_}{\underset{\_}{D}}}_3({\mathrm{\Psi }}_i(t))\cdot {\underset{\_}{\underset{\_}{D}}}_2(-{\mathrm{\Phi }}_i(t))\cdot {\underset{\_}{\overrightarrow{e}}}_1$.

Die Integration über den zylindrischen Impeller schaffen wir einfacher in Polarkoordinaten

$(x_2,y_2,z_2)=(x_2,\tilde{y},0)\cdot {\underset{\_}{\underset{\_}{D}}}_1(\zeta )$

Für die Ebene x₂=0 ist das

${\overrightarrow{r}}_P=(0,V_A,W_A)\cdot {\underset{\_}{\overrightarrow{e}}}_1+(0,\tilde{y},0)\cdot {\underset{\_}{\underset{\_}{D}}}_1(\eta )\cdot {\underset{\_}{\overrightarrow{e}}}_2$.

Die beiden Kippungen um die y₁- und z₁-Achse sind klein, es gilt

${\mathrm{\Phi }}_A\ll 1\text{ und }{\mathrm{\Psi }}_A\ll 1$.

Wir linearisieren deshalb bezüglich dieser Winkel.

Für x₂=0 ist dieser Punkt P noch in der y-z-Ebene von Punkt A. Wir müssten nun die Integration über den komplexen Impeller mit seinen Schaufeln ausführen - mit analytischen Ansätzen hoffnungslos! Wir stellen uns vor, der Impeller sei eine Scheibe mit konstante Dicke "w". Und statt die Integration explizit in x₂-Richtung auszuführen, multiplizieren wir einfach (vereinfachend) mit der Dicke der imaginären Scheibe w.

Wir führen also die Integration über

$dV=w\cdot \tilde{y}d\zeta d\tilde{y}$

für

$0<\tilde{y}<R\text{ und }0<\zeta <2\pi$

aus und erhalten - hier für den Impeller -

$\delta W_I^a=-\delta {\underset{\_}{Q}}_A^T\cdot ({\underset{\_}{\underset{\_}{M}}}_I\cdot {\underset{\_}{\ddot{Q}}}_A+{\underset{\_}{\underset{\_}{G}}}_I\cdot {\underset{\_}{\dot{Q}}}_A+{\underset{\_}{\underset{\_}{K}}}_I\cdot {\underset{\_}{Q}}_A)$

mit

${\underset{\_}{\underset{\_}{M}}}_I=\left(\begin{array}{cccc}{m}_I& 0& 0& 0\\ 0& J_I& 0& 0\\ 0& 0& m_I& 0\\ 0& 0& 0& J_I\end{array}\right)$,

${\underset{\_}{\underset{\_}{G}}}_I=2\mathrm{\Omega }\left(\begin{array}{cccc}0& 0& m_I& 0\\ 0& 0& 0& -J_I\\ -m_I& 0& 0& 0\\ 0& J_I& 0& 0\end{array}\right)$,

${\underset{\_}{\underset{\_}{K}}}_I={\mathrm{\Omega }}^2\left(\begin{array}{cccc}-m_I& 0& 0& 0\\ 0& -J_I& 0& 0\\ 0& 0& -m_I& 0\\ 0& 0& 0& -J_I\end{array}\right)$.

Die Matrizen des Teilsystems Turbine sind die gleichen - nur mit dem Intex T statt I!

Komposition der Gesamtmatrix

Wir bauen die Matrizen der Teilsysteme wie im Bild links in das Gesamtsystem ein.

Jetzt fehlt noch die Unwucht.

/* displacement of mass point P 
   on either Impeller- or Turbine-Wheel*/
r : expand(matrix([0,V[i](t),W[i](t)]).D[1](Omega*t)
          +matrix([0,   y   ,  0    ]).D[1](zeta).DL[2](-Φ[i](t)).DL[3](Ψ[i](t)).D[1](Omega*t))$
/* linearize*/
r : subst(nuller,r) + sum(subst(nuller,diff(r,Q[1][j]))*Q[1][j],j,9,12)$
/* Variation of ...*/
δr : sum(subst(nuller,diff(r,Q[1][j]))*Q[2][j],j,9,12)$

δW[W] :-expand(integrate(integrate(expand(w*y*rho*  diff(r,t,2). δr  ), zeta,0,2*%pi),y,0,R))$
δW[W] : subst( append(solve(subst(params[1][2],params[1][1]),R^4), solve(params[1][2],R^2)),δW[W]);

/***********************************/
/* matrices from d'Alembert forces
                    of rigid wheels*/
MW : trigsimp(funmake('matrix,makelist(makelist(coeff(coeff(-δW[W],Q[2][j]),diff(Q[1][k],t,2)),j,9,12),k,9,12)))$
GW : trigsimp(funmake('matrix,makelist(makelist(coeff(coeff(-δW[W],Q[2][j]),diff(Q[1][k],t,1)),j,9,12),k,9,12)))$
KW : trigsimp(funmake('matrix,makelist(makelist(coeff(coeff(-δW[W],Q[2][j]),diff(Q[1][k],t,0)),j,9,12),k,9,12)))$

tmp

Virtuelle Arbeit von D'Alembert'schen der Unwucht

Eine Unwucht hat die Gesamtmasse m_U. Wir setzen m_U ≪ m_i' und m_U ≪ m_T' an, dann brauchen wir unten die Anteile der Unwucht in den System-Matrizen M, G und K nicht berücksichtigen. Was bleibt dann?.

Der Ortsvektor zur "vorderen" (positive x-Koordinate) der Hantelmassen ist

$\begin{array}{ll}{\overrightarrow{r}}_{U,1}(t)=& (0,V_A,W_A)\cdot {\underset{\_}{\overrightarrow{e}}}_1\\ & +(0,0,e)\cdot {\underset{\_}{\overrightarrow{e}}}_2\\ & +(+a,0,0)\cdot {\underset{\_}{\underset{\_}{D}}}_2(\phi )\cdot {\underset{\_}{\overrightarrow{e}}}_2\end{array}$

Die Virtuelle Arbeit von D'Alembert'schen Trägheitskräften für diese Hälfte der Hantel-Masse erhalten wir aus

$\delta W_{U,1}=(-\frac{m_U}{2}{\ddot{\overrightarrow{r}}}_{U,1})\cdot \delta {\overrightarrow{r}}_{U,1}$

Den Term für die zweite Masse der Hantel (Index "U,2") erhalten wir, wenn wir die Länge "a" durch "-a" ersetzen. Dann ist

$\begin{array}{ll}\delta W_U& =\delta W_{U,1}+\delta W_{U,2}\end{array}$

Wir erhalten in Matrix-Schreibweise - hier für die Unwucht am Impeller (bei A) -

$\delta W_{U,A}^a=-\delta {\underset{\_}{Q}}_A^T\cdot ({\underset{\_}{\underset{\_}{M}}}_U\cdot {\underset{\_}{\ddot{Q}}}_A+{\underset{\_}{\underset{\_}{G}}}_U\cdot {\underset{\_}{\dot{Q}}}_A+{\underset{\_}{\underset{\_}{K}}}_U\cdot {\underset{\_}{Q}}_A-{\underset{\_}{P}}_U)$

mit

${\underset{\_}{\underset{\_}{M}}}_U=m_U\left(\begin{array}{cccc}1& 0& 0& 0\\ 0& a^2{\cos (\phi )}^2& 0& 0\\ 0& 0& 1& 0\\ 0& 0& 0& e^2+a^2\end{array}\right)$,

${\underset{\_}{\underset{\_}{G}}}_U=2\mathrm{\Omega }{m}_U\left(\begin{array}{cccc}0& 0& 1& 0\\ 0& 0& 0& a^2{\cos (\phi )}^2\\ -1& 0& 0& 0\\ 0& -a^2{\cos (\phi )}^2& 0& 0\end{array}\right)$,

${\underset{\_}{\underset{\_}{K}}}_U={\mathrm{\Omega }}^2{m}_U\left(\begin{array}{cccc}-1& 0& 0& 0\\ 0& -a^2{\cos (\phi )}^2& 0& 0\\ 0& 0& -1& 0\\ 0& 0& 0& -a^2{\cos (\phi )}^2\end{array}\right)$

und

${\underset{\_}{P}}_A={\mathrm{\Omega }}^2{m}_U\left(\begin{array}{c}0\\ 0\\ e\\ \frac{a^2\sin \left(2\phi \right)}{2}\end{array}\right)$.

Damit es übersichtlich bleibt, vernachlässigen wir - wegen m_U ≪ m_i' - die Matrizen M_U, G_U und K_U beim Zusammenbau der Gesamt-Gleichungssystems.

Es bleibt: P_A als "rechte Seite" im Gleichungssystem.

/***********************************/
/* matrices from d'Alembert forces
                       of unbalance*/

r : expand(matrix([ 0,  V[i](t),W[i](t)]).D[1](Omega*t)
          +matrix([ 0,    0    ,    e  ]).DL[2](-Φ[i](t)).DL[3](Ψ[i](t)).D[1](Omega*t)
          +matrix([+a,    0    ,    0  ]).D[2](-phi).DL[2](-Φ[i](t)).DL[3](Ψ[i](t)).D[1](Omega*t))$
/* linearize*/
r : subst(nuller,r) + sum(subst(nuller,diff(r,Q[1][j]))*Q[1][j],j,9,12)$
/* Variation of ...*/
δr : sum(subst(nuller,diff(r,Q[1][j]))*Q[2][j],j,9,12)$

δW[U] :-m[U]/2*diff(r,t,2). δr$
δW[U] : expand(subst(nuller,δW[U]))$
/* add second Mass */
δW[U] : expand(trigsimp(δW[U] +subst([a=-a],δW[U])))$
δW[U] : subst([cos(phi)=sin(2*phi)/sin(phi)/2],δW[U]);

/***********************************/
/* right-hand-side from d'Alembert forces
                              of unbalance*/
PU : trigsimp(funmake('matrix,makelist([coeff(+δW[U],Q[2][j])],j,9,12)));

Virtuelle Formänderungsenergie

Zwei elastische Elemente hat unser Modell:

• die Welle und
• die elastischen Lager.

tmp

Virtuelle Formänderungsenergie der Welle

Die Virtuelle Formänderungsenergie für die elastische Welle können wir aus der FEM-Formulierung für den Euler-Bernoulli-Balken kopieren:

$\delta {\mathrm{\Pi }}_S=\delta {\underset{\_}{Q}}^T\cdot {\underset{\_}{\underset{\_}{K}}}_S\cdot \underset{\_}{Q}$

mit

${\underset{\_}{\underset{\_}{K}}}_S=\frac{EI}{{\ell }^3}\left(\begin{array}{cccccccc}12& 6\ell & 0& 0& -12& 6\ell & 0& 0\\ 6\ell & 4{\ell }^2& 0& 0& -6\ell & 2{\ell }^2& 0& 0\\ 0& 0& 12& 6\ell & 0& 0& -12& 6\ell \\ 0& 0& 6\ell & 4{\ell }^2& 0& 0& -6\ell & 2{\ell }^2\\ -12& -6\ell & 0& 0& 12& -6\ell & 0& 0\\ 6\ell & 2{\ell }^2& 0& 0& -6\ell & 4{\ell }^2& 0& 0\\ 0& 0& -12& -6\ell & 0& 0& 12& -6\ell \\ 0& 0& 6\ell & 2{\ell }^2& 0& 0& -6\ell & 4{\ell }^2\end{array}\right)$

/*******************************************************/
/* virtuel strain energies                             */
/*******************************************************/
/* matrices from elastic deformation
                          of shaft */
δΠ[S] : integrate(EI*diff(subst(trial,w(x,t)),xi,2)*diff(subst(varia,subst(trial,w(x,t))),xi,2),xi,0,1)/ℓ^3+
        integrate(EI*diff(subst(trial,v(x,t)),xi,2)*diff(subst(varia,subst(trial,v(x,t))),xi,2),xi,0,1)/ℓ^3$
δΠ[S] : expand(subst(solve(params[1][4],EI) ,δΠ[S]))$

KS : funmake('matrix,makelist(makelist(coeff(coeff(δΠ[S],Q[2][i]),diff(Q[1][j],t,0)),i,1,8),j,1,8))$

tmp

Virtuelle Formänderungsenergie der elastischen Lager

Etwas komplizierter wir es bei der virtuellen Formänderungsenergie der Lager.

Auslenkung des Lagers - hier "B".

Die Verschiebungen der Welle - hier V_B und W_B für Lager B - haben wir im mitrotierenden Koordinatensystem angegeben. Wenn hier das Turbolader-Gehäuse unterschiedliche Nachgiebigkeiten in y₀ und z₀-Richtung hat, müssen wir die Auslenkungen auf das Intertialsystem transformieren.

Dafür brauchen wir

${\overrightarrow{r}}_B=({\ell }_1,V_B(t),W_B(t))\cdot {\underset{\_}{\overrightarrow{e}}}_1$

und

$\delta {\overrightarrow{r}}_B=(0,\delta V_B(t),\delta W_B(t))\cdot {\underset{\_}{\overrightarrow{e}}}_1$

Die virtuelle Formänderungsenergie der beiden Federn ist dann

$\begin{array}{ll}\delta {\mathrm{\Pi }}_{B,B}=& k_2{r}_{B,2}\cdot \delta r_{B,2}\\ & +k_3{r}_{B,3}\cdot \delta r_{B,3}\end{array}$.

🧨 Gleitlager sind komplizierter:

In Gleitlagern ist die Auslenkung in eine Richtung (z.B. y1) durch die Drehung der Welle immer mit einer Kraft senkrecht zur Auslenkung (z.B. in z1-Richtung) gekoppelt. Die Bewegungsgleichungen haben dann periodische Koeffizienten (vgl. Aufgabe "Kw30"). Das vernachlässigen wir hier.

Einsetzen und Vereinfachen liefert

$\delta {\mathrm{\Pi }}_{B,B}=\frac{1}{2}(\delta V_B,\delta W_B)\cdot \left(\begin{array}{c}(k_3-k_2)W_B(t)\sin \left(2\mathrm{\Omega }t\right)+(k_2-k_3)V_B(t)\cos \left(2\mathrm{\Omega }t\right)+(k_3+k_2)V_B(t)\\ (k_3-k_2)V_B(t)\sin \left(2\mathrm{\Omega }t\right)+(k_3-k_2)W_B(t)\cos \left(2\mathrm{\Omega }t\right)+(k_3+k_2)W_B(t)\end{array}\right)$.

Hier stehen jetzt Terme mit sin(2 Ω t), cos(2 Ω t), die sich auch nicht herauskürzen lassen. Sie führen in der Bewegungsgleichung zu einer Steifigskeits-Matrix (die Koeffizienten), die nicht mehr konstant ist. Diese periodischen Anteile haben alle den Koeffizienten k₃-k₂ - wir führen deshalb

$\mathrm{\Delta }k=k_3-k_2$

ein und schreiben damit die Steifigkeitsmatrizen

${\underset{\_}{\underset{\_}{K}}}_B={\underset{\_}{\underset{\_}{K}}}_{B,0}+\mathrm{\Delta }k\cdot \cos (2\mathrm{\Omega }t)\cdot {\underset{\_}{\underset{\_}{K}}}_{B,C}+\mathrm{\Delta }k\cdot \sin (2\mathrm{\Omega }t)\cdot {\underset{\_}{\underset{\_}{K}}}_{B,S}$

an. Aber dafür müssen wir zuerst noch die Auslenkungen V_B und W_B in unsere FE-Knoten umrechnen. Wir wählen

$\frac{{\ell }_1}{{\ell }_0}=\frac{1}{3}\text{ und }\frac{{\ell }_2}{{\ell }_0}=\frac{2}{3}$

und erhalten z.B. für

$V_B(t)=\frac{1}{27}(20V_0(t)+7V_1(t)+4{\mathrm{\Psi }}_0(t)\ell -2{\mathrm{\Psi }}_1(t)\ell )$.

Damit berechnen wir die Element-Steifigkeits-Matrizen zu

${\underset{\_}{\underset{\_}{K}}}_{B,0}=\left(\begin{array}{cccccccc}\frac{449\mathrm{\Delta }{k}}{1458}+\frac{449k_2}{729}& \frac{47\mathrm{\Delta }{k}\ell }{729}+\frac{94k_2\ell }{729}& 0& 0& \frac{140\mathrm{\Delta }{k}}{729}+\frac{280k_2}{729}& -\frac{34\mathrm{\Delta }{k}\ell }{729}-\frac{68k_2\ell }{729}& 0& 0\\ \frac{47\mathrm{\Delta }{k}\ell }{729}+\frac{94k_2\ell }{729}& \frac{10\mathrm{\Delta }{k}{\ell }^2}{729}+\frac{20k_2{\ell }^2}{729}& 0& 0& \frac{34\mathrm{\Delta }{k}\ell }{729}+\frac{68k_2\ell }{729}& -\frac{8\mathrm{\Delta }{k}{\ell }^2}{729}-\frac{16k_2{\ell }^2}{729}& 0& 0\\ 0& 0& \frac{449\mathrm{\Delta }{k}}{1458}+\frac{449k_2}{729}& \frac{47\mathrm{\Delta }{k}\ell }{729}+\frac{94k_2\ell }{729}& 0& 0& \frac{140\mathrm{\Delta }{k}}{729}+\frac{280k_2}{729}& -\frac{34\mathrm{\Delta }{k}\ell }{729}-\frac{68k_2\ell }{729}\\ 0& 0& \frac{47\mathrm{\Delta }{k}\ell }{729}+\frac{94k_2\ell }{729}& \frac{10\mathrm{\Delta }{k}{\ell }^2}{729}+\frac{20k_2{\ell }^2}{729}& 0& 0& \frac{34\mathrm{\Delta }{k}\ell }{729}+\frac{68k_2\ell }{729}& -\frac{8\mathrm{\Delta }{k}{\ell }^2}{729}-\frac{16k_2{\ell }^2}{729}\\ \frac{140\mathrm{\Delta }{k}}{729}+\frac{280k_2}{729}& \frac{34\mathrm{\Delta }{k}\ell }{729}+\frac{68k_2\ell }{729}& 0& 0& \frac{449\mathrm{\Delta }{k}}{1458}+\frac{449k_2}{729}& -\frac{47\mathrm{\Delta }{k}\ell }{729}-\frac{94k_2\ell }{729}& 0& 0\\ -\frac{34\mathrm{\Delta }{k}\ell }{729}-\frac{68k_2\ell }{729}& -\frac{8\mathrm{\Delta }{k}{\ell }^2}{729}-\frac{16k_2{\ell }^2}{729}& 0& 0& -\frac{47\mathrm{\Delta }{k}\ell }{729}-\frac{94k_2\ell }{729}& \frac{10\mathrm{\Delta }{k}{\ell }^2}{729}+\frac{20k_2{\ell }^2}{729}& 0& 0\\ 0& 0& \frac{140\mathrm{\Delta }{k}}{729}+\frac{280k_2}{729}& \frac{34\mathrm{\Delta }{k}\ell }{729}+\frac{68k_2\ell }{729}& 0& 0& \frac{449\mathrm{\Delta }{k}}{1458}+\frac{449k_2}{729}& -\frac{47\mathrm{\Delta }{k}\ell }{729}-\frac{94k_2\ell }{729}\\ 0& 0& -\frac{34\mathrm{\Delta }{k}\ell }{729}-\frac{68k_2\ell }{729}& -\frac{8\mathrm{\Delta }{k}{\ell }^2}{729}-\frac{16k_2{\ell }^2}{729}& 0& 0& -\frac{47\mathrm{\Delta }{k}\ell }{729}-\frac{94k_2\ell }{729}& \frac{10\mathrm{\Delta }{k}{\ell }^2}{729}+\frac{20k_2{\ell }^2}{729}\end{array}\right)$,

${\underset{\_}{\underset{\_}{K}}}_{B,C}=\left(\begin{array}{cccccccc}-\frac{449}{1458}& -\frac{47\ell }{729}& 0& 0& -\frac{140}{729}& \frac{34\ell }{729}& 0& 0\\ -\frac{47\ell }{729}& -\frac{10{\ell }^2}{729}& 0& 0& -\frac{34\ell }{729}& \frac{8{\ell }^2}{729}& 0& 0\\ 0& 0& \frac{449}{1458}& \frac{47\ell }{729}& 0& 0& \frac{140}{729}& -\frac{34\ell }{729}\\ 0& 0& \frac{47\ell }{729}& \frac{10{\ell }^2}{729}& 0& 0& \frac{34\ell }{729}& -\frac{8{\ell }^2}{729}\\ -\frac{140}{729}& -\frac{34\ell }{729}& 0& 0& -\frac{449}{1458}& \frac{47\ell }{729}& 0& 0\\ \frac{34\ell }{729}& \frac{8{\ell }^2}{729}& 0& 0& \frac{47\ell }{729}& -\frac{10{\ell }^2}{729}& 0& 0\\ 0& 0& \frac{140}{729}& \frac{34\ell }{729}& 0& 0& \frac{449}{1458}& -\frac{47\ell }{729}\\ 0& 0& -\frac{34\ell }{729}& -\frac{8{\ell }^2}{729}& 0& 0& -\frac{47\ell }{729}& \frac{10{\ell }^2}{729}\end{array}\right)$

und

${\underset{\_}{\underset{\_}{K}}}_{B,S}=\left(\begin{array}{cccccccc}0& 0& \frac{449}{1458}& \frac{47\ell }{729}& 0& 0& \frac{140}{729}& -\frac{34\ell }{729}\\ 0& 0& \frac{47\ell }{729}& \frac{10{\ell }^2}{729}& 0& 0& \frac{34\ell }{729}& -\frac{8{\ell }^2}{729}\\ \frac{449}{1458}& \frac{47\ell }{729}& 0& 0& \frac{140}{729}& -\frac{34\ell }{729}& 0& 0\\ \frac{47\ell }{729}& \frac{10{\ell }^2}{729}& 0& 0& \frac{34\ell }{729}& -\frac{8{\ell }^2}{729}& 0& 0\\ 0& 0& \frac{140}{729}& \frac{34\ell }{729}& 0& 0& \frac{449}{1458}& -\frac{47\ell }{729}\\ 0& 0& -\frac{34\ell }{729}& -\frac{8{\ell }^2}{729}& 0& 0& -\frac{47\ell }{729}& \frac{10{\ell }^2}{729}\\ \frac{140}{729}& \frac{34\ell }{729}& 0& 0& \frac{449}{1458}& -\frac{47\ell }{729}& 0& 0\\ -\frac{34\ell }{729}& -\frac{8{\ell }^2}{729}& 0& 0& -\frac{47\ell }{729}& \frac{10{\ell }^2}{729}& 0& 0\end{array}\right)$.

/***********************************/
/* matrices from elastic deformation
                        of bearing */
 r : expand(subst(trial,matrix([0,v(x,t),w(x,t)]).D[1](Omega*t)));
δr : sum(subst(nuller,diff(r,Q[1][j]))*Q[2][j],j,1,8);

δΠ[B] : k[2]*r[1][2]*subst(varia,r[1][2])+
        k[3]*r[1][3]*subst(varia,r[1][3])$
δΠ[B] : expand(sum(subst(params[2][i],δΠ[B]),i,1,2))$
δΠ[B] : expand(subst([k[3]=k[2]+Δk],δΠ[B]))$

KB[N] : funmake('matrix,makelist(makelist(trigsimp(coeff(coeff(δΠ[B],Q[2][i]),diff(Q[1][j],t,0))),i,1,8),j,1,8))$
KB[N] : expand(subst(trigReplace[3],expand(subst(trigReplace[2],expand(subst(trigReplace[1],KB[N]))))))$

KB[C] : coeff(KB[N],cos(2*Omega*t))/Δk$
KB[S] : coeff(KB[N],sin(2*Omega*t))/Δk$
KB[N] : KB[N] - Δk*KB[S]*sin(2*Omega*t) - Δk*KB[C]*cos(2*Omega*t)$

/* -> see Matthieus DGL, Ottl 3.11*/

tmp

Komponieren der System-Matrizen

Aus den Element-Matrizen müssen wir nun noch die System-Matrix komponieren, d.h. die Element-Matrizen passend hinein-addieren.

Wir erhalten

$\underset{\_}{\underset{\_}{M}}=\left(\begin{array}{cccccccc}\frac{13m_S}{35}+m_I& \frac{11m_S\ell }{210}& 0& 0& \frac{9m_S}{70}& -\frac{13m_S\ell }{420}& 0& 0\\ \frac{11m_S\ell }{210}& \frac{m_S{\ell }^2}{105}+J_I& 0& 0& \frac{13m_S\ell }{420}& -\frac{m_S{\ell }^2}{140}& 0& 0\\ 0& 0& \frac{13m_S}{35}+m_I& \frac{11m_S\ell }{210}& 0& 0& \frac{9m_S}{70}& -\frac{13m_S\ell }{420}\\ 0& 0& \frac{11m_S\ell }{210}& \frac{m_S{\ell }^2}{105}+J_I& 0& 0& \frac{13m_S\ell }{420}& -\frac{m_S{\ell }^2}{140}\\ \frac{9m_S}{70}& \frac{13m_S\ell }{420}& 0& 0& m_T+\frac{13m_S}{35}& -\frac{11m_S\ell }{210}& 0& 0\\ -\frac{13m_S\ell }{420}& -\frac{m_S{\ell }^2}{140}& 0& 0& -\frac{11m_S\ell }{210}& \frac{m_S{\ell }^2}{105}+J_T& 0& 0\\ 0& 0& \frac{9m_S}{70}& \frac{13m_S\ell }{420}& 0& 0& m_T+\frac{13m_S}{35}& -\frac{11m_S\ell }{210}\\ 0& 0& -\frac{13m_S\ell }{420}& -\frac{m_S{\ell }^2}{140}& 0& 0& -\frac{11m_S\ell }{210}& \frac{m_S{\ell }^2}{105}+J_T\end{array}\right)$,

$\underset{\_}{\underset{\_}{G}}=\mathrm{\Omega }\cdot \left(\begin{array}{cccccccc}0& 0& \frac{26m_S}{35}+2m_I& \frac{11m_S\ell }{105}& 0& 0& \frac{9m_S}{35}& -\frac{13m_S\ell }{210}\\ 0& 0& \frac{11m_S\ell }{105}& \frac{2m_S{\ell }^2}{105}& 0& 0& \frac{13m_S\ell }{210}& -\frac{m_S{\ell }^2}{70}\\ -\frac{26m_S}{35}-2m_I& -\frac{11m_S\ell }{105}& 0& 0& -\frac{9m_S}{35}& \frac{13m_S\ell }{210}& 0& 0\\ -\frac{11m_S\ell }{105}& -\frac{2m_S{\ell }^2}{105}& 0& 0& -\frac{13m_S\ell }{210}& \frac{m_S{\ell }^2}{70}& 0& 0\\ 0& 0& \frac{9m_S}{35}& \frac{13m_S\ell }{210}& 0& 0& 2m_T+\frac{26m_S}{35}& -\frac{11m_S\ell }{105}\\ 0& 0& -\frac{13m_S\ell }{210}& -\frac{m_S{\ell }^2}{70}& 0& 0& -\frac{11m_S\ell }{105}& \frac{2m_S{\ell }^2}{105}\\ -\frac{9m_S}{35}& -\frac{13m_S\ell }{210}& 0& 0& -2m_T-\frac{26m_S}{35}& \frac{11m_S\ell }{105}& 0& 0\\ \frac{13m_S\ell }{210}& \frac{m_S{\ell }^2}{70}& 0& 0& \frac{11m_S\ell }{105}& -\frac{2m_S{\ell }^2}{105}& 0& 0\end{array}\right)$,

${\underset{\_}{\underset{\_}{K}}}_0=\left(\begin{array}{cccccccc}\frac{449\mathrm{\Delta }{k}}{1458}-m_I{\mathrm{\Omega }}^2+4k_4+\frac{449k_2}{729}& \frac{47\mathrm{\Delta }{k}\ell }{729}+2k_4\ell +\frac{94k_2\ell }{729}& 0& 0& \frac{140\mathrm{\Delta }{k}}{729}-4k_4+\frac{280k_2}{729}& -\frac{34\mathrm{\Delta }{k}\ell }{729}+2k_4\ell -\frac{68k_2\ell }{729}& 0& 0\\ \frac{47\mathrm{\Delta }{k}\ell }{729}+2k_4\ell +\frac{94k_2\ell }{729}& \frac{10\mathrm{\Delta }{k}{\ell }^2}{729}+\frac{4k_4{\ell }^2}{3}+\frac{20k_2{\ell }^2}{729}& 0& 0& \frac{34\mathrm{\Delta }{k}\ell }{729}-2k_4\ell +\frac{68k_2\ell }{729}& -\frac{8\mathrm{\Delta }{k}{\ell }^2}{729}+\frac{2k_4{\ell }^2}{3}-\frac{16k_2{\ell }^2}{729}& 0& 0\\ 0& 0& \frac{449\mathrm{\Delta }{k}}{1458}-m_I{\mathrm{\Omega }}^2+4k_4+\frac{449k_2}{729}& \frac{47\mathrm{\Delta }{k}\ell }{729}+2k_4\ell +\frac{94k_2\ell }{729}& 0& 0& \frac{140\mathrm{\Delta }{k}}{729}-4k_4+\frac{280k_2}{729}& -\frac{34\mathrm{\Delta }{k}\ell }{729}+2k_4\ell -\frac{68k_2\ell }{729}\\ 0& 0& \frac{47\mathrm{\Delta }{k}\ell }{729}+2k_4\ell +\frac{94k_2\ell }{729}& \frac{10\mathrm{\Delta }{k}{\ell }^2}{729}+\frac{4k_4{\ell }^2}{3}+\frac{20k_2{\ell }^2}{729}& 0& 0& \frac{34\mathrm{\Delta }{k}\ell }{729}-2k_4\ell +\frac{68k_2\ell }{729}& -\frac{8\mathrm{\Delta }{k}{\ell }^2}{729}+\frac{2k_4{\ell }^2}{3}-\frac{16k_2{\ell }^2}{729}\\ \frac{140\mathrm{\Delta }{k}}{729}-4k_4+\frac{280k_2}{729}& \frac{34\mathrm{\Delta }{k}\ell }{729}-2k_4\ell +\frac{68k_2\ell }{729}& 0& 0& \frac{449\mathrm{\Delta }{k}}{1458}-{\mathrm{\Omega }}^2{m}_T+4k_4+\frac{449k_2}{729}& -\frac{47\mathrm{\Delta }{k}\ell }{729}-2k_4\ell -\frac{94k_2\ell }{729}& 0& 0\\ -\frac{34\mathrm{\Delta }{k}\ell }{729}+2k_4\ell -\frac{68k_2\ell }{729}& -\frac{8\mathrm{\Delta }{k}{\ell }^2}{729}+\frac{2k_4{\ell }^2}{3}-\frac{16k_2{\ell }^2}{729}& 0& 0& -\frac{47\mathrm{\Delta }{k}\ell }{729}-2k_4\ell -\frac{94k_2\ell }{729}& \frac{10\mathrm{\Delta }{k}{\ell }^2}{729}+\frac{4k_4{\ell }^2}{3}+\frac{20k_2{\ell }^2}{729}& 0& 0\\ 0& 0& \frac{140\mathrm{\Delta }{k}}{729}-4k_4+\frac{280k_2}{729}& \frac{34\mathrm{\Delta }{k}\ell }{729}-2k_4\ell +\frac{68k_2\ell }{729}& 0& 0& \frac{449\mathrm{\Delta }{k}}{1458}-{\mathrm{\Omega }}^2{m}_T+4k_4+\frac{449k_2}{729}& -\frac{47\mathrm{\Delta }{k}\ell }{729}-2k_4\ell -\frac{94k_2\ell }{729}\\ 0& 0& -\frac{34\mathrm{\Delta }{k}\ell }{729}+2k_4\ell -\frac{68k_2\ell }{729}& -\frac{8\mathrm{\Delta }{k}{\ell }^2}{729}+\frac{2k_4{\ell }^2}{3}-\frac{16k_2{\ell }^2}{729}& 0& 0& -\frac{47\mathrm{\Delta }{k}\ell }{729}-2k_4\ell -\frac{94k_2\ell }{729}& \frac{10\mathrm{\Delta }{k}{\ell }^2}{729}+\frac{4k_4{\ell }^2}{3}+\frac{20k_2{\ell }^2}{729}\end{array}\right)$,

${\underset{\_}{\underset{\_}{K}}}_C=\mathrm{\Delta }k\cdot {\underset{\_}{\underset{\_}{K}}}_{B,C}$,

${\underset{\_}{\underset{\_}{K}}}_S=\mathrm{\Delta }k\cdot {\underset{\_}{\underset{\_}{K}}}_{B,S}$

und

$\underset{\_}{P}={\mathrm{\Omega }}^2{m}_U\cdot \left(\begin{array}{c}0\\ 0\\ e\\ \frac{1}{2}{a}^2\sin \left(2\phi \right)\\ 0\\ 0\\ 0\\ 0\end{array}\right)$

In P steht dabei nur die Zentrifugalkraft der Impeller-Unwucht - auf eine Unwucht in der Turbine verzichten wir hier.

In der Hauptdiagonale der Steifigkeitsmatrix K₀ stehen nun Terme - hier in Zeile 1 - die bei genügend großem Ω negativ werden:

$\frac{449\mathrm{\Delta }{k}}{1458}+4k_4+\frac{449k_2}{729}-m_I{\mathrm{\Omega }}^2$

Das sieht nach Instabilität aus!

Aber unser Mathematisches Modell ist erst mal fertig! Wir können es aber etwas einfacher hinschrieben:

/*******************************************************/
/* compose total equations of motion                   */

M    : MS$
G    : GS$
K[N] : KS + KB[N]$
K[S] : Δk*KB[S]$
K[C] : Δk*KB[C]$
P    : zeromatrix(8,1)$

for row:1 thru 4 do
  (P[row,1] : subst([sin(phi)=sin(2*phi)/cos(phi)/2],PU[row,1]),
   for col:1 thru 4 do
   (print (row,col),
    /* compressor wheel*/
    M   [  row][  col] : M   [  row][  col]+subst([i=I],MW[row][col]),
    M   [4+row][4+col] : M   [4+row][4+col]+subst([i=T],MW[row][col]),
    G   [  row][  col] : G   [  row][  col]+subst([i=I],GW[row][col]),
    G   [4+row][4+col] : G   [4+row][4+col]+subst([i=T],GW[row][col]),
    K[N][  row][  col] : K[N][  row][  col]+subst([i=I],KW[row][col]),
    K[N][4+row][4+col] : K[N][4+row][4+col]+subst([i=T],KW[row][col])))$

Mathematisches Modell anpassen

Hinschreiben in dimensionsloser Form

{{{text}}}

1+1

Links

• ...

Literature

• ...