Gelöste Aufgaben/Kita

Aufgabenstellung

Lageplan

Das skizzierte System ist ein Mast unter einer linear veränderlichen Windlast, der durch drei gleichmäßig über den Umfang verteilten Stäbe abgestützt wird.

Gesucht ist die analytische Lösung für ein Euler-Bernoulli-Modell des elastischen Mastes und der drei Dehnstäbe.

Sicht auf den Mast

Der Mast steht senkrecht dabei auf einer ebenen Unterlage mit dem festen Gelenklager „O“ und ist durch drei Stäbe abgestützt. Alle Stäbe sind in Punkt „H“ mit dem Mast verbunden und in den Punkten „A“, „B“ und „C“ gelenkig gelagert. Die Lager A, B und C sind gleichmäßig in einem Radius von R um O herum auf der Unterlage verteilt. Die Windlast hat den Maximalwert q_T und wirkt in der Ebene, die durch die Punkte A, O und H aufgespannt werden. Für die Geometrie des Masts gilt h₁ = 2 h₂, h₂ = √2 R, außerdem sei die Dehnsteifigkeiten der Stäbe E A₂=2 E A₁,E A₃=E A₁.

Der Mast hat ein zylindrisches Profil mit Innen- und Außendurchmesser d_i, d_a.

Mastprofil

Ein Knicken der drei Stäbe sei ausgeschlossen.

Lösung mit Maxima

Mit Maxima berechnen wir die allgemeine Lösung der Differentialgleichung des Euler-Bernoulli-Balkens und geben die Rand- und Übergangsbedingungen an. Der Mast soll in Längsrichtung nicht signifikant durch die Stabkräfte verformt werden, als Koordinaten der Verschiebung haben hier also nur die Auslenkungen Querrichtung sowie die Verdrehungen um diese Koordinatenrichtungen. Die Stabkräfte berechnen wir aus der Längung der Stäbe, dabei linearisieren wir bezüglich der Mast-Auslenkungen.

Header

Kern der Lösung ist die Berechnung der Integrationskonstanten des Euler-Bernoulli-Balkens. In diesem Beispiel führen wir zusätzliche Abkürzungen als Variablen ein, um die Rand- und Übergangsbedingungen einfacher formulieren zu können.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 21.05.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2022-08-19                            */
/* ref: NMM, Labor 1                                   */
/* Mast unter linear-veränderlicher Windlast           */
/*                                                     */
/*******************************************************/

Declarations

Wir übernehmen die Parameter aus der Aufgabenstellung, also

${\begin{array}{ccl}EA_{2}&=&2EA_{1},\\EA_{3}&=&EA_{1},\\h_{1}&=&2\;h_{2},\\h_{2}&=&{\sqrt {2}}\;R{\text{ und }}\\EA_{1}&=&\alpha \;EI/R^{2}\end{array}}$

x-y-z-Koordinaten

und definieren für die Berechnung der Stabkräfte die Referenzorte von A, B, C und H wie rechts skizziert im x, y, z Koordinatensystem zu

${\underline {r}}_{H}={\begin{pmatrix}h_{1}\\0\\0\end{pmatrix}},{\underline {r}}_{A}=R{\begin{pmatrix}0\\\sin(0)\\-\cos(0\end{pmatrix}},{\underline {r}}_{B}=R{\begin{pmatrix}0\\\sin(-2\pi /3)\\-\cos(-2\pi /3)\end{pmatrix}},{\underline {r}}_{C}=R{\begin{pmatrix}0\\\sin(+2\pi /3)\\-\cos(+2\pi /3)\end{pmatrix}}.$

Die Koordinaten der Vektoren, die jeweils in Stablängsrichtung von H zu den Lagerpunkten zeigen, sind dann

${\underline {r}}_{1}={\underline {r}}_{A}-{\underline {r}}_{H},{\underline {r}}_{2}={\underline {r}}_{B}-{\underline {r}}_{H}{\text{ und }}{\underline {r}}_{3}={\underline {r}}_{C}-{\underline {r}}_{H},$

die Referenz-Länge aller drei Stäbe ist damit

$L=||{\underline {r}}_{i}||,i=1,2{\text{ oder }}3$.

Und wir schreiben damit die Koordinaten der Einheitsvektoren dieser Stab-Längsrichtungen als

${\underline {e}}_{i}={\frac {\displaystyle {\underline {r}}_{i}}{\displaystyle L}},i=1,2,3$.

/*******************************************************/
/* declarations                                        */
/* *****************************************************/

/* parameter selection */
params: [EA[2]=2*EA[1],EA[3]=EA[1], h[1] = 2*h[2], h[2]=sqrt(2)*R, EA[1] = α*EI/R^2];
assume(R>0);
  
/* non-sclar variables */
declare(r,nonscalar,
        e,nonscalar);

/* geometry           **********************************/
/* points */
geo: [r[H] = matrix([ h[1], 0, 0]),
      r[A] = matrix([   0 , R*sin(    0   ),-R*cos(    0   )]),
      r[B] = matrix([   0 , R*sin(-2*%pi/3),-R*cos(-2*%pi/3)]),
      r[C] = matrix([   0 , R*sin(+2*%pi/3),-R*cos(+2*%pi/3)])];
geo: append(geo, subst(geo, [r[1] = r[A]-r[H],
                             r[2] = r[B]-r[H],
                             r[3] = r[C]-r[H]]));
geo: append(geo, [L = sqrt(subst(geo,r[1]).subst(geo,r[1]))]);
/* unit-vecotor coefficients */
geo: append(geo, makelist(e[i]=subst(geo,r[i]/L),i,1,3));

Integration Of Differential Equation for Euler-Bernoulli-Beam

In den Bereichen I und II haben wir jeweils eine Auslenkung des Masts in zwei Richtungen: z und y.

Wir nutzen die Standard-Nomenklatur für den Euler-Bernoulli-Balken und schrieben jeweils die Gleichgewichtsbedingungen

	... in z-Richtung als	... in y-Richtung als
	${\displaystyle E\,I\,w_{i}^{IV}(x)=q_{z},\;\;i=\{1,2\}}$.	${\displaystyle E\,I\,v_{i}^{IV}(x)=q_{y},\;\;i=\{1,2\}}$.
Für die Auslenkungen in z und y-Richtung geben wir hier die Bedeutung der Koordinaten vi(x), wi(x) je Bereich und deren Ableitungen an. Es ist
... die Querschnitts-Auslenkung:	$w_{i}(x)$	$v_{i}(x)$
... die Querschnitts-Verdrehung:	$\varphi _{i}(x)={\frac {\displaystyle d\,w_{i}(x)}{\displaystyle d\,x}}$	$\psi _{i}(x)={\frac {\displaystyle d\,v_{i}(x)}{\displaystyle d\,x}}$
... das Biege-Moment:	$M_{y,i}(x)=-EI{\frac {\displaystyle d^{2}\,w_{i}(x)}{\displaystyle d\,x^{2}}}$	$M_{z,i}(x)={\color {red}+}EI{\frac {\displaystyle d^{2}\,v_{i}(x)}{\displaystyle d\,x^{2}}}$ und
... die Querkraft:	$Q_{z,i}(x)=-EI{\frac {\displaystyle d^{3}\,w_{i}(x)}{\displaystyle d\,x^{3}}}$	$Q_{y,i}(x)=-EI{\frac {\displaystyle d^{3}\,v_{i}(x)}{\displaystyle d\,x^{3}}}$

Für die Streckenlasten auf den Mast gilt je Bereich "i" die lineare Funktion:

• ... in z-Richtung: $q_{z,i}(x)=q_{z,i-1}\cdot (1-{\frac {\displaystyle x_{i}}{\displaystyle h_{i}}})+q_{z,i}\cdot {\frac {\displaystyle x_{i}}{\displaystyle h_{i}}}$ und
• ... in y-Richtung: $q_{y,i}(x)=0$

wobei an den Knotenpunkten dies gilt:

${\begin{array}{ccl}q_{z,2}&=&{\color {red}-}q_{T}\\q_{z,1}&=&{\color {red}-}q_{T}\cdot {\frac {\displaystyle h_{1}}{\displaystyle h_{1}+h_{2}}}\\q_{z,0}&=&0.\end{array}}$

Mit diesen Ansätzen erhalten wir aus der Integration der Differentialbeziehung für den Euler-Bernoulli-Balken diese generischen (weil mit Integrationskonstanten behaftete) Lösungen:

Richung ...	z	y
Bereich I:	$w_{I}(x)=-{\frac {q_{T}x^{5}}{120\left({h_{2}}+{h_{1}}\right)EI}}+{c_{1}}{\frac {{x}^{3}}{6}}+{c_{2}}{\frac {{x}^{2}}{2}}+{c_{3}}\;x+{c_{4}}$	$v_{I}(x)={c_{5}}{\frac {{x}^{3}}{6}}+{c_{6}}{\frac {{x}^{2}}{2}}+{c_{7}}\;x+{c_{8}}$
Bereich II:	$w_{II}(x)=-{\frac {{\frac {h_{1}q_{T}\left({\frac {x^{4}}{24}}-{\frac {x^{5}}{120h_{2}}}\right)}{h_{2}+h_{1}}}+{\frac {q_{T}x^{5}}{120h_{2}}}}{EI}}+{c_{9}}{\frac {{x}^{3}}{6}}+{c_{10}}{\frac {{x}^{2}}{2}}+{c_{11}}\;x+{c_{12}}$	$v_{II}(x)={c_{13}}{\frac {{x}^{3}}{6}}+{c_{14}}{\frac {{x}^{2}}{2}}+{c_{15}}\;x+{c_{16}}$

Wir haben also Bereich I und II für Richtungen z und y mit jeweils 4 integrationskonstanten - das macht insgesamt 16 zu bestimmende Variablen.

/*******************************************************/
/* differential equations for EB-beam                  */
/* and generic solution                                */
/* *****************************************************/
dgl: diff(w(x),x,4)=-1/EI*(q[i-1]*(1-x/h[i])+q[i]*x/h[i]);
dgl: integrate(integrate(integrate(integrate(dgl,x),x),x),x);

sectionReplace: [[%c1=c[ 1],%c2=c[ 2],%c3=c[ 3],%c4=c[ 4], q[i-1]=  0 , q[i]=q[H],h[i]=h[1]           ],
                 [%c1=c[ 9],%c2=c[10],%c3=c[11],%c4=c[12], q[i-1]=q[H], q[i]=q[T],h[i]=h[2]           ],
                 [%c1=c[ 5],%c2=c[ 6],%c3=c[ 7],%c4=c[ 8], q[i-1]=  0 , q[i]= 0  ,h[i]=h[1], w(x)=v(x)],
                 [%c1=c[13],%c2=c[14],%c3=c[15],%c4=c[16], q[i-1]=  0 , q[i]= 0  ,h[i]=h[2], w(x)=v(x)]];
/* create 4 lists for each section */
sol: [makelist(subst(sectionReplace[i],[dgl]),i,1,2),
      makelist(subst(sectionReplace[i],[dgl]),i,3,4)];
sol: subst([q[H] = q[T]*h[1]/(h[1]+h[2])],sol);

/* tilt-angles, bending and cross-sec. force   */
/* see Gross e.a.: Technische Mechanik 2, p156 */
for dir:1 thru 2 do
   for sec:1 thru 2 do
      (sol[dir][sec]: append(sol[dir][sec], [[  φ(x) ,  ψ(x) ][dir] =                 diff(subst(sol[dir][sec],[w(x),v(x)][dir]),x  )]),
       sol[dir][sec]: append(sol[dir][sec], [[M[y](x),M[z](x)][dir] = [-1,+1][dir]*EI*diff(subst(sol[dir][sec],[w(x),v(x)][dir]),x,2)]),
       sol[dir][sec]: append(sol[dir][sec], [[Q[z](x),Q[y](x)][dir] = [-1,-1][dir]*EI*diff(subst(sol[dir][sec],[w(x),v(x)][dir]),x,3)]));

Forces in Supporting Rods

Die Zugkräfte S_i in den drei Dehnstäben erhalten wir aus der Stab-Längung $\Delta L_{i}$, also

$S_{i}=EA_{i}{\frac {\displaystyle \Delta L_{i}}{\displaystyle L}}$

Freikörperbild in der x-z-Ebene

Freikörperbild in der y-z-Ebene

Die Bilder rechts zeigen die Stabkräfte am freigeschnittenen Punkt H des Masts. Bei der Berechnung der Stabkräfte ist $\Delta L_{i}$ die Längung von Stab i. Die Kraft hat als Richtung ${\underline {e}}_{i}$, also ist

${\underline {S}}_{i}=S_{i}\cdot {\underline {e}}_{i}$.

Es fehlt nur noch die Stablängung $\Delta L_{i}$ je Stab – und die bekommen wir aus dem Vergleich der Geometrie des Stabes im verformten und unverformten Zustand.

Analog zur Länge des Stabes im unverformten Zustand ist nun der Ort von H

${\tilde {\underline {r}}}_{H}={\underline {r}}_{H}+{\begin{pmatrix}0\\V_{H}\\W_{H}\end{pmatrix}}$

und die Koeffizienten der Stab-Vektoren sind nun

${\tilde {\underline {r}}}_{1}={\underline {r}}_{A}-{\tilde {\underline {r}}}_{H},\ldots$.

Die Differenzlänge erhalten wir – nach dem gleichen Schema wie oben – aus

$\Delta L_{i}=||{\tilde {\underline {r}}}_{i}||-L$.

In

$\Delta L_{i}=\Delta L_{i}(V_{H},W_{H}),$

steht nun allerdings ein komplizierter, nichtlinearer Ausdruck. Den linearisieren wir, schreiben also

$\Delta L_{i}:=\left.{\frac {\partial \Delta L_{i}}{\partial V_{H}}}\right\vert _{V_{H}=0,W_{H}=0}\cdot V_{H}+\left.{\frac {\partial \Delta L_{i}}{\partial W_{H}}}\right\vert _{V_{H}=0,W_{H}=0}\cdot W_{H}$

und erhalten damit

${\begin{array}{llll}S_{1}&=&R\cdot {\frac {\displaystyle E\,A_{1}}{\displaystyle L^{2}}}&\cdot \;\;\;\;\;\;\;W_{H}\\S_{2}&=&R\cdot {\frac {\displaystyle E\,A_{2}}{\displaystyle L^{2}}}&\cdot \left(-{\frac {\displaystyle 1}{\displaystyle 2}}W_{H}+{\frac {\displaystyle {\sqrt {3}}}{\displaystyle 2}}V_{H}\right)\\S_{3}&=&R\cdot {\frac {\displaystyle E\,A_{3}}{\displaystyle L^{2}}}&\cdot \left(-{\frac {\displaystyle 1}{\displaystyle 2}}W_{H}-{\frac {\displaystyle {\sqrt {3}}}{\displaystyle 2}}V_{H}\right)\end{array}}$

/*******************************************************/
/* forces S[i] in supporing rods                       */
/* S[i] as a function of W[H] and V[H] *****************/
/* *****************************************************/
ΔL: subst(geo,[r[A] - (r[H]+matrix([0,V[H],W[H]])),
               r[B] - (r[H]+matrix([0,V[H],W[H]])),
               r[C] - (r[H]+matrix([0,V[H],W[H]]))]);
ΔL: makelist(sqrt(ΔL[i].ΔL[i])-subst(geo,L),i,1,3);
displ: [W[H],V[H]];
null : makelist(displ[i]=0,i,1,2);
/* linearize .... */
ΔL: sum(subst(null, diff(ΔL,displ[j]))*displ[j],j,1,2);
S : makelist(EA[i]*ΔL[i]/subst(geo,L),i,1,3);

Boundary- and Transition-Conditions

Aus der Lösung der Differentialgleichungen für zwei Raumrichtungen und zwei Bereiche haben wir 16 Integrationskonstanten, die wir bestimmen müssen. Hinzu kommen V_H und W_H für den Knoten H. Um hier konsistent zu sein, führen wir für die Knoten H und T – "Top", die Mastspitze – die Koordinaten der Auslenkung und Kippung der Querschnitte ein, also zusammen die 8 Knotenvariablen

Richtung	z	y
Knoten T Auslenkung Kippwinkel	$W_{T}$, $\Phi _{T}$	$V_{T}$, $\Psi _{T}$
Knoten H Auslenkung Kippwinkel	$W_{H}$, $\Phi _{H}$	$V_{H}$, $\Psi _{H}$
Knoten 0 Auslenkung Kippwinkel	$0$, $c_{3}$	$0$, $c_{7}$

In O hätten wir auch noch die Variablen $\Phi _{O}$ und $\Psi _{O}$ einführen könnten. Die sind allerdings identisch mit $c_{3}$ und $c_{7}$.

Alle Unbekannten fassen wir nun in

${\underline {c}}=\left({\begin{array}{l}c_{01}\\c_{02}\\\ldots \\c_{15}\\c_{16}\\W_{H}\\V_{H}\\\Phi _{H}\\\Psi _{H}\\W_{T}\\V_{T}\\\Phi _{T}\\\Psi _{T}\end{array}}\right)$

zusammen.

Für diese 24 Unbekannten brauchen wir nun 24 Gleichungen – Geometriebedingungen und Kräfte-/Momentengleichgewichte.

... aus Rand "O"

Das gelenkige Lager in O erlaubt keine Verschiebung und es nimmt keine Momente auf. Daraus ergeben sich die Geometrischen Bedingungen:

1. $w_{I}(0)=0$
2. $v_{I}(0)=0$

und die Kraft- und Momenten-Randbedingungen:

3. $M_{z,I}(0)=0$
4. $M_{y,I}(0)=0$

... aus Übergang "H"

Geometrische Bedingungen:

5. $w_{I}(h_{1})=W_{H}$
6. $v_{I}(h_{1})=V_{H}$
7. $w_{II}(0)=W_{H}$
8. $v_{II}(0)=V_{H}$
9. $\varphi _{I}(h_{1})=\Phi _{H}$
10. $\psi _{I}(h_{1})=\Psi _{H}$
11. $\varphi _{II}(0)=\Phi _{H}$
12. $\psi _{II}(0)=\Psi _{H}$

Kraft- und Momenten-Randbedingungen: Hier wird es spannend: durch die drei Stäbe werden Kräfte eingeleitet,

Schnittbild für Knoten H
hier ohne Schnittmomente

Einfach sind die Momenten-Gleichgewichtsbedingungen am Knoten H - hier wird kein externes Moment eingeleitet, die beiden Schnittmomente müssen gleich sein:

13. $M_{y,I}(h_{1})=M_{y,II}(0)$
14. $M_{z,I}(h_{1})=M_{z,II}(0)$

Für die Kraft-Übergangsbedingungen in y- und z-Richtung müssen wir nun allerdings die Seilkräfte mit einbeziehen.

15. $Q_{y,I}(h_{1})=Q_{y,II}(0)+\sum _{k=1}^{3}S_{i}\cdot e_{i,y}$
16. $Q_{z,I}(h_{1})=Q_{z,II}(0)+\sum _{k=1}^{3}S_{i}\cdot e_{i,z}$

Dabei nehmen wir vom Einheitsvektor nur die Komponente der jeweiligen Raumrichtung, also z.B. $e_{i,y}$ aus ${\underline {e}}_{i}=\left({\begin{array}{c}e_{i,x}\\e_{i,y}\\e_{i,z}\end{array}}\right)$.

... aus Rand "T"

Geometrische Bedingungen: Für die geometrischen Randbedingen haben wir nur die Gleichungen, die unsere Abkürzungen einführen, also

17. $w_{II}(h_{2})=W_{T}$
18. $v_{II}(h_{2})=V_{T}$
19. $\varphi _{II}(h_{2})=\Phi _{T}$
20. $\psi _{II}(h_{2})=\Psi _{T}$

Kraft- und Momenten-Randbedingungen: Hier ist Rand frei: Kräfte und Momente in T müssen Null sein:

21. $M_{y,II}(h_{2})=0$
22. $M_{z,II}(h_{2})=0$
23. $Q_{y,II}(h_{2})=0$
24. $Q_{z,II}(h_{2})=0$

Damit sind wir komplett - wir haben 24 Gleichungen für 24 Unbekannte. Das Gleichungssystem können wir nun als

${\underline {\underline {A}}}\cdot {\underline {c}}={\underline {b}}$

schreiben - oder mit den oben angegebenen Systemparametern ausgeschreiben als

${\begin{pmatrix}0&0&0&1&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0\\0&0&0&0&0&0&0&1&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0\\0&-EI&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0\\0&0&0&0&0&EI&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0\\{\frac {{h}_{1}^{3}}{6}}&{\frac {{h}_{1}^{2}}{2}}&{h_{1}}&1&0&0&0&0&0&0&0&0&0&0&0&0&-1&0&0&0&0&0&0&0\\0&0&0&0&{\frac {{h}_{1}^{3}}{6}}&{\frac {{h}_{1}^{2}}{2}}&{h_{1}}&1&0&0&0&0&0&0&0&0&0&-1&0&0&0&0&0&0\\0&0&0&0&0&0&0&0&0&0&0&1&0&0&0&0&-1&0&0&0&0&0&0&0\\0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&1&0&-1&0&0&0&0&0&0\\{\frac {{h}_{1}^{2}}{2}}&{h_{1}}&1&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0&-1&0&0&0&0&0\\0&0&0&0&{\frac {{h}_{1}^{2}}{2}}&{h_{1}}&1&0&0&0&0&0&0&0&0&0&0&0&0&-1&0&0&0&0\\0&0&0&0&0&0&0&0&0&0&1&0&0&0&0&0&0&0&-1&0&0&0&0&0\\0&0&0&0&0&0&0&0&0&0&0&0&0&0&1&0&0&0&0&-1&0&0&0&0\\-{h_{1}}&-1&0&0&0&0&0&0&0&1&0&0&0&0&0&0&0&0&0&0&0&0&0&0\\0&0&0&0&{h_{1}}&1&0&0&0&0&0&0&0&-1&0&0&0&0&0&0&0&0&0&0\\-1&0&0&0&0&0&0&0&1&0&0&0&0&0&0&0&{\frac {\left({EA_{3}}+{EA_{2}}+4{EA_{1}}\right){{R}^{2}}}{{\sqrt {{{R}^{2}}+{{h}_{1}^{2}}}}\left(4EI{{R}^{2}}+4{{h}_{1}^{2}}\,EI\right)}}&{\frac {\left({\sqrt {3}}{EA_{3}}-{\sqrt {3}}{EA_{2}}\right){{R}^{2}}}{{\sqrt {{{R}^{2}}+{{h}_{1}^{2}}}}\left(4EI{{R}^{2}}+4{{h}_{1}^{2}}\,EI\right)}}&0&0&0&0&0&0\\0&0&0&0&-1&0&0&0&0&0&0&0&1&0&0&0&{\frac {\left({\sqrt {3}}{EA_{3}}-{\sqrt {3}}{EA_{2}}\right){{R}^{2}}}{{\sqrt {{{R}^{2}}+{{h}_{1}^{2}}}}\left(4EI{{R}^{2}}+4{{h}_{1}^{2}}\,EI\right)}}&{\frac {\left(3{EA_{3}}+3{EA_{2}}\right){{R}^{2}}}{{\sqrt {{{R}^{2}}+{{h}_{1}^{2}}}}\left(4EI{{R}^{2}}+4{{h}_{1}^{2}}\,EI\right)}}&0&0&0&0&0&0\\0&0&0&0&0&0&0&0&{\frac {{h}_{2}^{3}}{6}}&{\frac {{h}_{2}^{2}}{2}}&{h_{2}}&1&0&0&0&0&0&0&0&0&-1&0&0&0\\0&0&0&0&0&0&0&0&0&0&0&0&{\frac {{h}_{2}^{3}}{6}}&{\frac {{h}_{2}^{2}}{2}}&{h_{2}}&1&0&0&0&0&0&-1&0&0\\0&0&0&0&0&0&0&0&{\frac {{h}_{2}^{2}}{2}}&{h_{2}}&1&0&0&0&0&0&0&0&0&0&0&0&-1&0\\0&0&0&0&0&0&0&0&0&0&0&0&{\frac {{h}_{2}^{2}}{2}}&{h_{2}}&1&0&0&0&0&0&0&0&0&-1\\0&0&0&0&0&0&0&0&-{h_{2}}&-1&0&0&0&0&0&0&0&0&0&0&0&0&0&0\\0&0&0&0&0&0&0&0&0&0&0&0&{h_{2}}&1&0&0&0&0&0&0&0&0&0&0\\0&0&0&0&0&0&0&0&-1&0&0&0&0&0&0&0&0&0&0&0&0&0&0&0\\0&0&0&0&0&0&0&0&0&0&0&0&-1&0&0&0&0&0&0&0&0&0&0&0\end{pmatrix}}\cdot {\underline {c}}={\begin{pmatrix}0\\0\\0\\0\\{\frac {{{h}_{1}^{5}}{q_{T}}}{\left(120{h_{2}}+120{h_{1}}\right)\,EI}}\\0\\0\\0\\{\frac {{{h}_{1}^{4}}{q_{T}}}{\left(24{h_{2}}+24{h_{1}}\right)\,EI}}\\0\\0\\0\\-{\frac {{{h}_{1}^{3}}{q_{T}}}{\left(6{h_{2}}+6{h_{1}}\right)\,EI}}\\0\\-{\frac {{{h}_{1}^{2}}{q_{T}}}{\left(2{h_{2}}+2{h_{1}}\right)\,EI}}\\0\\{\frac {\left({{h}_{2}^{5}}+5{h_{1}}{{h}_{2}^{4}}\right){q_{T}}}{\left(120{h_{2}}+120{h_{1}}\right)\,EI}}\\0\\{\frac {\left({{h}_{2}^{4}}+4{h_{1}}{{h}_{2}^{3}}\right){q_{T}}}{\left(24{h_{2}}+24{h_{1}}\right)\,EI}}\\0\\-{\frac {\left({{h}_{2}^{3}}+3{h_{1}}{{h}_{2}^{2}}\right){q_{T}}}{\left(6{h_{2}}+6{h_{1}}\right)\,EI}}\\0\\-{\frac {\left({{h}_{2}^{2}}+2{h_{1}}{h_{2}}\right){q_{T}}}{\left(2{h_{2}}+2{h_{1}}\right)\,EI}}\\0\end{pmatrix}}$

/******************************************************/
/* Boundary Value Problem Formulation                 */
/* ****************************************************/

/* point "O" - geometry */
BC: [subst(x=  0  ,  subst(sol[1][1],w(x))     )=  0 ,
     subst(x=  0  ,  subst(sol[2][1],v(x))     )=  0 ,
/* point "O" - bending moments */                 
     subst(x=  0  ,  subst(sol[1][1],M[y](x))  )=  0 ,
     subst(x=  0  ,  subst(sol[2][1],M[z](x))  )=  0 ,
/* point "H" - geometry */
     subst(x= h[1],  subst(sol[1][1],w(x))     )=W[H],
     subst(x= h[1],  subst(sol[2][1],v(x))     )=V[H],
     subst(x=  0  ,  subst(sol[1][2],w(x))     )=W[H],
     subst(x=  0  ,  subst(sol[2][2],v(x))     )=V[H],
     subst(x= h[1],  subst(sol[1][1],φ(x))     )=Φ[H],
     subst(x= h[1],  subst(sol[2][1],ψ(x))     )=Ψ[H],
     subst(x=  0  ,  subst(sol[1][2],φ(x))     )=Φ[H],
     subst(x=  0  ,  subst(sol[2][2],ψ(x))     )=Ψ[H],
/* point "H" - bending moments */                 
     subst(x= h[1],  subst(sol[1][1],M[y](x))  )=subst(x=  0  ,  subst(sol[1][2],M[y](x))  ),
     subst(x= h[1],  subst(sol[2][1],M[z](x))  )=subst(x=  0  ,  subst(sol[2][2],M[z](x))  ),
/* point "H" - forces */
     subst(x= h[1],  subst(sol[1][1],Q[z](x))  )=subst(x=  0  ,  subst(sol[1][2],Q[z](x))  ) + sum(S[i]*subst(geo,e[i]),i,1,3)[1][3],
     subst(x= h[1],  subst(sol[2][1],Q[y](x))  )=subst(x=  0  ,  subst(sol[2][2],Q[y](x))  ) + sum(S[i]*subst(geo,e[i]),i,1,3)[1][2],
/* point "T" (Top) - geometry */
     subst(x= h[2],  subst(sol[1][2],w(x))     )=W[T],
     subst(x= h[2],  subst(sol[2][2],v(x))     )=V[T],
     subst(x= h[2],  subst(sol[1][2],φ(x))     )=Φ[T],
     subst(x= h[2],  subst(sol[2][2],ψ(x))     )=Ψ[T],
/* point "T" (Top) - bending moment */
     subst(x= h[2],  subst(sol[1][2],M[y](x))  ) = 0,
     subst(x= h[2],  subst(sol[2][2],M[z](x))  ) = 0,
/* point "T" (Top) - forces */
     subst(x= h[2],  subst(sol[1][2],Q[z](x))  ) = 0,
     subst(x= h[2],  subst(sol[2][2],Q[y](x))  ) = 0];

C: append(makelist(c[i],i,16), [W[H],V[H],Φ[H],Ψ[H],W[T],V[T],Φ[T],Ψ[T]]);

scale: [1,1,1,1,1,1,1,1,1,1,
        1,1,EI,EI,EI,EI,1,1,1,1,
        EI,EI,EI,EI];
for i:1 thru 24 do BC[i]:BC[i]/scale[i];

ACM: ratsimp(augcoefmatrix(BC,C));

a: submatrix(ACM,25);
b:-col(ACM,25);

Solving

Dieses lineare Gleichungssystem kann man gerade noch analytisch lösen - wir finden die gesuchten Integrationskonstanten und Knotenvariablen

${\begin{array}{l}{c_{1}}=0\\{c_{2}}=0\\{c_{3}}={\frac {{{2}^{\frac {9}{2}}}{{R}^{3}}{q_{T}}\alpha -2187{{R}^{3}}{q_{T}}}{180EI\alpha }}\\{c_{4}}=0\\{c_{5}}=0\\{c_{6}}=0\\{c_{7}}=-{\frac {{{3}^{\frac {7}{2}}}{{R}^{3}}{q_{T}}}{20EI\alpha }}\\{c_{8}}=0\\{c_{9}}={\frac {5R{q_{T}}}{3{\sqrt {2}}EI}}\\{c_{10}}=-{\frac {8{{R}^{2}}{q_{T}}}{9EI}}\\{c_{11}}=-{\frac {{{2}^{\frac {13}{2}}}{{R}^{3}}{q_{T}}\alpha +2187{{R}^{3}}{q_{T}}}{180EI\alpha }}\\{c_{12}}=-{\frac {243{{R}^{4}}{q_{T}}}{5{\sqrt {2}}EI\alpha }}\\{c_{13}}=0\\{c_{14}}=0\\{c_{15}}=-{\frac {{{3}^{\frac {7}{2}}}{{R}^{3}}{q_{T}}}{20EI\alpha }}\\{c_{16}}=-{\frac {{{3}^{\frac {7}{2}}}{{R}^{4}}{q_{T}}}{5{\sqrt {2}}EI\alpha }}\\{W_{H}}=-{\frac {243{{R}^{4}}{q_{T}}}{5{\sqrt {2}}EI\alpha }}\\{V_{H}}=-{\frac {{{3}^{\frac {7}{2}}}{{R}^{4}}{q_{T}}}{5{\sqrt {2}}EI\alpha }}\\{{\Phi }_{H}}=-{\frac {{{2}^{\frac {13}{2}}}{{R}^{3}}{q_{T}}\alpha +2187{{R}^{3}}{q_{T}}}{180EI\alpha }}\\{{\Psi }_{H}}=-{\frac {{{3}^{\frac {7}{2}}}{{R}^{3}}{q_{T}}}{20EI\alpha }}\\{W_{T}}=-{\frac {70{{R}^{4}}{q_{T}}\alpha +2187{\sqrt {2}}{{R}^{4}}{q_{T}}}{60EI\alpha }}\\{V_{T}}=-{\frac {{{3}^{\frac {9}{2}}}{{R}^{4}}{q_{T}}}{5{{2}^{\frac {3}{2}}}EI\alpha }}\\{{\Phi }_{T}}=-{\frac {119{\sqrt {2}}{{R}^{3}}{q_{T}}\alpha +2187{{R}^{3}}{q_{T}}}{180EI\alpha }}\\{{\Psi }_{T}}=-{\frac {{{3}^{\frac {7}{2}}}{{R}^{3}}{q_{T}}}{20EI\alpha }}\end{array}}$

/*******************************************************/
/* solve for integration constants                     */
/* *****************************************************/
consts: ratsimp(solve(ratsimp(subst(params,BC)),C)[1]);

sol: subst(consts,sol);
toReplace: [x=ξ*h[1],x=ξ*h[2]];
for dir: 1 thru 2 do
   for sec: 1 thru 2 do
     (print(dir,sec),
      for elem: 1 thru 4 do
      sol[dir][sec][elem]: lhs(sol[dir][sec][elem])=subst(toReplace[sec],rhs(sol[dir][sec][elem])));

Post-Processing

Die Verläufe der Auslenkung und Schnittkräfte - hier exemplarisch das Biegemoment - können wir nun plotten:

Auslenkung der Querschnitte

Biegemomente

/*******************************************************/
/* post-processing                                     */
/*******************************************************/

/* what is a reasonable size is α ?                               */
/* geopar: [A[1]= π/ 4*d[r]^2, d[r]=1*cm,                          
             I  = π/64*(d[o]^4-d[i]^4), d[o]=10*cm, d[i]=9*cm,     
             R  = h[2]/sqrt(2), h[2]=500*cm,
             α  = A[1]*R^2/I              ]                        */

sol: ratsimp(subst([α=500],subst(params,sol)));

toPlot: ratsimp([subst(sol[1][1],w(x)/R),subst(sol[1][2],w(x)/R),subst(sol[2][1],v(x)/R),subst(sol[2][2],v(x)/R)]/(q[T]*R^3/6/EI));
plot2d([[parametric, ξ, toPlot[1], [ξ,0,1]],
        [parametric, 1+ξ*subst(params,h[2]/h[1]), toPlot[2], [ξ,0,1]],
        [parametric, ξ, toPlot[3], [ξ,0,1]],
        [parametric, 1+ξ*subst(params,h[2]/h[1]), toPlot[4], [ξ,0,1]]],
        [legend, "w(x), sec 1", "w(x), sec 2", "v(x), sec 1", "v(x), sec 2"],
        [xlabel, "x/h_1->"],[ylabel, "w(x)/W_0, v(x)/V_0 ->"])$

toPlot: ratsimp([subst(sol[1][1],M[y](x)),subst(sol[1][2],M[y](x)),subst(sol[2][1],M[z](x)),subst(sol[2][2],M[z](x))]/(q[T]*R^2));
plot2d([[parametric, ξ, toPlot[1], [ξ,0,1]],
        [parametric, 1+ξ*subst(params,h[2]/h[1]), toPlot[2], [ξ,0,1]],
        [parametric, ξ, toPlot[3], [ξ,0,1]],
        [parametric, 1+ξ*subst(params,h[2]/h[1]), toPlot[4], [ξ,0,1]]],
        [legend, "M_y(x), sec 1", "M_y(x), sec 2", "M_z(x), sec 1", "M_z(x), sec 2"],
        [xlabel, "x/h_1->"],[ylabel, "M(x)/M_0 ->"])$

---

Links

• ...

Literature

• ...