Gelöste Aufgaben/FEB3

Aufgabenstellung

Hier geht es offensichtlich um Symmetrien, die wir mit einer skalaren Gleichgewichtsformulierung wie dem Prinzip der virtuellen Verrückungen sehr elegant ausnutzen können.

Die Euler-Bernoulli-Balken AB und CD (Länge 2ℓ, Biegesteifigkeit EI) sind in A und B bzw. C und D gelenkig gelagert. Jeweils mittig haben die beiden Balken einen Verbindungspunkt, in die eine Feder der Steifigkeit k eingehängt wird. Zum Einhängen muss bei entspannten Balken die Feder um die Länge d gelängt werden. Nach dem Loslassen stellt sich dann eine neue statische Gleichgewichtslage zwischen Balken und Feder ein.

Lageplan.

Gesucht sind die Auslenkungen der beiden Verbindungspunkte der Feder mit den Balken. Das Modell soll aus vier Finiten Elementen bestehen, jeweils zwei für die beiden Balken sowie einer Feder.

Lösung mit Maxima

Header

Hier müssen die Element-Steifigkeitsmatrizen für vier Sektionen von Euler-Bernoulli-Balken und einer Feder zusammengefügt (assembliert) werden. Die Schwierigkeit liegt darin, die Symmetrien des Systems auszunutzen.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 16.04.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2018-12-23                            */
/* ref: TM-C                                           */
/* description: FEM-solution for two beams, centrally  */
/*              connected by a spring                  */
/*******************************************************/
/* declare variational variables - see 6.3 Identifiers */
declare("δW", alphabetic);
declare("δA", alphabetic);
declare("δΠ", alphabetic);
declare("δw", alphabetic);
declare("δQ", alphabetic);

Declarations

Wir kopieren den Ausdruck für die virtuelle Formänderungsenergie aus der FEM-Formulierung für den Euler-Bernoulli-Balken für Element "i" zu

$\delta \Pi _{i}=\delta {\underline {Q}}^{T}\cdot {\underline {\underline {K}}}_{i}\cdot {\underline {Q}}$.

/***************************************************/
/* FEM-Formulierung+für+den+Euler-Bernoulli-Balken */
/*Trial-Fucntions*/
  
Ki(l):= (EI/l^3)*matrix([ 12, 6*l  ,-12  , 6*l  ],
                        [6*l, 4*l^2, -6*l, 2*l^2],
                        [-12,-6*l  , 12  ,-6*l  ],
                        [6*l, 2*l^2, -6*l, 4*l^2]);
/***************************************************/

Equilibrium Conditions

Der Schlüssel zur einfachen Lösung liegt in der Symmetrie der Verformung des Systems: alle vier Balken-Elemente verformen sich gleich. So verformt sich der Balken AB symmetrisch zum mittleren Verbindungspunkt "M", das gleiche gilt für Balken CD.

Für das Finite Element AM sind nun die Knotenvariablen

${\underline {Q}}_{AM}=\left({\begin{array}{l}W_{A}\\\Phi _{A}\\W_{M}\\\Phi _{M}\end{array}}\right)$,

wobei wegen der Rand- und Übergangsbedingungen

${\begin{array}{l}W_{A}=0{\text{ und }}\\\Phi _{M}=0\end{array}}$

gilt. Nach Einarbeiten dieser Bedingungen ist also die virtuelle Formänderungsenergie des Balken-Segments

$\displaystyle \delta \Pi _{AM}=\left(\delta \Phi _{A},\delta W_{M}\right)\cdot {\frac {EI}{\ell ^{3}}}\left({\begin{array}{cc}4\ell ^{2}&-6\ell \\-6\ell &12\end{array}}\right)\cdot \left({\begin{array}{l}\Phi _{A}\\W_{M}\end{array}}\right)$.

Analog ist die virtuelle Formänderungsenergie der Feder

$\delta \Pi _{k}=k\cdot (d-2\;W_{M})\cdot (-2\;\delta W_{M})$

weil unterer und oberer Verbindungspunkt gleich ausgelenkt werden - wenn auch mit unterschiedlichen Orientierungen.

Wir haben keine eingeprägten, äußeren Kräfte - also gilt im Gleichgewicht

$\delta \Pi =0$.

Nun ist

$\displaystyle \delta \Pi =\underbrace {\sum _{I=1}^{4}\delta \Pi _{i}} _{\displaystyle =4\;\delta \Pi _{AM}}+\delta \Pi _{k}$

und damit folgt die Gleichgewichtsbedingung zu

${\begin{pmatrix}\displaystyle {\frac {16\cdot {\mathit {EI}}}{l}}&\displaystyle -{\frac {24\cdot {\mathit {EI}}}{{l}^{2}}}\\\displaystyle -{\frac {24\cdot {\mathit {EI}}}{{l}^{2}}}&\displaystyle {\frac {48\cdot {\mathit {EI}}}{{l}^{3}}}+4\cdot k\end{pmatrix}}\cdot {\begin{pmatrix}{{\Phi }_{A}}\\{{W}_{M}}\end{pmatrix}}={\begin{pmatrix}0\\2\;d\;k\end{pmatrix}}$.

/***************************************************/
/* virtuelle Formänderungsenergie der Feder */

Q : matrix([Phi[A]],[W[M]]);

δΠ[k] : k*(d-2*W[M])*(-2*δW[M]);

/* Gesamt-Matrizen  */
K : 4* submatrix(1,4,Ki(l),1,4)
K[2,2] : K[2,2] + coeff(coeff(expand(δΠ[k]),δW[M]),W[M]);

P : matrix([0],[-subst(0,W[M],coeff(expand(δΠ[k]),δW[M]))])
print(K,"*",Q,"=",P);

Solving

Lösen des Gleichungssystems liefert

${\begin{array}{l}\displaystyle \Phi _{A}={\frac {3\;d\;k\;\ell ^{2}}{12\;EI+4\;k\;\ell ^{3}}}\\\displaystyle W_{M}={\frac {d\;k\;\ell ^{3}}{6\;EI+2\;k\;\ell ^{3}}}\end{array}}$,

und das ist zum Beispiel für k = EI / ℓ³

${\begin{array}{l}\displaystyle \Phi _{A}={\frac {3\;d}{16\;\ell }}\\\displaystyle W_{M}={\frac {d}{8}}\end{array}}$

/***************************************************/
/* solve */
sol : ratsimp(linsolve_by_lu(K,P));

subst([k=EI/l^3],sol);

Links

• ...

Literature

• ...