Sources/Lexikon/Kontaktkennlinie

Beim Billard prallen zwei Körper aufeinander und trennen sich dann wieder. Der Löser der Bewegungsgleichungen braucht also eine Kraft, die "da" ist, wenn der Abstand der Kugelmittelpunkte kleiner als der Kugeldurchmesser ist - und Null sonst.

Für die Bewegungsgleichung eines solchen Systems müssen wir die Kraft erfassen, die im Kontakt zwischen zwei Körpern wirkt. Ein Finite Elemente Modell könnte diese Kraft als Resultierende der Kontakt-Drücke für verschiedene Eindringtiefen ermitteln.

Das ist ist aufwändig und teuer.

Einfacher kommen wir mit einer Kontaktkennlinie zum Ziel, die ein heuristisches Modell der Kontaktkraft ist.

Stückweise linearer Ansatz

Kennlinie (erster Ansatz)

Wir suchen also eine Funktion, die für h<0 einen positive Wert (Druck) zurückliefert und Null sonst. Als Kontaktkraft schreiben wir

$F=k\cdot \kappa (h)$

mit der Federkonstante k und der nichtlinearen Funktion κ(h).

κ(h) wählen wir zu:

$\kappa (h)=\left\{{\begin{array}{ll}\;\;\;0&{\text{ für }}h>0\\-h&{\text{ sonst}}\end{array}}\right.$

Maxima-Code

Zum Einbauen in Ihr Programm: der Quellcode zur Kennlinie.

/* contact characteristic */
kappa(h) := if h>0 then 0 else -h;
plot2d(kappa(h),[h,-1,1], [y,-0.1,1], [xlabel, "h/ε->"], [ylabel, "κ ->"])$

Ausrunden der Kennlinie

Stetig differenzierbarere Kennlinie
... hier für ε=0.5

Damit die Kennlinie stetig differenzierbar ist, brauchen wir ein "Ausrundungspolynom" um h=0 herum.

Für -ε < h < ε wählen wir ein Polynom 2.ten Graden und passen es stetig an die beiden Geradenstücke an.

Dann ist die nichtlineare Funktion κ(h,ε):

$\kappa (h)=\left\{{\begin{array}{ll}\;\;\;0&{\text{ für }}h>\varepsilon \\\displaystyle {\frac {{h}^{2}}{4\cdot \epsilon }}-{\frac {h}{2}}+{\frac {\epsilon }{4}}&{\text{ für }}\varepsilon >h>-\varepsilon \\-h&{\text{ sonst}}\end{array}}\right.$

Maxima-Code

Zum Einbauen in Ihr Programm: der Quellcode zur Kennlinie.

/* contact characteristic with smooth transition */
p(h) := sum(a[i]*h^i,i,0,2);
bc : [p(+epsilon)=0, subst([h=-epsilon],diff(p(h),h))=-1,subst([h=+epsilon],diff(p(h),h))=0];
coeff: solve(bc,[a[0],a[1],a[2]])[1];

kappa(h,epsilon) := if h>epsilon then 0 else if h<-epsilon then -h else epsilon/4-1/2*h+1/(4*epsilon)*h^2;
plot2d(kappa(h,0.25),[h,-1,1], [y,-0.1,1], [xlabel, "h/ε->"], [ylabel, "κ ->"])$

Kontaktkennlinie mit Verlustglied

Oft möchte man bei Kontaktkennlinen ein Verlustglied einbauen - also ein mathematisches Modell für einen Stoß, bei dem im Prozess der elastischen Deformation auch kinetische Energie verloren geht.

Kennlinie mit dynamischem Verlustglied. Schraffiert ist die Verlustarbeit beim einem Schwingungszyklus

Dafür multiplizieren wir den Ausdruck für die Kraft F oben mit dem Geschwindigkeitsabhängigen Verlustglied l(v), also

$N=l(v)\cdot F(h){\text{ mit }}v={\frac {\displaystyle dh}{\displaystyle dt}}$.

Für das Verlustglied kann man dann z.B. ansetzten

$l(v)=\left\{{\begin{array}{l}1\cdot \left(1-{\frac {\displaystyle v}{\displaystyle v_{ref}}}\right){\text{ für }}v<0{\text{ (eindringen)}}\\1/\left(1+{\frac {\displaystyle v}{\displaystyle v_{ref}}}\right){\text{ sonst. }}\end{array}}\right.$.

Maxima-Code

Zum Einbauen in Ihr Programm: der Quellcode zur Kennlinie.

/* Maxima                            */
/* contact characteristic            */
/* piecewise linear with energy loss */

n(h,H) := if h<0 then -h/H else 0;
l(v,V) := if v<0 then 1*(1-v/V) else 1/(1+v/V);

motion: h=cos(2*%pi*τ);
motion: [motion, v=diff(subst(motion,h),τ)];
plot2d(subst(motion,n(h,1)*l(v,1)),[τ,0,1], [ylabel,"N/F[0] ->"], [xlabel,"t/T ->"])$

plot2d([parametric,subst(motion,h),subst(motion,n(h,1)*l(v,1)),[τ,0,1]], [ylabel,"N/F[0] →"], [xlabel,"h/H →"], [x,-1.1,0.1])$

---

Links:

• Kw23, Kv52