Gelöste Aufgaben/PvV2

Aufgabenstellung

Hier setzen wir unsere Untersuchung aus PvV1 fort: nun bauen wir eine elastische "Leiter" ein, die durch die Kraft F gestaucht wird. Die Problemstellung lautet:

Ein elastischer Stab (Dehnsteifigkeit EA, Länge ℓ₀) ist bei A eingekeilt und steht bei B auf einer reibungsfreien Rolle.

Lageplan

Gesucht ist die Kraft F auf das Stabende als Funktion der horizontalen Verschiebung von Punkt B mit dem Prinzip der virtuellen Verrückungen.

In der gezeichneten Ausgangslage ist der Stab spannungsfrei.

Lösung mit Maxima

Lageplan

Koordinaten

Hier ist die Leiter mit der Koordinate u₁ von Punkt B gezeichnet. Bei der Variation um δu wandert der Angriffspunktspunkt B der Kraft F also in horizontaler Richtung.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 15.08.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2017-10-08                            */
/* ref: TM-C, PvV mit elastischen Körpern              */
/* description: finds the displacement u employing PvV */
/*******************************************************/
 
/* declare variational variables - see 6.3 Identifiers */
declare("δW", alphabetic);
declare("δΠ", alphabetic);
declare("Δl", alphabetic);
declare("δl", alphabetic);
declare("δu", alphabetic);
declare("δη", alphabetic);

assume(EA > 0, l[0]>0, h[0]>0, u[0]>0);
/* parameter */
params: [h[0]=2*u[0]];

Kinematik

Über den Satz des Pythagoras bekommen wir einen Zusammenhang zwischen der Verschiebung u₁ und der Stablängung Δℓ:

${{\left({{\ell }_{0}}+{\mathit {\Delta \ell }}\right)}^{2}}={{u}_{1}^{2}}+{{h}_{0}^{2}}{\text{ also }}{\mathit {\Delta \ell }}(u_{1})={\sqrt {{{u}_{1}^{2}}+{{h}_{0}^{2}}}}-{{\ell }_{0}}$

Für die Variation δℓ von Δℓ führen wir die Hilfsgröße ε als Koeffizient von δu ein. Da die virtuelle Verrückung "differentiell klein" sein darf, nehmen wir nur das lineare Glied bzgl. δu und bekommen mit

$\delta \,\ell =\displaystyle {\frac {d\,\Delta \ell (u_{1}+\epsilon \cdot \delta u)}{d\,\epsilon }}|_{\epsilon =0}$

den Ausdruck

${\mathit {\delta \ell }}=\displaystyle {\frac {{{u}_{1}}\cdot {\mathit {\delta u}}}{\sqrt {{{u}_{1}^{2}}+{{h}_{0}^{2}}}}}$.

Der Zusammenhang ist nichtlinear! Das ist anschaulich klar - liefert hier jedoch komplizierte Formeln ....

/* Kinematik: */
kinematics: (l[0]+Δl)^2 = h[0]^2+u[1]^2;
ref: solve(l[0]^2 = h[0]^2+u[0]^2,l[0])[2];
/* displacemant and variation */
disp: solve(kinematics,Δl)[2];
disp: [disp, δl=subst(0,epsilon,
        diff(subst([u[1] = u[1]+epsilon*δu],subst(disp,Δl)),
                                                    epsilon))];

Gleichgewicht

In das Gleichgewicht gehen alle Arbeiten am System ein.

Im Unterschied zu einem Kräftegleichgewicht fallen hier alle Lager-Reaktionskräfte herus: in A und B verschwindet nämlich das Skalarprodukt des virtuellen Verschiebungsvektors mit den Normalkräften auf die Wände - sie stehen senkrecht aufeinander. Im Vergleich zu PvV1 müssen wir allerdings die virtuelle Formänderungsenergie δΠ berücksichtigen:

${\begin{array}{rl}\delta W&=\delta W^{a}-\delta \Pi \\&=-F\cdot \delta u-\displaystyle {\frac {EA}{\ell _{0}}}\cdot \Delta \ell \cdot \delta \ell \\&{\stackrel {!}{=}}0\end{array}}$

/* equilibrium condition */
PvV: [δW=δW^a-δΠ,
      δW^a = -F*δu,
      δΠ = EA/l[0]*Δl*δl];

Gleichungen und Unbekannte

Mit der Gleichung oben haben wir genau eine Gleichung für F - das passt!.

Allerdings haben wir zwei Koordinaten Δℓ und u₁ sowie deren Variationen. Die Forderung an die virtuellen Verrückungen ist jedoch, dass sie mit "der geometrischen Konfiguration des Systems verträglich" ist. Der Stab bleibt gerade - wir haben also nur eine unabhängige Koordinate im System. Wir können und müssen also entweder

• u₁ durch Δℓ oder
• Δℓ durch u₁

ausdrücken. Wir wählen u₁ als Minimal-Koordinate.

Lösen

Einsetzten von Δℓ und seiner Variationen

${\begin{array}{l}{\mathit {\Delta \ell }}={\sqrt {{{u}_{1}^{2}}+{{h}_{0}^{2}}}}-{{\ell }_{0}}\\{\mathit {\delta \ell }}=\displaystyle {\frac {{{u}_{1}}\cdot {\mathit {\delta u}}}{\sqrt {{{u}_{1}^{2}}+{{h}_{0}^{2}}}}}\end{array}}$

liefert

${\mathit {\delta W}}=-F\cdot {\mathit {\delta u}}-\displaystyle {\frac {{{u}_{1}}\cdot \left({\sqrt {{{u}_{1}^{2}}+{{h}_{0}^{2}}}}-{\sqrt {{{u}_{0}^{2}}+{{h}_{0}^{2}}}}\right)\cdot {\mathit {EA}}\cdot {\mathit {\delta u}}}{{\sqrt {{{u}_{0}^{2}}+{{h}_{0}^{2}}}}\cdot {\sqrt {{{u}_{1}^{2}}+{{h}_{0}^{2}}}}}}$

Charakteristisch ist dabei, dass sich die Variation - hier der Stab-Längung Δℓ - herauskürzt: sie dient nur zur Identifikation einer Gleichgewichtsbeziehung. Das wird wichtig, wenn wir mehrere Unbekannten und Koordinaten haben - dann ist der Koeffizient vor jeder Variation einer Koordinate eine Gleichgewichtsbeziehung. Jetzt macht die Aussage Sinn, dass sie "gedachte, voneinander unabhängige Verschiebungen" sind!

Mit der Abkürzung $u_{1}=\nu \cdot u_{0}$ ist die Gleichgewichtsbeziehung:

$F=-\displaystyle {\frac {\left(\nu \cdot {\sqrt {{{\nu }^{2}}+4}}-{\sqrt {5}}\cdot \nu \right)\cdot {\mathit {EA}}}{{\sqrt {5}}\cdot {\sqrt {{{\nu }^{2}}+4}}}}$

/* solve */
equ : subst(ref,subst(subst(disp,[PvV[2],PvV[3]]),PvV[1]));
equ : subst([u[1]= nu*u[0], u[0]=1],subst(params,equ));
equ: expand(subst(equ,δW))=0;

sol[1]: solve(equ,F)[1];

Ausdeuten der nichtlinearen Lösung

Stabkraft F

Beim Auftragen von F über u₁ sehen wir:

Um den Abstand zur Wand zu verringern (u₁ kleiner zu machen) steigt die Kraft F zunächst, sinkt dann aber wieder auf Null. Das macht anschaulich Sinn - denn wenn der Stab im Extremfall senkrecht steht, brauchen wir (fast) keine Kraft aufzuwenden, um ihn weiter nach "links" zu verschieben. Im Gegenteil: bei einem Experiment würde der Stab durch seine Längskraft aus der vertikalen Lage herausgedrückt.

/* postprocess */
plot2d(subst(sol[1],F/EA),[nu,0,1],
             [legend,false],
             [xlabel, "u1/u0 ->"], [ylabel, "F/EA->"]);

Linearisieren der Lösung

Vergleich von linearer und nichtlinearer Lösung

Ein wenig einfacher wird es, wenn wir kleine Auslenkungen u₂ um die entspannte Lage des Stabes herum betrachten also

$u_{1}=u_{0}+u_{2}$

Dann dürfen wir die kinematischen Beziehungen linearisieren, also

${\begin{array}{l}{\mathit {\Delta \ell }}=\displaystyle {\frac {{u}_{2}}{\sqrt {5}}},\\{\mathit {\delta \ell }}=\displaystyle {\frac {\mathit {\delta u}}{\sqrt {5}}}\end{array}}$

und erhalten damit

$\displaystyle -F\cdot {\mathit {\delta u}}-{\frac {{{u}_{2}}\cdot {\mathit {EA}}\cdot {\mathit {\delta u}}}{{{5}^{\frac {3}{2}}}\cdot {{u}_{0}}}}=0$

Diesen Zusammenhang können wir als lineare Approximation in das Ergebnis oben eintragen:

/* postprocess: linearize solution */
lindisp: subst([u[1]=u[0]+u[2]],subst(ref,disp[1]));
lindisp: subst([u[2]=0],lindisp)+subst([u[2]=0],diff(lindisp,u[2]))*u[2];
lindisp: subst(params,lindisp);
lindisp: [lindisp, subst([Δl=δl, u[2]=δu],lindisp)];
equ : subst(params,subst(ref,subst(subst(lindisp,[PvV[2],PvV[3]]),PvV[1])));
equ: expand(subst(equ,δW))=0;
sol[2]: solve(equ,F)[1];

plot2d([[parametric, t, subst([nu=t],subst(sol[1],F/EA)),[t,0,1]],
        [parametric, 1+t, subst([u[2]=t*u[0]],subst(sol[2],F/EA)),[t,-1/4,0]]],
             [legend,"nonlinear", "linear approximation"],
             [xlabel, "u1/u0, (u2+u0)u0 →"], [ylabel, "F/EA →"]);

---

Links

• ...

Literature

• ...