Gelöste Aufgaben/FEAE

Aufgabenstellung

Wir schauen uns die Lösungsanteile für die Bewegungsgleichung des Zwei-Masse-Schwinger an: welche Rolle spielen die homogene und partikulare Lösung?

Lageplan

Gesucht ist Gesamtlösung des Systems im Zeitbereich beim Loslassen der beiden Massen aus der Referenz-Konfiguration, bei der beide Federn entspannt sind. Wir stellen die Bewegungsgleichung mit dem Prinzip der virtuellen Verrückungen auf.

Wir arbeiten mit den System-Parametern

${\begin{array}{ccc}k_{1}&=&{\frac {3}{2}}k_{0}\\k_{2}&=&k_{0}\\m_{1}&=&m_{0}\\m_{2}&=&m_{0}\\\end{array}}$

Lösung mit Maxima

Header

Der Lösungsweg zu dieser Aufgabe wird bereits in Integration der Differentialbeziehung (IVP) gezeigt, hier verfolgende wir einen etwas allgemeineren Lösungspfad.

Dabei arbeiten wir u.a. mit quadratischen Gleichungen. Für deren Lösung müssen wir Maxima wissen lassen, welche Parameter positiv sind, also

$k_{0}>0,\;\;\;m_{0}>0,\;\;\;T>0;$

Koordinaten der Bewegung.

Die Lage-Koordinaten des Systems fassen wir in

${\underline {Q}}=\left({\begin{array}{l}w_{1}(t)\\w_{2}(t)\end{array}}\right)$

zusammen.

Für die dimensionslose Schreibweise brauchen wir später eine Bezugszeit t_Bez.

Dazu nehmen wir eine "Anleihe" bei einem ähnlichen System:

Für dieses System "kennen" wir die Eigenkreisfrequenz

$\displaystyle \omega _{0}={\sqrt {\displaystyle {\frac {k_{0}}{m_{0}}}}}{\text{ und }}\omega _{0}={\frac {2\pi }{T}}$.

Aus diesem Modell "leihen" wir uns die Bezugszeit zu

$\displaystyle T=2\pi {\sqrt {\displaystyle {\frac {m_{0}}{k_{0}}}}}$.

und wählen

$t_{Bez}:=T$

Hier kennen wir ω₀.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 16.04.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2018-01-07                            */
/* ref: FEM, PVMPE using two coordinates               */
/* description: solve by principle virt. Work          */
/*******************************************************/
/* declare variational variables - see 6.3 Identifiers */
declare("δW", alphabetic);
declare("δA", alphabetic);
declare("δΠ", alphabetic);
declare("δw", alphabetic);
declare("δQ", alphabetic);

/* assumptions */
assume(k[0]>0,m[0]>0,T>0);

/* abbreviations */
abbrev : [omega[0,0]=2*%pi/T, omega[0,0]^2= k[0]/m[0]];
abbrev : append(abbrev, solve(abbrev,[omega[0,0],T])[2]);

/* system parameters and dimensionless time tau */
params: [m[1]=m[0],m[2]=m[0],k[1]=3/2*k[0],k[2]=k[0],
         t = T*tau, w[s] = m[0]*g/k[0]];

/* coordinates */
 Q[t]: [ w[1](t), w[2](t)]; 
δQ[t]: [δw[1]   ,δw[2]   ];

Equilibrium Conditions

Die Gleichgewichtsbedingung mit dem Prinzip der virtuellen Verrückungen lautet

${\begin{array}{lcl}\delta W&=&\underbrace {-m_{1}\cdot {\ddot {w}}_{1}\cdot \delta {w}_{1}-m_{2}\cdot {\ddot {w}}_{2}\cdot \delta {w}_{2}+m_{1}\cdot g\cdot \delta w_{1}+m_{2}\cdot g\cdot \delta w_{2}} _{\displaystyle :=\delta W^{a}}\\&&-\underbrace {k_{1}\cdot {w}_{1}\cdot \delta {w}_{1}+k_{2}\cdot \left({w}_{2}-{w}_{1}\right)\cdot \left(\delta {w}_{2}-\delta {w}_{1}\right)} _{\displaystyle :=\delta \Pi }\\&{\stackrel {!}{=}}0\end{array}}$.

Aufgelöst nach den Koeffizienten der virtuellen Verrückungen folgt die gewöhnliche, lineare Differentialgleichung:

$\left({\begin{array}{cc}m_{0}&0\\0&m_{0}\end{array}}\right)\cdot \left({\begin{array}{c}{\ddot {w}}_{1}\\{\ddot {w}}_{2}\end{array}}\right)+\left({\begin{array}{cc}{\frac {5}{2}}k_{0}&-k_{0}\\-k_{0}&k_{0}\end{array}}\right)\cdot \left({\begin{array}{c}w_{1}\\w_{2}\end{array}}\right)=\left({\begin{array}{c}m_{0}\cdot g\\m_{0}\cdot g\end{array}}\right)$.

In dieser Beziehung stehen jetzt nur noch m₀ und k₀ - die Indizes "0" können wir also ab hier weglassen. In Matrix-Schreibweise lautet die Bewegungsgleichung jetzt:

${\underline {\underline {M}}}\cdot {\underline {\ddot {Q}}}+{\underline {\underline {K}}}\cdot {\underline {Q}}={\underline {G}}$.

/* virtual of system (equilibrium condition) */
PvV : [δW = δW^a - δΠ,
       δW^a = - sum(m[i]* diff(w[i](t),t,2)*δw[i],i,1,2) + sum(m[i]*g*δw[i],i,1,2),
       δΠ   =   sum(k[i]*(w[i](t)-w[i-1](t))*(δw[i]-δw[i-1]),i,1,2)];

/* equlilbrium condition */

eom: subst(PvV[3],subst(PvV[2],subst(PvV[1],δW=0)));
eom: expand(subst([w[0](t)=0,δw[0]=0],eom));

M : -funmake('matrix,makelist(makelist(coeff(coeff(lhs(eom),δQ[t][i]),diff(Q[t][j],t,2)),i,1,2),j,1,2));
K : -funmake('matrix,makelist(makelist(coeff(coeff(lhs(eom),δQ[t][i]),     Q[t][j]     ),i,1,2),j,1,2));
G :  funmake('matrix,makelist(coeff(
            subst(makelist(diff(Q[t][i],t,2)=0,i,1,2), 
            subst(makelist(     Q[t][i]=0     ,i,1,2),[lhs(eom)])),δQ[t][j]), j,1,2));

/* control print-out */
print(M,"∙",transpose(diff(Q[t],t,2)),"+",K,"∙",transpose(Q[t]),"=",G)$

Solving

Die Lösung des Anfangswertproblems setzt sich aus zwei Teilen zusammen:

• der partikularen Lösung, die die Rechte Seite "G" erfüllt und
• der homogenen Lösung, die die Rechte Seite "0" erfüllt.

Die Gesamtlösung Q_t setzt sich nun - bei diesem linearen System - additiv aus partikularer Q_p und Q_h homogener Lösung zusammen:

${\underline {Q}}_{t}(t)={\underline {Q}}_{p}(t)+{\underline {Q}}_{h}(t)$

/**************** total solution */
Q[t] : Q[p] + Q[h]

Right-Hand-Side Approach

Die rechte Seite der Bewegungsgleichung G ist nicht zeitabhängig - sie ist statisch. Also ist auch die Lösung Q_p - die partikulare Lösung - statisch, wir suchen nach der Lösung des Gleichungssystems

${\underline {\underline {K}}}\cdot {\underline {Q}}_{p}={\underline {G}}$

und die ist

${\underline {Q}}_{p}={\begin{pmatrix}\displaystyle {\frac {4\;{m}\;g}{3\;{k}}}\\\displaystyle {\frac {7\;{m}\;g}{3\;{k}}}\end{pmatrix}}$

Wir führen die Abkürzung

$\displaystyle w_{s}={\frac {{m}g}{k}}$

ein, also ist

${\underline {Q}}_{p}=w_{s}\cdot {\begin{pmatrix}\displaystyle {\frac {4}{3}}\\\displaystyle {\frac {7}{3}}\end{pmatrix}}$.

/**************** particular solution */
Q[p] : ratsimp(subst(params,linsolve_by_lu(K,G)[1]));

Homogeneous Solution

Für die Lösung der homogenen Bewegungsgleichung

${\underline {\underline {M}}}\cdot {\underline {\ddot {Q}}}+{\underline {\underline {K}}}\cdot {\underline {Q}}={\underline {0}}$

setzen wir (vgl. Modalanalyse) an

$\displaystyle {\underline {Q}}_{h}={\underline {\hat {Q}}}_{h}\cdot e^{\lambda \cdot t}$

und erhalten das Eigenwertproblem

$\underbrace {\left(\lambda ^{2}{\underline {\underline {M}}}+{\underline {\underline {K}}}\right)} _{\displaystyle {\underline {\underline {D}}}(\lambda )}\cdot {\underline {\hat {Q}}}_{h}={\underline {0}}$

mit

den Eigenwerten	$\lambda$ und
den Eigenvektoren	$\displaystyle {\underline {\hat {Q}}}_{h}$

Die Berechnung der Eigenwerte λ wird einfacher mit

$\lambda ^{2}=-\Lambda$

und wir transformieren parallel die Bewegungsgleichungen auf die dimensionslose Zeit

$\displaystyle \tau :={\frac {t}{t_{Bez}}}$ mit $t_{Bez}=T.$,

also

$\displaystyle {\underline {\ddot {Q}}}={\frac {d^{2}{\underline {Q}}}{d\tau ^{2}}}\cdot \underbrace {\frac {d^{2}\tau }{dt^{2}}} _{\displaystyle {\frac {1}{T^{2}}}}$.

Wir finden zwei Eigenwerte aus der Bedingung det(D)=0:

${\begin{array}{lr}\Lambda _{1}=&2\cdot \pi ^{2}\\\Lambda _{2}=&12\cdot \pi ^{2}\\\end{array}}$

und

${\begin{array}{lr}\lambda _{1}=&j\cdot {\sqrt {2}}\cdot \pi \\\lambda _{2}=&j\cdot 2{\sqrt {(}}3)\cdot \pi \\\end{array}}{\text{ mit }}j:={\sqrt {-1}}$.

Für die Matrix

$\displaystyle {\underline {\underline {D}}}(\lambda _{i})=\lambda ^{2}\cdot {\frac {1}{T^{2}}}\cdot {\underline {\underline {M}}}+{\underline {\underline {K}}}$

stellen wir fest:

Die Matrix hat

• einen Rang (rank) von 1 - es gibt eine linear abhängige Zeile im Gleichungssystem und - entsprechend -
• einen Rangabfall (nullity)  von 1.

Die Eigenvektoren spannen nun den Nullraum (nullspace) der Matrix auf. Normmert auf die Länge 1 sind das

• für λ₁:
  $\displaystyle {\underline {\hat {Q}}}_{h,1}={\frac {1}{\sqrt {5}}}\cdot \left({\begin{array}{c}1\\2\end{array}}\right)$ und
• für λ₂:
  $\displaystyle {\underline {\hat {Q}}}_{h,2}={\frac {1}{\sqrt {5}}}\cdot \left({\begin{array}{c}2\\-1\end{array}}\right)$.

Die homogene Lösung der Bewegungsgleichung lautet damit

$\displaystyle {\underline {Q}}_{h}(t)=c_{1}\cdot {\frac {1}{\sqrt {5}}}\cdot \left({\begin{array}{r}1\\2\end{array}}\right)\cdot e^{\displaystyle j\cdot {\sqrt {2}}\pi \cdot \tau }+c_{2}\cdot {\frac {1}{\sqrt {5}}}\cdot \left({\begin{array}{r}2\\-1\end{array}}\right)\cdot e^{\displaystyle j\cdot 2{\sqrt {3}}\pi \cdot \tau }$

mit den Integrationskonstanten c₁ und c₂. Durch die komplexen Eigenwerte sind die beiden Integrationskonstanten nun auch komplexwertig, also

${\begin{array}{l}c_{1}=c_{R,1}+j\cdot c_{I,1}\\c_{2}=c_{R,2}+j\cdot c_{I,2}\end{array}}$.

Diese vier reell-wertigen Integrationskonstanten bekommen wir aus vier Anfangsbedingungen für die beiden Massen, hier

${\begin{array}{l}w_{1}(0)=0\\w_{2}(0)=0\\{\dot {w}}_{1}(0)=0\\{\dot {w}}_{2}(0)=0\end{array}}$.

Wir finden

$\displaystyle {{c}_{R,1}}=-{\frac {6\;{m}\;g}{{\sqrt {5}}\;{k}}},{{c}_{I,1}}=0,{{c}_{R,2}}=-{\frac {{m}\;g}{3\;{\sqrt {5}}\;{k}}},{{c}_{I,2}}=0$.

und damit

${\underline {Q}}_{h}(t)=15\cdot {\begin{pmatrix}-2\cos {\left(2{\sqrt {3}}{\pi }\cdot \tau \right)}-18\cos {\left({\sqrt {2}}{\pi }\cdot \tau \right)}\\\cos {\left(2{\sqrt {3}}{\pi }\cdot \tau \right)}-36\cos {\left({\sqrt {2}}{\pi }\cdot \tau \right)}\end{pmatrix}}$.

/* direct approach */
load(eigen); eigensystem: uniteigenvectors(subst(params, invert(M).K));
/* -> not employed */

/**************** homogeneous solution */
/* solve eigenvalue problem */
Q[E] : matrix([q[1,i]],[q[2,i]]);
ansatz: Q[h] = Q[E]*%e^(%lambda[i]*tau);

D : -Lambda*(1/T)^2*M + K;
D : subst(params, D);
charPoly : determinant(D);

/* eigenvalues */
eigval : solve(subst(params,charPoly)=0,Lambda);
eigval : subst(abbrev, eigval);

/* save for later ....*/
eigvalList : makelist(subst(eigval[j],[%lambda[j]=%i*sqrt(Lambda)]),j,1,2);

/* eigenvectors */
prop: [rnk = rank(subst(eigval[1],subst(params,D))), nly = nullity(subst(eigval[1],D))];

eigvec : makelist(apply (addcol, args (nullspace(
                           subst(abbrev,subst(eigval[i],D/k[0]))))),i,1,2);

/* norm eigenvectors (to be of length "1" */
eigvec : makelist(eigvec[i]/sqrt(eigvec[i].eigvec[i]),i,1,2);

/* adapt to initial values w[1](0)=0, w[2](0)=0 */
Q[h] : sum(subst(eigval[j],subst([%lambda[j]=%i*sqrt(Lambda),i=j],
                           (c[R,j]+%i*c[I,j])*eigvec[j]*%e^(%lambda[j]*tau))),j,1,2);

/* update Q[t]*/
Q[t] : ''(Q[t]);

/* adapt to initial values */
intcons : [c[R,1],c[I,1],c[R,2],c[I,2]];
intcond : append(makelist(subst([tau=0],     Q[t]     )[i][1]=0,i,1,2),
                 makelist(subst([tau=0],diff(Q[t],tau))[i][1]=0,i,1,2));

/* integration constants: */
sol[1] : ratsimp(solve(realpart(intcond),intcons)[1]);

Q[t] : realpart(ratsimp(subst(params,subst(sol[1],Q[t]/w[s]))))

Post-Processing

Die Lösung für

• w₁ (blau) und
• w₂ (rot)

im Zeitbereich, angepasst an die Anfangsbedingungen, sieht nun so aus:

Ergebnis-Plots für w₁(t), w₂(t).

Interessant ist die separate Auftragung der Lösungsanteile nach partikularer Lösung (Index "p") und den beiden homogenen Lösungsanteilen (Index "h1", "h2"). Man erkennt, wie die Summe jeweils der blauen und der roten Anteile die Gesamtlösung ergibt.

Ergebnis-Plot mit den Lösungsanteilen.

/* plot results */
preamble: "set yrange [] reverse";
plot2d([Q[t][1][1],Q[t][2][1]],[tau,0,4], [legend, "w[1]", "w[2]"],
    [xlabel, "τ/1 →"], [ylabel, "← w/(m*g/k)"],
    [gnuplot_preamble, preamble]);

/* deconstruct solution into modes */
timeFcts : makelist(subst(eigvalList[i],%e^(%lambda[i]*tau)),i,1,2)
Q[l] : subst(params,append([Q[p]/w[s]],
            realpart(makelist(coeff(subst(sol[1],Q[h]),timeFcts[i])/w[s]*timeFcts[i],i,1,2))));

plot2d([Q[l][1][1][1],Q[l][1][2][1],
        Q[l][2][1][1],Q[l][2][2][1],
        Q[l][3][1][1],Q[l][3][2][1]],
        [tau,0,4],
        [legend, "w[p,1]", "w[p,2]", "w[h1,1]", "w[h1,2]", "w[h2,1]", "w[h2,2]"],
        [color, blue, red, blue, red, blue, red],
        [style, [lines,3], [lines,3], [lines,1], [lines,1], [lines,1], [lines,1]],
        [xlabel, "τ/1 →"], [ylabel, "← w/(m*g/k)"],
        [gnuplot_preamble, preamble]);

Links

• ...

Literature

• ...