Gelöste Aufgaben/Kig1

Aufgabenstellung

Das skizzierte System ist ein elektrischer Schalter, der in C einen Stromkreis schließen soll. Es besteht aus einem durchgehenden elastischen Stab ABC (Euler-Bernoulli-Balken: Masse m, Biegesteifigkeit EI, Länge ℓ), der in A gelenkig gelagert ist, in B mit einer Führung aus drei starren, masselosen Stäben gelenkig verbunden ist und dem Kontakt in C. Die Führung ist durch eine Feder (Steifigkeit k) mit der Umgebung verbunden.

Lageplan

Damit der Schalter zuverlässig funktioniert soll die Kraft F an der Führung so gewählt werden, dass die vorgegebene Kontaktkraft K eingestellt wird. Gesucht ist die analytische Lösung für ein Euler-Bernoulli-Modell der elastischen Struktur.

Wir lösen dazu das Gleichungssystem zur Bestimmung der Integrationskonstanten der Differentialgleichung des Euler-Bernoulli-Balkens und weiterer Unbekannten und geben die grafischen Lösungen für w, w', M und Q an.

Gegeben: K, ℓ, EI, m, g, k

Lösung mit Maxima

Koordinaten

Das System besteht aus den drei starren Stäben und dem elastischen Balken.

Die Verschiebungen und Verbiegungen der Stäbe verstehen wir am besten, wenn wir uns das System einmal im ausgelenkten Zustand ansehen. Gleichgewichtsbedingungen für die Führung erhalten wir aus einfachen Kräfte- und Momentenbilanzen, die Gleichgewichtsbedingungen für den Euler-Bernoulli-Balken ist die Feld-Differentialgleichung, deren Integrationskonstanten wir an die Rand- und Übergangsbedingungen anpassen.

Aus dem Bild sehen wir

${\begin{array}{ccl}w_{1}(a)=w_{B}\\w_{2}(\ell -a)=w_{C}=d\\\end{array}}$,

und wir arbeiten im folgenden mit

${\begin{array}{ccl}\alpha &=&a/\ell \\\beta &=&1-\alpha \end{array}}$.

Wir beginnen, indem wir Führung und Balken von einander freischneiden:

Damit legen wir die Schnittkräfte

• B_z und
• K

frei. K ist dabei gegeben, F und B_z sind unbekannt.

Wir müssen überlegen, wo wir Bedingungen für diese beiden Größen herbekommen.

Die Lösung der Teilaufgabe für den Euler-Bernoulli-Balken ist ein klassisches Randwertproblem mit

1. zwei Gebieten, in denen ein Euler-Bernoulli-Balken in AB (Bereich I) und BC (Bereich II) durch eine Streckenlast q₀ belastet ist sowie
2. Rand- und Übergangsbedingungen in den Punkten A, B, C.

Die Biegesteifigkeit des Balkens ist konstant (also nicht von "x" abhängig), die Lösungen in beiden Bereichen ist also bis auf die Integrationskonstanten gleich.

Wir verwenden ein x_i bzw. ξ_i als Ortskoordinaten je Bereich.

Zusätzlich zum "klassischen" Randwertproblem haben wir hier Zwangsbedingung durch die starren Stäbe und die Kontaktkraft.

Header

In dieser Lösung arbeiten wir mit dimensionslosen Koordinaten für die unabhängige Koordinate x und die abhängige Koordinate w(x).

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 18.10.1                           */
/* author: Andreas Baumgart                            */
/* last updated: 2019-12-07                            */
/* ref: TMC, Labor 1                                   */
/* description: analytical solution for beam with      */
/*              with parallel rod guidance             */
/*******************************************************/

Declarations

Die Streckenlast auf den Balken ist seine Gewichtskraft, also

$\displaystyle q_{0}={\frac {m\;g}{\ell }}$.

Später werden wir noch die dimensionslose Koordinate

$\xi _{i}=\displaystyle {\frac {x_{i}}{\ell }}$

gebrauchen.

declare("ℓ", alphabetic);
 
/* system parameters                                  */
params: [k[B]     = gamma*EI/ℓ^3,
         q[0]     = m*g/ℓ,
         K        = kappa*Q[ref],
         d        = delta*W[ref],
         gamma    = 5,
         kappa    = 3,
         delta    = 1];

geometry : [beta  = 1-alpha,
            alpha = 1/3];

/* reference deflection selected:                         */
/* beam with doublesided bearing under constant line load */
dimless : [M[ref]=Q[ref]*ℓ, Q[ref]= 3*EI/ℓ^3*W[ref],
           F = Q[ref]*f, B[z] = Q[ref]*b,
           W[ref] = 5*q[0]*ℓ^4/(EI*384)]; 

dimless: subst(params, dimless);
params : subst(dimless, params);

Integration Of Differential Equation

In Bereich I und II gilt dieselbe Bewegungs-Differentialgleichung

$E\,I\,w_{i}^{IV}(x)=q_{0},\;\;i=\{1,2\}$,

die wir durch Integration lösen und dann bereichsweise an Rand- und Übergangsbedingungen anpassen. Die Bedeutung der gesuchten Auslenkung w und seiner Ableitungen sind

${\begin{array}{ll}\ldots {\text{ die Auslenkung: }}&\displaystyle w_{i}(x)\\\ldots {\text{ die Verdrehung: }}&\displaystyle \phi _{i}(x)={\frac {d\,w_{i}(x)}{d\,x}}\\\ldots {\text{ das Biege-Moment: }}&\displaystyle M_{i}(x)=-EI{\frac {d^{2}\,w_{i}(x)}{d\,x^{2}}}\\\ldots {\text{ die Querkraft: }}&\displaystyle Q_{i}(x)=-EI{\frac {d^{3}\,w_{i}(x)}{d\,x^{3}}}\end{array}}$

Einfacher wird es, wenn wir mit der dimensionslosen Koordinate

$w_{i}(x_{i})=W_{ref}\cdot {\tilde {w}}_{i}(\xi )$.

arbeiten. Dann ist

${\begin{array}{cccl}E\,I&w_{i}^{IV}(x)&=&q_{0}\\E\,I&\displaystyle W_{ref}\;{\frac {\partial ^{4}}{\partial \xi ^{4}}}{\tilde {w}}_{i}(\xi )\cdot {\frac {1}{\ell ^{4}}}&=&\displaystyle {\frac {m\;g}{\ell }}\\{\text{ und damit }}&\displaystyle {\frac {\partial ^{4}}{\partial \xi ^{4}}}{\tilde {w}}_{i}(\xi )&=&\mu {\text{ mit }}\mu =\displaystyle {\frac {q_{0}\,\ell ^{4}}{EI}}\,{W_{ref}}\end{array}}$

Praktisch ist es nun, W_ref so zu wählen, dass wir die dimensionslose Koordinate für w einfach interpretieren können. Aus der Musterlösung für den beidseitig gelenkig gelagerten Euler-Bernoulli-Balken unter konstanter Streckenlast nehmen wir

$W_{ref}=\displaystyle {\frac {5\,q_{0}\;\ell ^{4}}{384\;EI}}$

und damit

$\mu =\displaystyle {\frac {384}{5}}$.

Ein Aufintegrieren der Differentialgleichung liefert dann

$w_{i}(x_{i})=\displaystyle W_{ref}\,\left({\frac {\mu \,\xi ^{4}}{24}}+{\frac {C_{i,3}\,\xi ^{3}}{6}}+{\frac {C_{i,2}\,\xi ^{2}}{2}}+C_{i,1}\,\xi +C_{i,0}\right)$

/******************************************************/
/* Boundary Value Problem Formulation                 */
/* part I: field                                      */
dgl : EI*W[ref]*diff(w(xi),xi,4)/ℓ^4 = q[0];
dgl: solve(subst(dimless,subst(params,dgl)),'diff(w(xi),xi,4))[1];

params : append(params, [mu = rhs(dgl)]);
dgl: lhs(dgl) = mu;

/* generic solution */
displ : solve(integrate(integrate(integrate(integrate(dgl,xi),xi),xi),xi),w(xi));
sections: [[i=1, %c4=C[1,0], %c3=C[1,1], %c2=C[1,2], %c1=C[1,3]],
           [i=2, %c4=C[2,0], %c3=C[2,1], %c2=C[2,2], %c1=C[2,3]]];
  
/* section I */
define(  w[1](xi),  ratsimp(subst(sections[1],W[ref]*subst(displ,w(xi)))));
define(Phi[1](xi),     diff(w[1](xi),xi  )/ℓ  );
define(  M[1](xi), -EI*diff(w[1](xi),xi,2)/ℓ^2);
define(  Q[1](xi), -EI*diff(w[1](xi),xi,3)/ℓ^3);
  
/* section II */
define(  w[2](xi),  ratsimp(subst(sections[2],subst(displ,W[ref]*w(xi)))));
define(Phi[2](xi),     diff(w[2](xi),xi  )/ℓ  );
define(  M[2](xi), -EI*diff(w[2](xi),xi,2)/ℓ^2);
define(  Q[2](xi), -EI*diff(w[2](xi),xi,3)/ℓ^3);

Boundary Conditions

Für die 2*4 = 8 Integrationskonstanten

$\left[C_{1,0},C_{1,1},C_{1,2},C_{1,3},C_{2,0},C_{2,1},C_{2,2},C_{2,3}\right]$

und die weiteren gesuchten Größen

$[F,B_{z}]$

suchen wir jetzt die passenden Gleichungen aus Rand- und Übergangsbedingungen des Systems.

Die Normalkräfte N brauchen wir dabei nicht auszuwerten.

Rand A.

Aus Rand A:

Geometrische Randbedingungen

1. $w_{1}(0)=0$
2. $M_{1}(0)=0$

Kraft- und Momenten-Randbedingungen

keine

Aus Übergang B:

Übergang B

Geometrische Randbedingungen

1. $w_{1}(a)=w_{2}(0)$
2. $\phi _{1}(a)=\phi _{2}(0)$

Kraft- und Momenten-Randbedingungen

1. $-M_{1}(a)+M_{2}(0)=0$
2. $-Q_{1}(a)+B_{z}+Q_{2}(0)=0$.

Aus Rand C:

Rand C

Geometrische Randbedingungen

1. $w_{2}(\ell -a)=d$

Kraft- und Momenten-Randbedingungen

1. $-M_{2}(\ell -a)=0$
2. $-Q_{2}(\ell -a)-K=0$

Gleichgewicht an der Führung

Führung

Für die starren Stäbe stellen wir die Summe aller Kräfte im senkrechten Stab auf:

$\displaystyle F-B_{z}-k\;w_{B}=0$.

Ein bisschen exotisch ist, dass wir nun zehn Unbekannte haben, nämlich

${\underline {X}}=\left({\begin{array}{c}C_{1,0}\\C_{1,1}\\C_{1,2}\\C_{1,3}\\C_{2,0}\\C_{2,1}\\C_{2,2}\\C_{2,3}\\F\\B_{z}\end{array}}\right)$

Aber mit den Randbedingungen oben steht uns ein vollständiges Gleichungssystem für diese zehn Unbekannten - die Integrationskonstanten und die Kräfte F, B_z - zur Verfügung.

Auch hier arbeiten wir mit dimensionslosen Größen, hier

${\begin{array}{lcl}F&=&Q_{ref}\;{\tilde {F}}\\B_{z}&=&Q_{ref}\;{\tilde {B}}_{z}\\\end{array}}$,

wobei wir

${\begin{array}{lcl}Q_{ref}&=&\displaystyle {\frac {3\;EI}{\ell ^{3}}}\cdot W_{ref}\\M_{ref}&=&Q_{ref}\;\ell \end{array}}$

setzen.

/******************************************************/
/* Boundary Value Problem Formulation                 */
/* part II: boundary conditions                       */
node[A]: [ w[1](0) = 0,
           M[1](0) = 0];
node[B]: [ w[1](alpha) = w[2](0),
           Phi[1](alpha) = Phi[2](0),       
          -Q[1](alpha) + Q[2](0) + B[z] = 0,
          -M[1](alpha) + M[2](0) = 0];
node[C]: [ w[2](beta) = d,
          -Q[2](beta) - K = 0,
          -M[2](beta) = 0];
node[D]: [F - k[B]*w[2](0)-B[z] = 0];

BCs : append(node[A],node[B],node[C],node[D]);
scale: [W[ref], -EI*W[ref]/(ℓ^2), 4*W[ref]/(24), 4*W[ref]/(24*ℓ),
        EI*W[ref]/(ℓ^3), EI*W[ref]/(ℓ^2), 4*W[ref]/24, EI*W[ref]/(ℓ^3),
        EI*W[ref]/(ℓ^2), 5*m*g/128];
BCs : makelist(expand(BCs[i]/scale[i]),i,1,length(BCs));
BCs : subst(dimless,subst(params,subst(dimless,subst(params,BCs))));

Prepare for Solver

Das Gleichungssystem wollen wir als

${\underline {\underline {A}}}\cdot {\underline {X}}={\underline {b}}$

schreiben. Um die Ergebnisse kompakt darstellen zu können, wählen wir als Parameter

${\begin{array}{lcl}k&=&\gamma \;{\frac {\displaystyle E\,I}{\displaystyle \ell ^{3}}},\\K&=&\kappa \,Q_{ref},\\d&=&\delta \;W_{ref}\end{array}}$

mit den dimensionslosen Größen

${\begin{array}{lcl}\gamma &=&5,\\\kappa &=&3,\\\delta &=&1\end{array}}$.

Damit erhalten wir - hier nach Einsetzen der gegeben System-Parameter:

${\begin{pmatrix}1&0&0&0&0&0&0&0&0&0\\0&0&1&0&0&0&0&0&0&0\\6&6\alpha &3{{\alpha }^{2}}&{{\alpha }^{3}}&-6&0&0&0&0&{\frac {96{{\alpha }^{4}}}{5}}\\0&6&6\alpha &3{{\alpha }^{2}}&0&-6&0&0&0&{\frac {384{{\alpha }^{3}}}{5}}\\0&0&0&1&0&0&0&-1&0&{\frac {384\alpha }{5}}\\0&0&1&\alpha &0&0&-1&0&0&{\frac {192{{\alpha }^{2}}}{5}}\\0&0&0&0&6&6\beta &3{{\beta }^{2}}&{{\beta }^{3}}&0&{\frac {96{{\beta }^{4}}}{5}}-6\\0&0&0&0&0&0&0&1&0&{\frac {384\beta }{5}}-9\\0&0&0&0&0&0&1&\beta &0&{\frac {192{{\beta }^{2}}}{5}}\\0&0&0&0&-{\frac {5}{3}}&0&0&0&1&0\end{pmatrix}}\cdot {\begin{pmatrix}{C_{1,0}}\\{C_{1,1}}\\{C_{1,2}}\\{C_{1,3}}\\{C_{2,0}}\\{C_{2,1}}\\{C_{2,2}}\\{C_{2,3}}\\{\tilde {F}}\\{{\tilde {B}}_{z}}\end{pmatrix}}={\begin{pmatrix}0\\0\\0\\0\\-3\\0\\0\\0\\0\\1\end{pmatrix}}$.

/* integration constants = unknowns */
ICs : [C[1,0],C[1,1],C[1,2],C[1,3],C[2,0],C[2,1],C[2,2],C[2,3],f,b];
ACM: augcoefmatrix(BCs,ICs)$
/* system matrix and rhs */
AA :   submatrix(ACM,10)$
bb : - col(ACM,10)$
/* print OLE */
print(subst(params,AA),"*",transpose(ICs),"=",subst(params,bb))$

Solving

Das Lösen des Gleichungssystems liefert dann

${\begin{array}{cl}{C_{1,0}}&=0,\\{C_{1,1}}&=-{\frac {49{{\alpha }^{2}}-147\alpha +56}{10}},\\{C_{1,2}}&=0,\\{C_{1,3}}&=-{\frac {339\alpha -147}{5\alpha }},\\{C_{2,0}}&={\frac {16{{\alpha }^{4}}-81{{\alpha }^{3}}+98{{\alpha }^{2}}-28\alpha }{5}},\\{C_{2,1}}&={\frac {64{{\alpha }^{3}}-194{{\alpha }^{2}}+147\alpha -28}{5}},\\{C_{2,2}}&={\frac {192{{\alpha }^{2}}-339\alpha +147}{5}},\\{C_{2,3}}&={\frac {384\alpha -339}{5}},\\{\tilde {F}}&={\frac {80{{\alpha }^{5}}-405{{\alpha }^{4}}+490{{\alpha }^{3}}-140{{\alpha }^{2}}-147}{15\alpha }},\\{\tilde {B}}_{z}&=-{\frac {49}{5\alpha }}\end{array}}$

und für

$\alpha ={\frac {1}{3}}$

die dimensionslosen Werte

$\left({\begin{array}{c}C_{1,0}\\C_{1,1}\\C_{1,2}\\C_{1,3}\\C_{2,0}\\C_{2,1}\\C_{2,2}\\C_{2,3}\\{\tilde {F}}\\{\tilde {B}}_{z}\end{array}}\right)=\left({\begin{array}{c}+0\\-{\frac {56}{45}}\\+0\\+{\frac {102}{5}}\\-{\frac {101}{405}}\\+{\frac {49}{135}}\\+{\frac {166}{15}}\\-{\frac {211}{5}}\\-{\frac {36226}{1215}}\\-{\frac {147}{5}}\\\end{array}}\right)$.

Ratio F/Q

Die Schaltkraft F ist negativ! Die Gewichtskraft des Balkens ist für die gewählte Konstellation zu groß, um die Kontaktkraft ohne F einzustellen. Wir schauen uns an, wie die erforderliche Kraft F über α verläuft:

/* ... solve .....*/
sol : ratsimp(solve(BCs, ICs))[1]$

/* check for required force */
part: expand(subst(geometry[1],subst(sol,f)));
plot2d(part, [alpha,0,1], [y,-50,0], [xlabel, "α ->"], [ylabel, "F/Q[ref] ->"])$

Post-Processing

Die Grafen der gesuchten Funktionen tragen wir nun direkt dimensionslos auf:

... für w(x):

w(x)

... für ϕ(x):

ϕ(x)

... für M(x):

M(x)

... für Q(x):

Q(x)

... für die Lager-Reaktionskräfte:

${\begin{array}{ll}{A_{z}}=&\displaystyle -{\frac {17\,m\,g}{64}}\end{array}}$

/******************************************************/
/* Post - Processing                                  */
/* part II: boundary conditions                       */

reactForces: [A[z] = Q[1](0)];
expand(subst(geometry,subst(params,subst(dimless,subst(params,subst(sol, subst(sol, reactForces)))))));
 
/* plot displacements */
 
fcts: [[ w [1](xi), w [2](xi)],
       [Phi[1](xi),Phi[2](xi)],
       [ M [1](xi), M [2](xi)],
       [ Q [1](xi), Q [2](xi)]];
facts: [1/W[ref], 1/(W[ref]/ℓ), 1/M[ref], 1/Q[ref]];
 
textlabels : ["w(x)/W[ref]→", "w'(x)/(W[ref]/ℓ)→", "M(x)/M[ref]→", "Q(x)/Q[ref]→"];
for i: 1 thru 4 do(
  f : expand(subst(geometry,subst(dimless,subst(params,facts[i]*[subst(sol, fcts[i][1]),
                                                                 subst(sol, fcts[i][2])])))),
  preamble: if i<=2 then "set yrange [] reverse" else "set yrange []",
  plot2d([[parametric,       t, subst(t,xi,f[1]), [t,0,subst(geometry,alpha)]],
          [parametric, subst(geometry,alpha)+t, subst(t,xi,f[2]), [t,0,subst(geometry,beta)]]],
                             [legend, "sec. I", "sec. II"],
                             [gnuplot_preamble, preamble],
                             [xlabel, "x/ℓ ->"],
                             [ylabel, textlabels[i]]))$

---

Links

• ...

Literature

• ...