Gelöste Aufgaben/FEAC

Aufgabenstellung

Hier berechnen wir die analytische Lösung zur Aufgabe FEAA.

Lageplan

Gesucht ist die analytische Lösung für die statische Auslenkung der beiden Massen. Wir arbeiten dabei mit dem Prinzip vom Minimum der Potentiellen Energie.

Lösung mit Maxima

Header

Koordinaten w₁, w₂

Als Koordinaten führen wir die Auslenkungen der Massen aus Ihrer Referenzlage ein, in der Referenzlage sind die Federn entspannt.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 15.08.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2017-09-14                            */
/* ref: FEM, PVMPE using two coordinates               */
/* description: solve by principle of minimum of p. E. */
/*******************************************************/

Equlibrium Conditions

Das Potential für das Aufstellen der Gleichgewichtsbeziehung lautet

$U=\Pi -A$,

wobei

${\begin{array}{ll}\displaystyle A&={{w}_{2}}\cdot g\cdot m+{{w}_{1}}\cdot g\cdot m,\\\Pi &\displaystyle ={\frac {{{\left({{w}_{2}}-{{w}_{1}}\right)}^{2}}\cdot k}{2}}+{\frac {{{w}_{1}^{2}}\cdot k}{2}}\end{array}}$

/* Potential Energy of system (equilibrium condition) */
parts : [/* work of gravitationaö forces */
         A = m*g*w[1]+m*g*w[2],
         /* strain energy*/
         Pi = 1/2*k*w[1]^2 + 1/2*k*(w[2]-w[1])^2];
 
PMPE : U= Pi-A;
PMPE : subst(parts,PMPE);

Solving

Die Gleichgewichtsbeziehungen nach dem Prinzips vom Minimum der Potentiellen Energie

$\displaystyle {\frac {dU}{dw_{i}}}{\stackrel {!}{=}}0$.

liefern die Gleichungen

${\begin{array}{l}g\cdot m+\left({{w}_{2}}-{{w}_{1}}\right)\cdot k-{{w}_{1}}\cdot k=0,\\g\cdot m-\left({{w}_{2}}-{{w}_{1}}\right)\cdot k=0\end{array}}$.

bzw. in Matrixform

${\underline {\underline {A}}}\cdot {\begin{pmatrix}w_{1}\\w2\end{pmatrix}}={\underline {b}}$

mit

${\underline {\underline {A}}}=k{\begin{pmatrix}2&-1\\-1&1\end{pmatrix}},{\underline {b}}=m\cdot g{\begin{pmatrix}1\\1\end{pmatrix}}$

mit der Lösung (vgl. Minimum Prinzipe)

$\displaystyle [{{w}_{1}}={\frac {2\cdot g\cdot m}{k}},{{w}_{2}}={\frac {3\cdot g\cdot m}{k}}]$.

/* pick individual equations */
equs : makelist(diff(subst(PMPE, -U),w[i])=0,i,1,2);
coord: makelist(w[i],i,1,2);

/* compose augmented coefficient matrix */
ACM : augcoefmatrix(equs,coord);

/* ordinary lineary system of equations*/
ole : [A = submatrix(ACM,3), b = -col(ACM,3)];

/* -> here we employ the shortcut via "solve" */
sol: solve(equs,coord)[1];

Post-Procesing

Potential U als Funtion von w₁, w₂.

Das dimensionslos-gemachte Potential U ist hier über w₁ und w₂ aufgetragen: man erkennt das Minimum des Potentials bei der berechneten Lösung.

/* plot results */
pltfct : expand(subst(makelist(w[i] = m*g/k*W[i],i,1,2),subst(parts, subst(PMPE,U/(m^2*g^2/k)))));
plot3d(pltfct,
    [W[1],2-10,2+10], [W[2],3-10,3+10],
    [z,-10,50], [legend, "potential energy"],
    [xlabel, "w[1]/(mg/k) →"], [ylabel, "w[2]/(mg/k) →"], [zlabel, "U →"]);

Links

• ...

Literature

• ...