Gelöste Aufgaben/JUMP/E-Motor and Drive-Train

← Back to Start

Scope

Diagram of drive-train components.

The Drive-Train consists of a DC/DC-converter, a DC Motor and a gear-box.

• DC/DC-converter: is supplied with the battery voltage U_B, the output voltage is controlled by the driver via setpoint “p“.
• motor: is a standard DC brushed motor, the manufacturer provides only few information on its characteristics - we’ll need to improvise.
• gearbox: has a gear ratio of ratio of n_G=100, its shaft rotates at speed ω_W and delivers a torque M_W to the front wheels.

The task is: provide a mathematical model for the drive train that accounts for load-alterations imposed by the driver. And we assume losses in the two converters - DC/DC and gearbox - to be negligible.

Structure

Block diagram

The drive train receives a "gas"-pedal position "p" from the driver and a battery-voltage U_B.

It delivers a torque M_W on the wheel and creates an electric current I_M through the motor.

Drive-train components.

The sub-model consists of  DC/DC-converter, Motor and gear-box:

DC/DC Converter

Losses in the DC/DC converter shall be small - so for input port “1“ and output port “2“ we obtain

$U_{1}\cdot I_{1}=U_{2}\cdot I_{2}$ .

Let the “gas”-pedal-indicator “p“ control

$U_{2}=p\cdot U_{1}{\text{; }}0\leq p\leq 1.$

with

$0\leq p\leq 1{\text{ and }}U_{1}=U_{B}$

Motor

Brushed-DC motor

We use a common electric circuit representation for a series wound motor, the field coils are connected electrically in series with the armature coils, resistance R sums up all electrical losses in the motor.

Gearbox

Losses in the gearbox shall be small - so for input (ω_M, M_M) and output (ω_W, M_W) we obtain the fixed relation

$\omega _{M}\cdot M_{M}=\omega _{W}\cdot M_{W}$.

And we have only one differential equation for the electrical components:

${\frac {\displaystyle dI_{B}}{\displaystyle dt}}={\frac {\displaystyle U_{L}}{\displaystyle L}}$,

the remaining equations are algebraic.

Model

Electrical Components

For the motor, we find with Kirchhoff's law that

$U_{M}=U_{R}+U_{L}+e$

with U_R, U_L being the differential voltage over resistance R and inductance L respectively. “e” is the back electromagnetic force with

$e=k_{e}\cdot \omega _{M}$

and the electromotive force constant k_e. Note the ω_M is the differential rotational velocity between rotor and stator, i.e.

$\omega _{M}={\dot {\psi }}_{M}(t)+{\dot {\phi }}(t).$

Employing

$U_{R}=R\cdot I_{M},U_{L}=L\cdot {\frac {\displaystyle dI_{M}}{\displaystyle dt}}$

and using

$M_{M}=k_{t}\cdot I_{M}$

with the armature constant k_t, we have the complete set of equations.

From the above, we find

$L\cdot {\frac {\displaystyle d}{\displaystyle dt}}{I_{M}}(t)=U_{B}(t)\cdot p(t)-R\,{I_{M}}(t)-e$

and additionally the algebraic equations

${\begin{array}{ll}{I_{B}}&={I_{M}}\cdot \operatorname {p} (t),\\{U_{R}}&=R\cdot {I_{M}}(t),\\{U_{L}}&={U_{B}}\cdot \operatorname {p} (t)-R\cdot {I_{M}}(t)-e,\\{U_{M}}&={U_{B}}\cdot \operatorname {p} (t)\end{array}}$.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 16.04.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2021-02-08                            */
/* ref: Modelling and Simulation (TUAS)                */
/* description: virtual work of drive train electrics  */
/*******************************************************/

/*******************************************************/
/* declarations                                        */
/*******************************************************/
declare("φ", alphabetic);
declare("ψ", alphabetic);
declare("ω", alphabetic);

/*******************************************************/
/* kinematics                                          */
/*******************************************************/
kirchhoff : [U[M] = p(t)*U[B],
	     U[B]*I[B] = U[M]*I[M],
	     U[M] = U[R] + U[L] + e,
             e = k[e]*omega[M],
	     ω[M] = diff(ψ[M](t),t)+diff(φ(t),t),
	     U[R] = R*I[M](t),
	     U[L] = L * diff(I[M](t),t),
	     M[M] = k[t]*I[M](t)];

solve(kirchhoff[7], [diff(I[M](t),t)]);

Mechanical Components

The Virtual Work of d'Alembert forces, motor torque M_M and wheel torque M_W is

${\begin{array}{ll}\delta W&=-J_{M}\cdot {\ddot {\psi }}_{M}(t)\cdot \delta \psi _{M}+M_{M}\cdot \left(\psi _{M}+\phi (t)\right)-M_{W}\cdot \delta \psi _{W}\\&=0\end{array}}$.

Since the gearbox is built into the car, the wheel-side relative gear-box-angle is

${\tilde {\psi }}_{W}=\psi _{W}(t)-\phi (t)$

and on the motor-side

${\tilde {\psi }}_{M}=\psi _{M}(t)+\phi (t)$.

With the gear transmission ratio

$n_{G}={\frac {\displaystyle {\tilde {\psi }}_{M}}{\displaystyle {\tilde {\psi }}_{W}}}$

and

${\underline {q}}_{E}=\left({\begin{array}{c}\phi (t)\\\psi _{W}(t)\end{array}}\right)$

we find

$\delta W=\delta {\underline {q}}_{E}\cdot \left(-{\underline {\underline {M}}}_{E}\cdot {\underline {\ddot {q}}}_{E}+\left({\begin{array}{c}-n_{G}\cdot M_{M}\\+n_{G}\cdot M_{M}-M_{W}\\\end{array}}\right)\right)$

with

${\underline {\underline {M}}}_{E}={\begin{pmatrix}\left({{n}_{G}^{2}}+2{n_{G}}+1\right)\,{J_{M}}&-\left({{n}_{G}^{2}}+{n_{G}}\right)\,{J_{M}}\\-\left({{n}_{G}^{2}}+{n_{G}}\right)\,{J_{M}}&{{n}_{G}^{2}}\,{J_{M}}\end{pmatrix}}$.

We have thus "returned" all state variables to the Car-Body-submodel.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 16.04.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2021-02-08                            */
/* ref: Modelling and Simulation (TUAS)                */
/* description: virtual work of drive train mechanics  */
/*******************************************************/

/*******************************************************/
/* declarations                                        */
/*******************************************************/
declare("δ", alphabetic);
declare("φ", alphabetic);
declare("ψ", alphabetic);

/*******************************************************/
/* kinematics                                          */
/*******************************************************/
kin : [ψ[M,r] = n[G]*ψ[W,r],
       ψ[W,r] = ψ[W](t) - φ(t),
       ψ[M,r] = ψ[M](t) + φ(t)];
Q : [ψ[M](t),ψ[M,r],ψ[W,r]];
sol: ratsimp(solve(kin,Q))[1];


/* Principle of Virtual Work */
PVW: δW = - J[M]*diff(ψ[M](t),t,2)*δψ[M] + M[M]*(δψ[M]+δφ) - M[W]*δψ[W];

/* minimal coordinates */
q : [ φ(t), ψ[W](t)];
δq: [δφ   ,δψ[W]   ];

varia: [ψ[M](t)=δψ[M],ψ[M,r]=δψ[M,r],ψ[W,r]=δψ[W,r],
        ψ[W](t)=δψ[W], φ(t) =δφ];
sol : expand(append(sol, subst(varia,sol)));

PVW : expand(subst(sol,PVW));
PVW : ev(PVW,nouns);

eom : makelist(coeff(rhs(PVW),δq[i]),i,1,2);
eom : ratsimp(eom);

MM : funmake('matrix,makelist(makelist(ratsimp(coeff(-eom[i],'diff(q[j],t,2))),j,1,2),i,1,2));

rest : expand(eom + makelist(sum(MM[i,j]*diff(q[j],t,2),j,1,2),i,1,2));

print(δq, "*(-",MM,"*",transpose(diff(q,t,2)),"+",transpose(rest),") = 0")$

Consequently, the drive train has only one state-variable: I_M:

${\underline {q}}_{E}(t)=\left(I_{M}(t)\right)$

where

${\frac {\displaystyle d}{\displaystyle dt}}{I_{M}}(t)={\frac {\displaystyle {U_{B}}\operatorname {p} (t)-R\,{I_{M}}(t)-e}{\displaystyle L}}$

and with this algebraic equation

$e=k_{e}\cdot \left({\dot {\psi }}_{W}(t)+{\dot {\phi }}(t)\right)$.

Variables

name	symbol	unit
motor current	IM	A

Parameter

System parameters for the motor are k_T / k_e and R_M . For the stationary (${\frac {\displaystyle d\;I_{M}}{\displaystyle dt}}=0$) - condition, we derive

$M_{M}={\frac {{U_{M}}\,{k_{T}}-{k_{T}}\,{k_{e}}\omega _{M}}{R_{M}}}$,

so that we see:

1. under a "no-load"-condition M_M=0, we have

$\omega _{NL}={\frac {U_{M}}{k_{e}}}$

1. under the "stalled motor"-condition ω_St=0, we have

$M_{St}={\frac {k_{T}\cdot U_{M}}{R_{M}}}$

Thus - for U_M = 8 V - we can replace k_T / k_e, R_M by ω_NL and M_St, which make the system parameters to be selected more descriptive.

name	symbol	value	unit
no-load rotational speed	ωNL	1033	rad/s
stall-torque	MSt	0.042	N m
inductance	L	0.05	H
gear tramission ratio	nG	7	1

Back to Start →

---

References

• ...