Gelöste Aufgaben/W8Zv

Aufgabenstellung

Zu den tabellierten Standardlösungen für den Euler-Bernoulli-Blaken berechnen wir eine Näherungslösung für einen beidseitig gelenkig gelagerten Euler-Bernoulli-Balken:

Lageplan

Hier soll mit dem Ansatz mit der Methode der Finiten Elemente gearbeitet werden. Gesucht ist das Verschiebungsfeld w(x) im Vergleich von FEM und analytischer Lösung.

Diese Aufgabe ist eng verwandt mit W8Zt und W8Zu.

Lösung mit Maxima

Mit dem Föppl-Symbol "<>", sowie

$\alpha =a/\ell$, $\beta =1-\alpha$ und $\xi =x/\ell$

ist die analytische Lösung:

$EIw(x)=\frac{F{\ell }^3}{6}[\beta \xi (1-{\beta }^2-{\xi }^2)+<\xi -\alpha {>}^3]$.

Bei dieser Lösung hat die unabhängige Koordinate x ihren Ursprung in A - wir verwenden unten einen anderen Ursprung!

Mit den passenden Ansatzfunktionen berechnen wir eine Näherungslösung des Problems nach dem Prinzip der virtuellen Verrückungen.

Header

Bei der Methode der Finiten Elemente setzen wir die virtuelle Formänderungsenergie des Systems additiv aus den Anteilen je Element zusammen. Hier arbeiten wir mit zwei Elementen, die am Kraft-Angriffspunkt aneinander stoßen.

Also ist

$\delta \mathrm{\Pi }=\delta {\mathrm{\Pi }}_1+\delta {\mathrm{\Pi }}_2$ ,

die virtuelle Arbeit der äußeren Kraft F ist

$\delta W^a=F\cdot \delta w_F$ .

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 15.08.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2017-11-21                            */
/* ref: TM-C, Labor 3 - aus Gross, Augf. TM 2,Biegestab*/
/* description: finds the approx. solution employing   */
/*              the FEM-approach                       */
/*******************************************************/

Virtual Strain-Energy per Element

Aus der Finite Elemente Methode kennen wir die virtuelle Formänderungsenergie eines Balkenelements

$\delta {\mathrm{\Pi }}_i=(\delta W_{i-1},\delta {\mathrm{\Phi }}_{i-1},\delta W_i,\delta {\mathrm{\Phi }}_i)\cdot {\underset{\_}{\underset{\_}{K}}}_i\cdot \left(\begin{array}{l}{W}_{i-1}\\ {\mathrm{\Phi }}_{i-1}\\ W_i\\ {\mathrm{\Phi }}_i\end{array}\right)$

für das klassische x-z-Koordinatensystem des Euler-Bernoulli-Balkens und mit der Element-Steifigkeitsmatrix

${\underset{\_}{\underset{\_}{K}}}_i=\frac{{E}{I}}{{\ell }_E^3}\cdot \left(\begin{array}{cccc}12& 6\cdot {\ell }_E& -12& 6\cdot {\ell }_E\\ 6\cdot {\ell }_E& 4\cdot {\ell }_E^2& -6\cdot {\ell }_E& 2\cdot {\ell }_E^2\\ -12& -6\cdot {\ell }_E& 12& -6\cdot {\ell }_E\\ 6\cdot {\ell }_E& 2\cdot {\ell }_E^2& -6\cdot {\ell }_E& 4\cdot {\ell }_E^2\end{array}\right)$.

/* virtual strain engergy */
K[e] : EI/l[i]^3*matrix([12,6*l[i],-12,6*l[i]],
                        [6*l[i],4*l[i]^2,-6*l[i],2*l[i]^2],
                        [-12,-6*l[i],12,-6*l[i]],
                        [6*l[i],2*l[i]^2,-6*l[i],4*l[i]^2]);

Equilibrium Conditions

Das Gesamt-Gleichungssystem für die Koordinaten

$\underset{\_}{Q}=\left(\begin{array}{l}{W}_0\\ {\mathrm{\Phi }}_0\\ W_1\\ {\mathrm{\Phi }}_1\\ W_2\\ {\mathrm{\Phi }}_2\end{array}\right)$

ist

${\underset{\_}{\underset{\_}{K}}}_0\cdot \underset{\_}{Q}=\underset{\_}{P}$

mit der 6x6 Matrix K₀. In diese Matrix müssen wir jetzt die Element-Steifigkeitsmatrizen für das Element 1 und das Element 2 hineinaddieren, also

${\underset{\_}{\underset{\_}{K}}}_0=EI\cdot \left(\begin{array}{cccccc}\frac{12}{{\ell }_1^3}& \frac{6}{{\ell }_1^2}& -\frac{12}{{\ell }_1^3}& \frac{6}{{\ell }_1^2}& 0& 0\\ \frac{6}{{\ell }_1^2}& \frac{4}{{\ell }_1}& -\frac{6}{{\ell }_1^2}& \frac{2}{{\ell }_1}& 0& 0\\ -\frac{12}{{\ell }_1^3}& -\frac{6}{{\ell }_1^2}& \frac{12}{{\ell }_2^3}+\frac{12}{{\ell }_1^3}& \frac{6}{{\ell }_2^2}-\frac{6}{{\ell }_1^2}& -\frac{12}{{\ell }_2^3}& \frac{6}{{\ell }_2^2}\\ \frac{6}{{\ell }_1^2}& \frac{2}{{\ell }_1}& \frac{6}{{\ell }_2^2}-\frac{6}{{\ell }_1^2}& \frac{4}{{\ell }_2}+\frac{4}{{\ell }_1}& -\frac{6}{{\ell }_2^2}& \frac{2}{{\ell }_2}\\ 0& 0& -\frac{12}{{\ell }_2^3}& -\frac{6}{{\ell }_2^2}& \frac{12}{{\ell }_2^3}& -\frac{6}{{\ell }_2^2}\\ 0& 0& \frac{6}{{\ell }_2^2}& \frac{2}{{\ell }_2}& -\frac{6}{{\ell }_2^2}& \frac{4}{{\ell }_2}\end{array}\right)$

Weil die Auslenkung des Kraft-Angriffspunktes

$\delta w_F=\delta W_1$

ist

$\underset{\_}{P}=\left(\begin{array}{c}0\\ 0\\ F\\ 0\\ 0\\ 0\end{array}\right)$.

Hier fehlen noch die ...

/* coordinates */
Q: [ W[0],Phi[0], W[1],Phi[1], W[2], Phi[2]];

/* initiate matrices */
K[0] : zeromatrix(6,6);
P    : zeromatrix(6,1);

/* virtual work of F */
P[3][1] : F;

/* compose system matrix */
for E:1 thru 2 do
  (for j:1 thru 4 do
     (for k:1 thru 4 do
         (row : 2*(E-1)+j,
          col : 2*(E-1)+k,
          K[0][row][col] : K[0][row][col]+subst([i=E],K[e][j][k]))));

Boundary Conditions

Einarbeiten der Randbedingungen in die Systemmatrix

Im Gesamt-Gleichungssystem müssen wir noch die Randbedingungen einarbeiten, nämlich

$\begin{array}{ll}{W}_0=0& (\delta W_0=0)\\ W_2=0& (\delta W_2=0)\end{array}$

Das machen wir durch Streichen der zugehörigen Zeilen und Spalten (1 und 5) im Gleichungssystem.

/* eliminate rows and columns of constrained coordinates */
K[0] : submatrix(1,5,K[0],1,5);
P    : submatrix(1,5,P);
Q    : [Q[2],Q[3],Q[4],Q[6]];

print(EI,expand(K[0]/EI),transpose(Q),"=",P)$

Solve

Die Lösung des verbleibenden Gleichungssystems mit

$\alpha =\frac{a}{{\ell }_0},{\ell }_0=a+b$

ist

$\begin{array}{ccl}{\mathrm{\Phi }}_0\cdot & \frac{EI}{{\ell }_0^2\cdot F}& =\frac{2\cdot \alpha -3\cdot {\alpha }^2+{\alpha }^3}{6}\\ W_1\cdot & \frac{EI}{{\ell }_0^3\cdot F}& =\frac{{\alpha }^2-2\cdot {\alpha }^3+{\alpha }^4}{3}\\ {\mathrm{\Phi }}_1\cdot & \frac{EI}{{\ell }_0^2\cdot F}& =\frac{\alpha -3\cdot {\alpha }^2+2\cdot {\alpha }^3}{3}\\ {\mathrm{\Phi }}_2\cdot & \frac{EI}{{\ell }_0^2\cdot F}& =\frac{{\alpha }^3-\alpha }{6}\end{array}$

Und die Ergebnisse können wir mit der analytischen Lösung vergleichen:

/* solve */
sol[1] : ratsimp(linsolve_by_lu(K[0],P));
sol[1] : ratsimp(subst([l[1]=alpha*l[0],l[2]=(1-alpha)*l[0]],sol[1][1]));

/* dim'less results */
scale : EI/(l[0]^3*F)*[l[0],1,l[0],l[0]];
sol[2] : ratsimp(scale*sol[1]);

/* print results */
print(transpose(scale*Q),"=",sol[2])$

Post-Process: Results

Die Auslenkung des Kraft-Angriffspunktes w(a) tragen wir hier auf:

Absenkung w(a) des Kraftangriffspunktes

Der Vergleich der tabellierten Lösungen mit unseren Lösungen:

Ort	analytische Lösung	FEM-Lösung	Vergleich
A	$EI\cdot w{\text{'}}_A=\frac{F{\ell }^2}{6}(\beta -{\beta }^3)$	$EI{\mathrm{\Phi }}_0=F{\ell }_0^2\cdot \frac{2\cdot \alpha -3\cdot {\alpha }^2+{\alpha }^3}{6}$	Erfüllt, weil w'A = Φ0 und $\beta -{\beta }^3={\alpha }^3-3\cdot {\alpha }^2+2\cdot \alpha$
B	$EI\cdot w{\text{'}}_B=-\frac{F{\ell }^2}{6}(\alpha -{\alpha }^3)$	$EI{\mathrm{\Phi }}_2=F{\ell }^2\cdot \frac{{\alpha }^3-\alpha }{6}$	Erfüllt, weil w'B = Φ2
Kraftangriffspunkt	$EI{w}_{\text{max}}=\frac{F{\ell }^3}{48}\text{ für }\alpha =\beta =1/2$	$EI{W}_1=F{\ell }^3\cdot \frac{{\alpha }^2-2\cdot {\alpha }^3+{\alpha }^4}{3}$	Erfüllt, weil wmax = W1 für α = 1/2

⚠ Ist das jetzt die analytische Lösung?:

Sind die FEM-Ergebnisse nicht exakt die der analytischen Lösung? Stimmt das? Und wenn ja:  wie kommt das?

/* displacement of beam at force F */
plot2d(sol[2][2],[alpha,0,1],[xlabel, "α→"],[ylabel, "W1/(F l^3/EI)→"]);

---

Links

• W8Zt, W8Zu

Literature

• ...