Gelöste Aufgaben/FEB2

Aufgabenstellung

Die zwei Euler-Bernoulli-Balken AB (Länge a) und BC (Länge 2a) sind in B fest verschweißt. Ihre Biegesteifigkeit ist EI. Die Konstruktion ist in A fest eingespannt und in C durch ein verschiebliches Gelenklager gelagert. In B ist sie durch die Kraft F und das Moment M belastet.

Lageplan

Gesucht ist die Verschiebungen und Verdrehungen der Balken mit der Methode der Finiten ELemente.

Gegeben: a, E I, F, M

Lösung mit Maxima

Berechnet werden sollten daf[r die Auslenkungen und Verdrehung der Punkte A, B und C. Das Modell soll aus zwei Finiten Elementen bestehen, jeweils eins für den Abschnitt AB und BC. Die neutralen Fasern der beiden Balken seien in Längsrichtung undehnbar – die Querschnitts-Schwerpunkte verschieben sich also nicht in Balken-Längsrichtung.

Header

Hier müssen die Element-Steifigkeitsmatrizen für zwei Sektionen von Euler-Bernoulli-Balken zusammengefügt (assembliert) werden. Die Schwierigkeit liegt darin, die Koordinaten in Punkt B passend zu wählen.

📑 toggle code

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 16.04.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2018-02-13                            */
/* ref: TM-C                                           */
/* description: FEM-solution for two rgidly connected  */
/*              sections                               */
/*******************************************************/

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 16.04.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2018-02-13                            */
/* ref: TM-C                                           */
/* description: FEM-solution for two rigidly connected */
/*              sections                               */
/*******************************************************/

Declarations

Die Element-Steifigkeitsmatrix kopieren wir aus Abschnitt FEM-Formulierung für den Euler-Bernoulli-Balken zu:

$K_i({\ell }_i)=\frac{EI}{{\ell }_i^3}\cdot \left(\begin{array}{cccc}12& 6\cdot {\ell }_i& -12& 6\cdot {\ell }_i\\ 6\cdot {\ell }_i& 4\cdot {{\ell }_i}^2& -6\cdot {\ell }_i& 2\cdot {{\ell }_i}^2\\ -12& -6\cdot {\ell }_i& 12& -6\cdot {\ell }_i\\ 6\cdot {\ell }_i& 2\cdot {{\ell }_i}^2& -6\cdot {\ell }_i& 4\cdot {{\ell }_i}^2\end{array}\right)$.

Die Element-Längen der zwei Finiten Elemente sind hier

$\begin{array}{l}{\ell }_1=a\\ {\ell }_2=2a\end{array}$.

📑 toggle code

/***************************************************/
/* FEM-Formulierung+für+den+Euler-Bernoulli-Balken */ 
/*Trial-Fucntions*/
phi : [       (xi-1)^2*(2*xi+1),
         l[i]* xi     *(  xi-1)^2,
        -      xi^2   *(2*xi-3),
         l[i]* xi^2   *(  xi-1)];
 
Ki(l):= (EI/l^3)*matrix([ 12, 6*l  ,-12  , 6*l  ],
                        [6*l, 4*l^2, -6*l, 2*l^2],
                        [-12,-6*l  , 12  ,-6*l  ],
                        [6*l, 2*l^2, -6*l, 4*l^2]);
/***************************************************/

Zunächst hat das System mit zwei Finiten Elementen jeweils 4 Koordinaten, nämlich

$W_{i-1},{\mathrm{\Phi }}_{i-1},W_i,{\mathrm{\Phi }}_i$.

Sektion A-B

Sektion B-C

Die Sektion ist in A fest eingespannt, also ist hier $W_{i-1}=0,{\mathrm{\Phi }}_{i-1}=0.$ Es bleiben die Verschiebung und Verdrehung in B, also $W_i=W_B,{\mathrm{\Phi }}_i={\mathrm{\Phi }}_B$.

Die neutralen Fasern der Balken-Sektionen - also auch von AB - sind undehnbar. Die Punkte B und C können sich also nur in vertikale Richtung jeweils um WB verschieben.  Durch diese Starrkörper-Verschiebung wird keine Arbeit geleistet - das tun nur die Lateral-Verschiebungen in w2(x2). Es ist also $W_{i-1}=0,W_i=0.$ Es bleiben also die Verdrehungen in B und C zu ${\mathrm{\Phi }}_{i-1}={\mathrm{\Phi }}_B,{\mathrm{\Phi }}_i={\mathrm{\Phi }}_C$

Übertragung der Koordinaten.

Die verbleibenden Koordinaten des Gesamtsystems sind

$\underset{\_}{Q}=\left(\begin{array}{l}{W}_B\\ {\mathrm{\Phi }}_B\\ {\mathrm{\Phi }}_C\end{array}\right)$

Das verformte System sieht dann so aus:

Verformte Lage.

📑 toggle code

/* coordinates */
Q : [W[B], Phi[B],Phi[C]];

K[1] : submatrix(1,2,Ki(  a),1,2);
K[2] : submatrix(1,3,Ki(2*a),1,3);

Assembly of System Matrices

Wir bauen das Gleichungssystem

$\underset{\_}{\underset{\_}{K}}\cdot \underset{\_}{Q}=\underset{\_}{P}$

zusammen, indem wir die Anteile der Element-Steifigkeitsmatrizen und die äußeren Lasten in die jeweiligen System Matrizen hineinaddieren.

Die virtuelle Formänderungsenergie ist

• für Sektion AB:
  $\delta {\mathrm{\Pi }}_{AB}=(\delta W_B,\delta {\mathrm{\Phi }}_B)\cdot \left(\begin{array}{cc}\frac{12\cdot {E}{I}}{a^3}& -\frac{6\cdot {E}{I}}{a^2}\\ -\frac{6\cdot {E}{I}}{a^2}& \frac{4\cdot {E}{I}}{a}\end{array}\right)\cdot \left(\begin{array}{l}{W}_B\\ {\mathrm{\Phi }}_B\end{array}\right)$ und
• für Section BC:
  $\delta {\mathrm{\Pi }}_{BC}=(\delta {\mathrm{\Phi }}_B,\delta {\mathrm{\Phi }}_C)\cdot \left(\begin{array}{cc}\frac{2\cdot {E}{I}}{a}& \frac{{E}{I}}{a}\\ \frac{{E}{I}}{a}& \frac{2\cdot {E}{I}}{a}\end{array}\right)\cdot \left(\begin{array}{l}{\mathrm{\Phi }}_B\\ {\mathrm{\Phi }}_C\end{array}\right)$.

Die Gesamt-Steifigkeitsmatrix aus Sektion AB (rot) und Sektion 2 (grün) ist damit

$\underset{\_}{\underset{\_}{K}}=\frac{EI}{a^3}\cdot \left(\begin{array}{ccc}+12& -6a& 0\\ -6a& 4a^2+2a^2& a^2\\ 0& a^2& 2a^2\end{array}\right)$,

Die Spaltenmatrix der eingeprägten, äußeren Lasten auf das System kommt aus

$\delta W^a=-F\cdot \delta W_B+M\cdot \delta {\mathrm{\Phi }}_B$

zu

$\underset{\_}{P}=\left(\begin{array}{r}-F\\ M\\ 0\end{array}\right)$.

📑 toggle code

/* system stiffness matrix K and system load matrix P */
K[0] : zeromatrix(3,3);

/* assembel */
for row:1 thru 2 do
   for col:1 thru 2 do
     (K[0][row  ,col  ] : K[0][row  ,col  ] + K[1][row,col],
      K[0][row+1,col+1] : K[0][row+1,col+1] + K[2][row,col]);

P : matrix([-F],[M],[0]);

Solving

Die Lösung des linearen Gleichungssystems liefert

$\left(\begin{array}{c}{W}_B\\ {\mathrm{\Phi }}_B\\ {\mathrm{\Phi }}_C\end{array}\right)=\left(\begin{array}{c}\frac{12\cdot a^2\cdot M-11\cdot a^3\cdot F}{60\cdot {E}{I}}\\ \frac{2\cdot a\cdot M-a^2\cdot F}{5\cdot {E}{I}}\\ -\frac{2\cdot a\cdot M-a^2\cdot F}{10\cdot {E}{I}}\end{array}\right)$

📑 toggle code

/* solve by LU-factorisation */
sol: ratsimp(linsolve_by_lu(K[0],P)[1]);
print(transpose(Q)=sol);

Post/Processing

Solange

$M>\frac{11\cdot a\cdot F}{12}$

sieht das System im ausgelenkten Zustand so aus:

Lage des verformten Systems.

📑 toggle code

NONE

Links

• ...

Literature

• ...