Gelöste Aufgaben/FEAB

Aufgabenstellung

Statt zwei Freiheitsgraden wie in FEAA haben wir jetzt - bei einem Kontinuum - unendlich viele.

Lageplan

Gesucht ist die Näherungslösung für die Auslenkung der Stab-Querschnitte mit dem Prinzip der Virtuellen Verrückungen. Wir verwenden polynomialen Ansatzfunktionen über die Gesamtlänge - also eine Mischung aus Finiten-Elemente-Methode und dem Rayleigh-Ritz-Verfahren.

Lösung mit Maxima

Header

In den Lageplan haben wir bereits den funktionalen Fireheitsgrad u(x) eingetragen, der Stab ist am oberen Ende befestigt und wird am unteren Ende mit der Zugkraft F belastet.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 16.04.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2017-10-10                            */
/* ref: FENV step 4 im Prozess: Ganzfeldansätze        */
/* description: mit dem PvV werden die Bewegungsgl.    */
/*          für einen Stab unter Gewichtskraft erstellt*/
/*******************************************************/

Declarations

Für Maxima brauchen wir einige Deklarationen.

Der maximale Exponent des Ansatz-Polynoms ist drei - dann fällt die Näherungslösung mit der analytischen Lösung zusammen.

Hier wählen wir

$I=2$ (im Maximaskipt I=3)

/*******************************************************/
/* declare variational variables - see 6.3 Identifiers */
declare("δW", alphabetic);
declare("δA", alphabetic);
declare("δΠ", alphabetic);
declare("δQ", alphabetic);
declare("δu", alphabetic);
/*******************************************************/
/* parameter */
I : 3; /* max: 3*/

Formfuctions

Für die Formfunktionen wählen wir

$\displaystyle u(x)=\sum _{i=1}^{I}U_{i}\cdot \left({\frac {x}{\ell }}\right)^{i}$> ,

also für I=2

$\displaystyle u(x)=U_{1}{\frac {x}{l}}+U_{2}\left({\frac {x}{l}}\right)^{2}$

und entsprechend

$\displaystyle \delta u(x)=\delta U_{1}{\frac {x}{l}}+\delta U_{2}\left({\frac {x}{l}}\right)^{2}$ .

/* coordinates and their variations */
 Q : makelist( U[i],i,1,I);
δQ : makelist(δU[i],i,1,I);

/* trial functions */
Phi : [(x/l)^1,(x/l)^2,(x/l)^3];

/* Ansatz */
 u : sum( Q[i]*Phi[i],i,1,I);
δu : sum(δQ[i]*Phi[i],i,1,I);

Equilibrium Conditions

Die Gleichgewichtsbedingung

${\begin{array}{ll}\delta W&=\delta W^{a}-\delta \Pi \\&{\stackrel {!}{=}}0\end{array}}$

liefert

$\displaystyle \delta W={\frac {\delta U_{2}Ag\ell \rho }{3}}+{\frac {\delta U_{1}Ag\ell \rho }{2}}-{\frac {4{{U}_{2}}\,{{\mathit {{\delta }U}}_{2}}AE}{3\ell }}-{\frac {{{U}_{1}}\,{{\mathit {{\delta }U}}_{2}}AE}{\ell }}-{\frac {{{\mathit {{\delta }U}}_{1}}\,{{U}_{2}}AE}{\ell }}-{\frac {{{U}_{1}}\,{{\mathit {{\delta }U}}_{1}}AE}{\ell }}$.

/* Equilibrium */
δΠ : E*A*integrate(diff(u,x)*diff(δu,x),x,0,l);
δA : integrate(rho*g*A*δu, x,0,l);

Solving

Die Gleichgewichtsbedingungen folgen daraus zu

${\begin{array}{l}\displaystyle -{\frac {Ag\ell \rho }{2}}+{\frac {{{U}_{2}}AE}{\ell }}+{\frac {{{U}_{1}}AE}{\ell }}=0,\\\displaystyle -{\frac {Ag\ell \rho }{3}}+{\frac {4{{U}_{2}}AE}{3l}}+{\frac {{{U}_{1}}AE}{\ell }}=0\end{array}}$

und somit

$\displaystyle {{U}_{1}}={\frac {g\,{{\ell }^{2}}\rho }{E}},\;\;\;{{U}_{2}}=-{\frac {g\,{{\ell }^{2}}\rho }{2E}}$

eom : makelist(-coeff(expand(δA-δΠ),c)=0,c,δQ);
sol: solve(eom, Q)[1];

Post-Processing

Und wir tragen die Ergebnisse auf für die numerische Näherungslösung

$\displaystyle u(x)={\frac {g\rho \ell ^{2}}{E}}\cdot {\frac {x}{\ell }}-{\frac {g\rho \ell ^{2}}{2E}}\cdot \left({\frac {x}{\ell }}\right)^{2}$

gegen die exakte Lösung auf:

Verschiebung der Stab-Querschnitte.

/* plot results*/

toPlot: append([xi*(1-xi/2)],
               [        expand(subst(xi*l,x,subst(sol,sum(Q[i]*Phi[i],i,1,I)/(rho*g*l^2/E))))],
               makelist(       subst(xi*l,x,subst(sol,    Q[i]*Phi[i]       /(rho*g*l^2/E))), i,1,I));

plot2d(toPlot, [xi,0,1], [xlabel, "xi→"], [ylabel, "u/((g*l^2*rho)/E)→"],
               [legend, "exact", "approximated", "first order", "second order", "third order"],
               [title, sconcat("I = ",I)]);

Links

• ...

Literature

• ...