Gelöste Aufgaben/UEBJ

Aufgabenstellung

Der Euler-Bernoulli-Balken AB wird durch seine Gewichtskraft belastet. Er ist in A fest eingespannt und hat eine konstante Breite b sowie eine zwischen A und B linear veränderliche Höhe h.

Für diese Aufgabe gibt es in UEBI eine analytische Lösung - hier schauen wir uns an, wie sich die Qualität der Näherungslösungen mit der Steigerung der Anzahl der Trial-Functions ändert.

Lageplan

Gesucht ist die Biegeline und Schnittkraftverläufe mit dem Ansatz von Ritz und mehreren Trial-Funktionen.

Gegeben sind für den Balken:

• Länge ℓ, Breite b,
• E-Modul E, Dichte ρ und
• die Höhe h₀=b und h₁ jeweils in A und B; dazwischen ist die Höhe linear veränderlich.

Lösung mit Maxima

Beim Verfahren von Ritz arbeiten wir mit

• dem Prinzip vom Minimum der Potentiellen Energie und
• Ansatzfunktionen über die gesamte Länge des Balkens.

Um die Lösung dimensionslos zu machen, nutzen wir die analytische Lösung des einseitig fest eingespannten Balkens  mit konstanten I unter einer konstanten Streckenlast q₀. Hier ist die maximale Auslenkung

${\begin{array}{lcl}\displaystyle {\hat {w}}:={\frac {q_{ref}\,\ell ^{4}}{8EI_{ref}}}&{\text{ mit }}&q_{ref}=A_{ref}\,\rho \,g\\&&A_{ref}=h_{ref}\cdot b{\text{ und}}\\&&h_{ref}=\displaystyle {\frac {h_{0}+h_{1}}{2}}\end{array}}$.

Damit können wir uns die Lösungen dieses Problems als Vielfaches der analytischen Lösung eines ähnlichen Problems denken.

Header

In diesem Problem werden wir Lösungen zu verschiedenen Ansatzfunktionen miteinander vergleichen.

Es geht also nicht nur um die Berechnung einer Lösung - sondern vieler. Damit können wir uns die Lösungen dieses Problems als Vielfaches der analytischen Lösung eines ähnlichen Problems denken.

/*******************************************************/
/* MAXIMA script                                       */
/* version: wxMaxima 15.08.2                           */
/* author: Andreas Baumgart                            */
/* last updated: 2019-08-30                            */
/* ref: TMC                                            */
/* description: Rayley-Ritz-Solution for EBB           */
/*              with I(x)                              */
/*******************************************************/

Declarations

Wir arbeiten mit den System-Parametern

${\begin{array}{lcl}\xi &=&\displaystyle {\frac {x}{\ell }},\\q(\xi )&=&A(\xi )\,\rho \,g,\\A(\xi )&=&b\,h(\xi ),\\I(\xi )&=&\displaystyle {\frac {b\cdot h^{3}(\xi )}{12}},\\h(\xi )&=&h_{0}\cdot (1-\xi )+h_{1}\cdot \xi {\text{ und}}\\h_{1}&=&\alpha \,h_{0}.\end{array}}$

Für die numerische Lösung verwenden wir - wie in UEBI -

$\alpha =\displaystyle {\frac {1}{2}}$.

/************************************************************/
/* declare variational variables - see 6.3 Identifiers      */
declare( "ℓ", alphabetic);

/* system parameters                                        */
params: [q(xi) = A(xi)*rho*g,
         A(xi) = b*h(xi),
         I(xi) = b*h(xi)^3/12,
         h(xi) = H[0]*(1-xi)+ H[1]*xi];
params: append(params,
               solve((H[0]+H[1])/2*b*ℓ*rho=m, rho));

geometry : [alpha=1/2];

dimless: [x = xi*ℓ, H[0]=b, H[1]=alpha*b];

/* load analytic solutions as discrete tables from UEBI */
file_search_maxima: append(file_search_maxima, ["C:/Users/abs384/OneDrive/Confluence Sources/UEBJ/"]);
batch("analyticSolFromUEBI.data")$

/* make equations of motion dim'less with load case #1 from Gross e.a., same as UEBI */
reference : [W[ref] = q[ref]*ℓ^4/8/EI[ref], Phi[ref] = q[ref]*ℓ^3/6/EI[ref], M[ref] = m*g*ℓ/2, Q[ref] = m*g, q[ref] = m*g/ℓ, EI[ref]=E*b*((H[0]+H[1])/2)^3/12];

Rayleigh-Ritz Approach

Gesucht ist hier ein Ansatz mit polynomialen Trial Functions. Wir probieren verschiedene Ansätze aus, die wir mit "i" kennzeichnen, also

$w_{i}(\xi )={\hat {w}}\cdot \displaystyle \sum _{j_{min}}^{J}W_{i,j}\cdot \phi _{j}(\xi )$

und den gesuchten Koeffizienten W_ij. Die ϕ_j müssen dabei alle geometrischen Randbedingungen erfüllen, also:

${\begin{array}{ll}w_{i}(0)&=0,\\w_{i}'(0)&=0.\end{array}}$.

Die Funktionen müssen nicht die Randbedingungen für Schnittlasten in B erfüllen - schließlich suchen wir nach einer Näherungslösung!

Diese Funktionen ϕ_j zu konstruieren ist einfach: wir brauchen lediglich eine doppelte Nullstelle in $\xi =0$. Das erreichen wir, indem wir nur Polynome ab einem Grad ≥ 2 (also j_min=2) zulassen:

$\phi _{j}(\xi )=\xi ^{j}{\text{ mit }}j\geq 2$.

Damit ist

$w_{i}(\xi )={\hat {w}}\cdot \displaystyle \sum _{2}^{J}W_{i,j}\cdot \xi ^{j}$.

Die freien Koeffizienten W_ij sind nun die anteiligen Auslenkungen in B.

---

Für die Gleichgewichtsbedingungen setzten wir die Formänderungsenergie Π (aus dem Abschnitt Euler-Bernoulli-Balken)

$\displaystyle \Pi ={\frac {1}{2}}\int _{0}^{\ell }M(x)\,w''(x)dx$

und die Arbeitsfunktion der Gewichtskraft A

$\displaystyle {\bf {A}}=\int _{0}^{\ell }q(x)\,w(x)dx$

in U ein und schreiben die skalare Gleichung allgemein in Matrizenform an. Dabei müssen wir

$\displaystyle {\frac {d\phi }{x}}={\frac {d\phi }{\xi }}\cdot \underbrace {\displaystyle {\frac {d\xi }{x}}} _{\displaystyle ={\frac {1}{\ell }}}$

berücksichtigen und erhalten

${\bf {U}}=\displaystyle {\frac {1}{2}}\cdot \displaystyle {\underline {Q}}^{T}\cdot {\underline {\underline {A}}}\cdot {\underline {Q}}-{\underline {Q}}^{T}\cdot {\underline {b}}$.

In der Spaltenmatrix

${\underline {Q}}=\left({\begin{array}{l}W_{i,2}\\\vdots \\W_{i,I}\end{array}}\right)$

stehen nun zwischen einer und I-1 Gewichtungsfaktoren W_ij : die gesuchten Unbekannten.

Die Gleichgewichtsbedingungen

$\displaystyle {\frac {d{\bf {U}}}{dW_{ij}}}{\stackrel {!}{=}}0$,

liefern uns die benötigte Anzahl von Gleichungen, z.B. für i=3:

${\begin{array}{cl}0=&{{W}_{3,3}}\cdot \left(36+72\cdot \alpha +108\cdot {{\alpha }^{2}}+144\cdot {{\alpha }^{3}}\right)+{{W}_{3,2}}\cdot \left(60+60\cdot \alpha +60\cdot {{\alpha }^{2}}+60\cdot {{\alpha }^{3}}\right)-30\cdot {{\alpha }^{3}}-70\cdot {{\alpha }^{2}}-50\cdot \alpha -10\\0=&{{W}_{3,3}}\cdot \left(36+108\cdot \alpha +216\cdot {{\alpha }^{2}}+360\cdot {{\alpha }^{3}}\right)+{{W}_{3,2}}\cdot \left(36+72\cdot \alpha +108\cdot {{\alpha }^{2}}+144\cdot {{\alpha }^{3}}\right)-24\cdot {{\alpha }^{3}}-54\cdot {{\alpha }^{2}}-36\cdot \alpha -6\end{array}}$.

Hier - für i=3 - ist

${\begin{array}{ll}{{W}_{3,2}}&=\displaystyle {\frac {1+8\cdot \alpha +34\cdot {{\alpha }^{2}}+94\cdot {{\alpha }^{3}}+164\cdot {{\alpha }^{4}}+148\cdot {{\alpha }^{5}}+51\cdot {{\alpha }^{6}}}{6\cdot {{\alpha }^{6}}+24\cdot {{\alpha }^{5}}+60\cdot {{\alpha }^{4}}+120\cdot {{\alpha }^{3}}+60\cdot {{\alpha }^{2}}+24\cdot \alpha +6}}\\{{W}_{3,3}}&=\displaystyle -{\frac {5\cdot {{\alpha }^{2}}+20\cdot {{\alpha }^{3}}+35\cdot {{\alpha }^{4}}+30\cdot {{\alpha }^{5}}+10\cdot {{\alpha }^{6}}}{3\cdot {{\alpha }^{6}}+12\cdot {{\alpha }^{5}}+30\cdot {{\alpha }^{4}}+60\cdot {{\alpha }^{3}}+30\cdot {{\alpha }^{2}}+12\cdot \alpha +3}}\end{array}}$.

/************************************************************/
/* Rayleigh-Ritz                                            */
/* try different degrees of polyomials                      */
fcts: [];
sols: [];
polyMax : 4;
for poly:2 thru polyMax do (
   /* trial function */
   trial: w[poly](xi) = sum(W[ref]*W[poly,j]*xi^(j),j,2,poly),
   /* potential energies */
   /* define potential energy of system */
   PMPE : [U  = Pi - A,
          Pi = 1/2*ℓ*'integrate(E*I(xi)*'diff(w[i](xi),xi,2)^2/ℓ^4,xi,0,1),
          A  = ℓ*'integrate(q(xi)*w[i](xi),xi,0,1)],
   PMPE: subst(dimless,subst(params,subst(trial,subst([i=poly],PMPE)))),
   PMPE: subst(PMPE[3],subst(PMPE[2], PMPE[1])),
   PMPE : ev(PMPE,nouns),
   /* equilibreium condition */
   X : makelist(W[poly,j],j,2,poly),
   equilibrium : ratsimp(subst(dimless,subst(reference,
                     makelist(diff(subst(PMPE, U),W[poly,j]) = 0,j,2,poly)))),
   /* solve */
   sol: ratsimp(solve(equilibrium,X)),
   sols: append(sols, sol),
   /* post-processing */
   fcts: append(fcts, [ratsimp(subst(geometry,subst(sol,subst(trial,w[poly](xi)/W[ref]))))]),
   print("done: #",poly))$

Post-Processing

Für die verschiedenen Ansätze (Polynimial-Grade der Trial-Functions) erhaltem wir Lösungen, die die analytische Lösung aus UEBI unterschiedlich gut approximieren. Hier wählen wir als Ansätze die Polynome bis zum Grad 2, 3 und 4.

Parameterstudie: Biegelinie w(x)

Und so berechnen wir die normierten Absenkungen des Balkens für die verschiedenen Ansätze: Für Moment- und Querkraftverläufe erhalten wir

Parameterstudie Biegemomentenverlauf M(x)

Parameterstudie Querkraftverlauf Q(x)

/************************************************************/
/* post - processing                                        */

/* cross-sectional bending moment */
M : subst(geometry,ratsimp(subst(dimless,subst(reference,subst(params,-E*I(xi)*W[ref]*diff(fcts,xi,2)/ℓ^2/(m*g*ℓ/2))))))$
/* cross-sectional shear force */
Q : subst(geometry,ratsimp(subst(dimless,subst(reference,subst(params,-E*I(xi)*W[ref]*diff(fcts,xi,3)/ℓ^3/(m*g))))))$

fcts :append([[discrete, WA]], fcts)$
plot2d(fcts,[xi,0,1],
       [gnuplot_preamble, "set yrange [] reverse"],
       [legend, "analytic", "2nd Ord", "3rd Ord", "4th Ord", "5th Ord", "6th Ord"],
       [xlabel, "x/ℓ->"], [ylabel, "<-w/w_ref"],
       [style, [lines,2], [lines,1], [lines,1], [lines,1], [lines,1], [lines,1]]);
     
M :append([[discrete, MA]], M)$
plot2d(M,[xi,0,1],
       [legend, "analytic", "p02","p03","p04","p05","p06","p07","p08","p09","p10","p11","p12"],
       [xlabel, "x/ℓ->"], [ylabel, "M/(mg ℓ->"],
       [style, [lines,2], [lines,1], [lines,1], [lines,1], [lines,1], [lines,1]]);

Q :append([[discrete, QA]], Q)$
plot2d(Q,[xi,0,1],
       [legend, "analytic", "p02","p03","p04","p05","p06","p07","p08","p09","p10","p11","p12"],
       [xlabel, "x/ℓ->"], [ylabel, "Q/mg->"],
       [style, [lines,2], [lines,1], [lines,1], [lines,1], [lines,1], [lines,1]]);

---

Links

• UEBI

Literature

• ...