Gelöste Aufgaben/T312

Aufgabenstellung

Bei Arbeiten mit elastischen Stäben stoßen wir immer wieder auf die gleiche Aufgabe: das Aufstellen der virtuellen Formänderungsenergie eines Stabes, den wir in ein System einbauen müssen.

Lageplan - einzelner Stab

Gesucht ist die allgemeine Formulierung für die virtuelle Formänderungsenergie eines Stabes in einem Stabwerk.

Lösung mit Maxima

Die relevanten Größen wie die Stablänge ℓ_i, die Stablängung Δℓ_i und die Stabkraft S_i sind im Stabsystem definiert, wir brauchen aber die Größen in einem einheitlichen x,y - Referenzsystem.

Damit wir also nicht bei jeder Aufgabe wieder von vorn anfangen, die Δℓ_i als Funktion der Auslenkungen u_j, v_j der Knoten K,L im x,y - System herzuleiten, machen wir das ein Mal allgemein.

Header

Dazu vergleichen wir den Stab in seiner verformten Konfiguration mit seiner Referenzkonfiguration - und schreiben die Terme der virtuellen Formänderungsenergie an.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 15.08.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2017-10-31                            */
/* ref: TM-2                                           */
/* description: virt. Formänderungsarbeit eines Stabes */
/*              in einem Stabwerk                      */
/*******************************************************/

Declarations

Hier stehen nur die Deklarationen für spezielle Symbole zur Verwendung mit Maxima.

/* special symbols to be declared */
declare("δΠ", alphabetic);
declare("δl", alphabetic);
declare("Δl", alphabetic);
declare("Δx", alphabetic);
declare("Δy", alphabetic);
declare("δu", alphabetic);
declare("δv", alphabetic);

Kinematics

Koordinaten

Der Stab i hat die Knoten K und L, die im unverformten Stabwerk die Koordinaten

${\begin{array}{ll}P_{K}:[x_{k},y_{k}]\\P_{L}:[x_{l},y_{l}]\end{array}}$

haben.

Im verformten System sind

${\begin{array}{llc}P'_{K}:[x_{k}+u_{k},&y_{k}+v_{k}],\\P'_{L}:[x_{l}+u_{l},&y_{l}+v_{l}]\end{array}}$.

Kinematische Verträglichkeit

Mit dem Satz von Pythagoras stellen wir nun den Zusammenhang her zwischen der Stablänge in der Ausgangskonfiguration und der verformten Konfiguration des Stabes:

${\begin{array}{rcc}{{\left({{y}_{l}}-{{y}_{k}}\right)}^{2}}+{{\left({{x}_{l}}-{{x}_{k}}\right)}^{2}}&=&{{\ell }_{i}^{2}}\\{{\left((v_{l}-v_{k})+(y_{l}-y_{k})\right)^{2}+\left((u_{l}-u_{k})+(x_{l}-x_{k})\right)}^{2}}&=&{{\left({{\ell }_{i}}+{{\mathit {\Delta \ell }}_{i}}\right)}^{2}}\end{array}}$

Die zweite Zeile stellt den nichtlinearen Zusammenhang zwischen den Koordinaten der Knoten-Verschiebungen u_j,v_j und der Stablängung Δℓ_i her.

Den nichtlinearen Zusammenhang brauchen wir praktisch nie, weil wir meist von kleinen Verformungen des Systems ausgehen - und damit auch kleinen Stablängungen ausgehen.

Wir linearisieren deshalb den Ausdruck oben und erhalten

$\Delta \,\ell _{i}=\displaystyle {\frac {(x_{l}-x_{k})\cdot (u_{l}-u_{k})+(y_{l}-y_{k})\cdot (v_{l}-v_{k})}{\ell _{i}}}$

den wir den Abkürzungen

${\begin{array}{ll}{{x}_{l}}&={\mathit {\Delta x}}+{{x}_{k}}\\{{y}_{l}}&={\mathit {\Delta y}}+{{y}_{k}}\\{\mathit {\Delta x}}&={{\ell }_{i}}\cdot {{\xi }_{x}}\ {\mathit {\Delta y}}&={{\ell }_{i}}\cdot {{\xi }_{y}}\\{{\mathit {EA}}_{i}}&={{k}_{i}}\cdot {{\ell }_{i}}\end{array}}$

schrieben als

${{\mathit {\Delta \ell }}_{i}}=\left({{v}_{l}}-{{v}_{k}}\right)\cdot {{\xi }_{y}}+\left({{u}_{l}}-{{u}_{k}}\right)\cdot {{\xi }_{x}}$.

/* coordinates */
q : [[ u[k], v[k], u[l], v[l],Δl[i]],
     [δu[k],δv[k],δu[l],δv[l],δl[i]]];

/* refernce Points */
points: [P[k]=matrix([x[k]],[y[k]]),
	     P[l]=matrix([x[l]],[y[l]]),
		 p[k]=matrix([x[k]+u[k]],[y[k]+v[k]]),
		 p[l]=matrix([x[l]+u[l]],[y[l]+v[l]])];

length: [subst(points,P[l])-subst(points,P[k]),
		 subst(points,p[l])-subst(points,p[k])];

pythagoras: [transpose(length[1]).length[1] = l[i]^2,
             transpose(length[2]).length[2] = (l[i]+Δl[i])^2];

kinematics: lhs(pythagoras[2])-lhs(pythagoras[1]) =
            rhs(pythagoras[2])-rhs(pythagoras[1]);

sol : solve(taylor(kinematics,
                   q[1],0,1),Δl[i])[1];

/* abbreviations */
simple : [x[l]=x[k]+Δx, y[l]=y[k]+Δy,
          Δx = xi[x]*l[i], Δy = xi[y]*l[i], EA[i]=k[i]*l[i]];

Virtual Strain Energy

Mit dem Prinzip der virtuellen Verrückungen schreiben wir die Gleichgewichtsbedingungen als

$\delta W=\delta W^{a}-\delta \Pi$

mit der virtuellen Formänderungsenergie δΠ aller Stäbe des Systems, also

$\delta \Pi =\displaystyle \sum _{i}\delta \Pi _{i}$

Für einen einzelnen Stab schrieben wir jetzt

${\begin{array}{ll}\delta \Pi &=\displaystyle A_{i}\int _{\ell }\sigma \cdot \delta \epsilon \;d{\tilde {x}}\\&=k_{i}\cdot \Delta \ell _{i}\cdot \delta \ell _{i}\end{array}}$

mit

$\displaystyle k_{i}={\frac {E\,A}{\ell _{i}}}$.

Mit den Ergebnissen von oben setzen wir also

in δΠ_i ein.

/* Einsetzen in das PvV */
sol : [sol,  subst(
   makelist(q[1][i]=q[2][i],i,1,5), sol)];

VSE: δΠ[i] = EA[i]/l[i]*Δl[i]*δl[i];
VSE : expand(subst(sol,VSE));

Solving

Die Terme schreiben wir noch etwas um, so dass man die Struktur hinter der virtuellen Formänderungsenergie erkennt - und erhalten:

$\delta \Pi _{i}={{k}_{i}}\cdot [{{\mathit {\delta \,u}}_{k}},{{\mathit {\delta \,v}}_{k}},{{\mathit {\delta \,u}}_{l}},{{\mathit {\delta \,v}}_{l}}]\cdot \underbrace {\begin{pmatrix}{{\xi }_{x}^{2}}&{{\xi }_{x}}\cdot {{\xi }_{y}}&-{{\xi }_{x}^{2}}&-{{\xi }_{x}}\cdot {{\xi }_{y}}\\{{\xi }_{x}}\cdot {{\xi }_{y}}&{{\xi }_{y}^{2}}&-{{\xi }_{x}}\cdot {{\xi }_{y}}&-{{\xi }_{y}^{2}}\\-{{\xi }_{x}^{2}}&-{{\xi }_{x}}\cdot {{\xi }_{y}}&{{\xi }_{x}^{2}}&{{\xi }_{x}}\cdot {{\xi }_{y}}\\-{{\xi }_{x}}\cdot {{\xi }_{y}}&-{{\xi }_{y}^{2}}&{{\xi }_{x}}\cdot {{\xi }_{y}}&{{\xi }_{y}^{2}}\end{pmatrix}} _{\displaystyle =:{\underline {\underline {K}}}_{E}}\cdot {\begin{pmatrix}{{u}_{k}}\\{{v}_{k}}\\{{u}_{l}}\\{{v}_{l}}\end{pmatrix}}$.

/* Element-Steifigkeitsmatrix K definieren */
K : makelist(makelist(coeff(
             coeff(subst(VSE, δΠ[i]),q[2][m]),q[1][n]),
                                              m,1,4),n,1,4);
print('δΠ[i],"=",k[i],"*",rest(q[2],-1),"*",
       funmake('matrix,ratsimp(subst(simple,K/k[i]))),"*",
       transpose(rest(q[1],-1)));

Post-Processing

Stabwerkskräfte und deren Knoten-Verschiebungen können wir nun mit geringem Aufwand bearbeiten:

Wir addieren die virtuelle Formänderungsenergie δΠ_i für jeden Stab zur gesamten virtuellen Formänderungsenergie δΠ zusammen.

Das wäre zwar anschaulich richtig - aber unpraktisch. So würden wir große Ausdrücke erhalten für δΠ. Einfacher und für die Behandlung mit dem Computer praktischer ist folgendes Vorgehen:

Ausgangspunkt ist die Element-Steifigkeitsmatrix

${{\underline {\underline {K}}}_{E}}$.

Wir erzeugen uns eine Steifigkeitsmatrix für die Verschiebungen aller Knoten des Stabwerks und sortieren die Elemente der Element-Steifigkeitsmatrix sukzessive und additiv in diese ein.

Wie das geht, zeigt T313.

---

Links

• ...

Literature

• ...