Gelöste Aufgaben/DGEC

Aufgabenstellung

Wie sich die Balkenmodell von Euler-Bernoulli und Timoshenko in Ihrem Modellverhalten unterscheiden, untersuchen wir hier.

Lageplan

Ein Balken AB (Länge ℓ, Rechteck-Querschnitt h*b, Elastizitäts-Module E) ist in A fest eingespannt und in B durch eine Parallelführung gelagert.

In B wird er durch eine senkrechte Kraft F belastet.

Wir vergleichen die Auslenkung in B nach den Balken-Modellen von

• Euler-Bernoulli und
• Timoshenko

Der Balken-Querschnitt sei rechteckig mit den Abmessungen h, b:

Hier gelte für den Querschnitt h=b.

Lösung mit Maxima

Lorem Ipsum ....

Header

Wir suchen Näherungslösungen für die Verschiebung des Punktes B mit dem Prinzip der virtuellen Verrückungen auf Basis der Bewegungsgleichungen aus DGEB. Dazu setzen wir einmal die Verschiebung und Verdrehung der Querschnitte jeweils nach dem Modell des

• Timoshenko-Balkens und
• Euler-Bernoulli-Balkens

an.

📑 toggle code

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 15.08.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2018-12-09                            */
/* ref: Euler-Bernoulli Beam                           */
/* description: derives the equations of motion for    */
/*              the Timoshenko and EBB beam            */
/*******************************************************/
/* declare variational variables */
declare("δW", alphabetic); /* virtual work */
declare("δA", alphabetic); /* virtual work of implied external forces */
declare("δΠ", alphabetic); /* virtual strain energy */
declare("δw", alphabetic);
declare( "ϕ", alphabetic);
declare("δϕ", alphabetic);
declare( "Φ", alphabetic);
declare("δΦ", alphabetic);
declare( "ℓ", alphabetic);

Parameter

Parameter sind

$G=\frac{E}{2(\nu +1)},\nu =\frac{3}{10},A=h^2,I=\frac{h^4}{12}$

📑 toggle code

/*******************************************************/
/* parameters */
params: [GA=G*A, EI = E*I, G = E/(2*(1+nu)), nu=3/10, A=h^2, I=h^4/12];

Trial-Functions

Wir wählen als Trial-Functions für die Auslenkung w und die Verdrehung ϕ des Timoshenko-Balkens:

$\begin{array}{ll}w(x)& =W\cdot (3{\xi }^2-2{\xi }^3),\\ \varphi (x)& =\mathrm{\Phi }\cdot 4\xi (1-\xi )\end{array}$ .

Beim Euler-Bernoulli-Balken ist

$\varphi (x)=w^{\prime })(x)$

fest "eingebaut" - wir brauchen keine Trial-Funktion für ϕ.

Und so sehen die beiden Trial-Funtions aus:

Unsere Trialfunctions.

📑 toggle code

/*******************************************************/
/* trial functions */
trials : [w = W*(3*xi^2-2*xi^3), ϕ = Φ*4*xi*(1-xi)];
plot2d(subst(trials,[w/W, ϕ/Φ]), [xi,0,1], [xlabel, "ξ ->"], [ylabel, "φ ->"]);

Equilibrium-Conditions

Mit dem Prinzip der virtuellen Verrückungen lautet die Gleichgewichtsbedingung

$\begin{array}{ll}\delta W& =\delta W^a-\delta \mathrm{\Pi }\\ & \stackrel{!}{=}0\end{array}$.

Aus DGEB wissen wir für die Virtuelle Formänderungsenergie

... für den Timoshenko-Balken	... für den Euler-Bernoulli-Balken
$\begin{array}{lcl}\delta \mathrm{\Pi }=& \underset{0}{\overset{\ell }{\int }}& \frac{1}{4}GA(w^{\prime }-\varphi )\cdot (\delta w^{\prime }-\delta \varphi )\\ & +& EI{\varphi }^{\prime }\delta {\varphi }^{\prime }dx\end{array}$	$\delta \mathrm{\Pi }=\underset{0}{\overset{\ell }{\int }}EI{w}^{″}\delta w^{″}dx$

Und die virtuelle Arbeit der äußeren Kraft F ist

$\delta W^a=F\delta W$

📑 toggle code

/*******************************************************/
/* Principle of Virtual Work */
δΠ : [  1/4*GA*('diff(w,x)-ϕ)*'diff(δw,x)
      + 1/4*GA*(ϕ-'diff(w,x))*    δϕ
      + EI*'diff(ϕ,x)*'diff(δϕ,x),
        EI*'diff(w,x,2)*'diff(δw,x,2)];
δA : F*δW;

Q : [[ W, Φ, w, ϕ],
     [δW,δΦ,δw,δϕ]];
varia : makelist(Q[1][i]=Q[2][i],i,1,4);
     
δΠ : subst([xi=x/ℓ],subst(trials,subst(subst(varia,trials),δΠ)));
δΠ : integrate(ev(δΠ,nouns),x,0,ℓ);

Solving

Aus den Gleichgewichtsbedingungen erhalten wir die Gleichungen von

• W und Φ für den Timoshenko-Balken und
• W für den Euler-Bernoulli-Balken.

Timoshenko	Euler-Bernoulli
$\begin{array}{ll}\frac{3GA}{10\ell }\cdot W-\frac{GA}{5}\cdot \mathrm{\Phi }& =F,\\ (\frac{2GA\ell }{15}+\frac{16EI}{3\ell })\cdot \mathrm{\Phi }-\frac{GA}{5}\cdot W& =0\end{array}$	$\frac{12EI}{{\ell }^3}W=F$
mit der Lösung>
$W=\frac{GA{\ell }^3+40EI\ell }{12EIGA}F,\mathrm{\Phi }=\frac{{\ell }^2}{8EI}F$	$W=\frac{{\ell }^3}{12EI}F$

📑 toggle code

/*******************************************************/
/* equations of motion */
eom: [makelist(coeff(expand(δΠ[1]-δA),Q[2][i])=0,i,1,2),
               coeff(expand(δΠ[2]-δA),Q[2][1])=0];

sol: [solve(eom[1],[ W, Φ])[1], solve(eom[2], W)];

Post-Processing

Einsetzen der Parameter liefert die Verschiebung des Punkte

$\tilde{W}=\frac{W}{\frac{{\ell }^{3}F}{E{h}^4}}\text{ für }\alpha =\frac{h}{\ell }:$:

Wir sehen: für schlanke Balken bis α<0.2 können wir getrost mit der Euler-Bernoulli-Hypothese arbeiten - für "stäbigere" Balken brauchen wir mindestens das Timoshenko-Modell.

Vergleich von Timoshenko und Euler-Bernoulli-Modell.

📑 toggle code

/*******************************************************/
/* post-processing */
sol: ratsimp(subst([h=alpha*ℓ],subst(params,sol/(F*ℓ^3/(E*h^4)))));

plot2d([rhs(sol[1][1]),rhs(sol[2][1])], [alpha,0.0001,0.5], [y,0,3], logx, [xlabel, "α ->"], [ylabel, "W/(Fℓ^3/12EI) ->"], [legend,"Timoshenko","Euler-Bernoulli"]);

Links

• ...

Literature

• ...