Quelltext der Seite Sources/Lexikon/Spannungs-Dehnungs-Beziehung (Stress-Strain-Relation)


<!-------------------------------------------------------------------------------->
{{MyCodeBlock|title=Allgemeines Werkstoffgesetzt (3D)
|text=
Der Zusammenhang zwischen Dehnung un Spannung für isotropes, linear-elastisches Werkstoffverhalten wird durch

::<math>\underline{\sigma} = \underline{\underline{E}}\cdot \underline{\varepsilon}</math>

beschrieben. In Komponenten-Schreibweise ist dies

::<math>\displaystyle {\begin{bmatrix}\sigma _{xx}\\\sigma _{yy}\\\sigma _{zz}\\\sigma _{yz}\\\sigma _{xz}\\\sigma _{xy}\end{bmatrix}}\,=\,{\begin{bmatrix}2\mu +\lambda &\lambda &\lambda &0&0&0\\\lambda &2\mu +\lambda &\lambda &0&0&0\\\lambda &\lambda &2\mu +\lambda &0&0&0\\0&0&0&2\mu &0&0\\0&0&0&0&2\mu &0\\0&0&0&0&0&2\mu \end{bmatrix}}{\begin{bmatrix}\varepsilon _{xx}\\\varepsilon _{yy}\\\varepsilon _{zz}\\\varepsilon _{yz}\\\varepsilon _{xz}\\\varepsilon _{xy}\end{bmatrix}}</math>,

wobei ''λ'' und ''μ'' die Lamé'schen Konstanten sind und zum Elastizitäts-Modul ''E'' und der Querkontraktion ''ν'' folgende Beziehung haben:

::<math>\begin{array}{l}\displaystyle \lambda=\frac {E\nu }{(1+\nu )(1-2\nu )}\\\displaystyle \mu = \frac {E }{2(1+\nu )}\end{array}</math>
|code=
<syntaxhighlight lang="lisp" line start=1>
/* Maxima */
/* version 5.38.1 */
/* general strain-displacement relation (sdr)*/
declare("σ", alphabetic);
declare("ε", alphabetic);

params: [%lambda=E*nu/((1+nu)*(1-2*nu)), mu=E/(2*(1+nu))];

sdr[3]: E = 2*mu*diagmatrix (6, 1) + 
            %lambda*matrix([1,1,1,0,0,0],
                           [1,1,1,0,0,0],
                           [1,1,1,0,0,0],
                           [0,0,0,0,0,0],
                           [0,0,0,0,0,0],
                           [0,0,0,0,0,0]);

σ : matrix([  sigma[xx]],[  sigma[yy]],[  sigma[zz]],[  sigma[yz]],[  sigma[xz]],[  sigma[xy]]);
ε : matrix([epsilon[xx]],[epsilon[yy]],[epsilon[zz]],[epsilon[yz]],[epsilon[xz]],[epsilon[xy]]);
print(σ," = ", subst(sdr[3],E),"∙",ε)$
</syntaxhighlight>
}}



<!-------------------------------------------------------------------------------->
{{MyCodeBlock|title=Ebener Spannugnszustand
|text=
Alle anderen Werkstoff-Gesetze lassen sich daraus ableiten, z.B. für den ebenen Spannungszustand mit 

::<math>\sigma_{zz}=0, \sigma_{xz}=0, \sigma_{yz}=0</math>

erhalten wir

::<math>\displaystyle {{\sigma}_{\mathit{xx}}}=\frac{2\lambda\mu{{\epsilon}_{\mathit{yy}}}+\left( 4{{\mu}^{2}}+4\lambda\mu\right) \,{{\epsilon}_{\mathit{xx}}}}{2\mu+\lambda},{{\sigma}_{\mathit{yy}}}=\frac{\left( 4{{\mu}^{2}}+4\lambda\mu\right) \,{{\epsilon}_{\mathit{yy}}}+2\lambda\mu{{\epsilon}_{\mathit{xx}}}}{2\mu+\lambda},{{\sigma}_{\mathit{xy}}}=2\mu{{\epsilon}_{\mathit{xy}}},{{\epsilon}_{\mathit{zz}}}=-\frac{\lambda{{\epsilon}_{\mathit{yy}}}+\lambda{{\epsilon}_{\mathit{xx}}}}{2\mu+\lambda},{{\epsilon}_{\mathit{yz}}}=0,{{\epsilon}_{\mathit{xz}}}=0</math>

In Matrixschreibweise erhalten wir

::<math>\left(\begin{array}{c}\sigma_{xx}\\ \sigma_{yy}\\ \sigma_{xy} \end{array}\right) =  \left(\begin{array}{ccc} \frac{4{{\mu}^{2}}+4\lambda\mu}{2\mu+\lambda} & \frac{2\lambda\mu}{2\mu+\lambda}& 0\\ \frac{2\lambda\mu}{2\mu+\lambda}&\frac{4{{\mu}^{2}}+4\lambda\mu}{2\mu+\lambda}&0\\ 0 & 0 & 2 \mu  \end{array}\right) \cdot  \left(\begin{array}{c}\varepsilon_{xx}\\ \varepsilon_{yy}\\ \varepsilon_{xy} \end{array}\right) </math>

bzw mit ''E'' und ''ν''

::<math>\left(\begin{array}{c}\sigma_{xx}\\ \sigma_{yy}\\ \sigma_{xy} \end{array}\right) =  \left(\begin{array}{ccc} \frac{E}{1-{{\nu}^{2}}} & \frac{E\;\nu}{1-{{\nu}^{2}}} & 0\\ \frac{E\;\nu}{1-{{\nu}^{2}}} & \frac{E}{1-{{\nu}^{2}}} & 0\\ 0 & 0 & \frac{E}{\nu+1}  \end{array}\right) \cdot  \left(\begin{array}{c}\varepsilon_{xx}\\ \varepsilon_{yy}\\ \varepsilon_{xy} \end{array}\right) </math>.
|code=
<syntaxhighlight lang="lisp" line start=1>
/* Maxima */
/* version 5.38.1 */
/*ebener Spannungszustand*/
assumption: [sigma[zz]=0, sigma[yz]=0, sigma[xz]=0];
/* general strain-displacement relation (sdr)*/

equs: subst(assumption,makelist(σ[i][1] = (subst(sdr[3],E).ε)[i][1],i,1,6));
Q: [  sigma[xx],  sigma[yy],  sigma[xy],
    epsilon[zz],epsilon[yz],epsilon[xz]];

sol: ratsimp(solve(equs,Q))[1];

ACM: augcoefmatrix([-sol[1],-sol[2],-sol[3]],[epsilon[xx],epsilon[yy],epsilon[xy]]);
sdr[2] : submatrix(ACM,4);

sdr[2]: [sdr[2],ratsimp(subst(params,sdr[2]))];
</syntaxhighlight>
}}



<!-------------------------------------------------------------------------------->
{{MyCodeBlock|title=Eindimensionaler Spannungszustand
|text=
Ganz entsprechend erhalten wir für

::<math>\sigma_{yy}=0, \sigma_{zz}=0, \sigma_{xz}=0, \sigma_{yz}=0, \sigma_{xy}=0</math>

die Ergebnisse

::<math>\displaystyle {{\sigma}_{\mathit{xx}}}=\frac{\left( 2{{\mu}^{2}}+3\lambda\mu\right) \,{{\epsilon}_{\mathit{xx}}}}{\mu+\lambda},{{\epsilon}_{\mathit{yy}}}=-\frac{\lambda{{\epsilon}_{\mathit{xx}}}}{2\mu+2\lambda},{{\epsilon}_{\mathit{zz}}}=-\frac{\lambda{{\epsilon}_{\mathit{xx}}}}{2\mu+2\lambda},{{\epsilon}_{\mathit{yz}}}=0,{{\epsilon}_{\mathit{xz}}}=0,{{\epsilon}_{\mathit{xy}}}=0</math>

bzw.

::<math>\displaystyle {{\sigma}_{\mathit{xx}}}=E\,{{\epsilon}_{\mathit{xx}}},{{\epsilon}_{\mathit{yy}}}=-\nu{{\epsilon}_{\mathit{xx}}},{{\epsilon}_{\mathit{zz}}}=-\nu{{\epsilon}_{\mathit{xx}}},{{\epsilon}_{\mathit{yz}}}=0,{{\epsilon}_{\mathit{xz}}}=0,{{\epsilon}_{\mathit{xy}}}=0</math>
|code=
<syntaxhighlight lang="lisp" line start=1>
/* Maxima */
/* version 5.38.1 */
/*eindimensionaler Spannungszustand*/
assumption: [sigma[yy]=0, sigma[zz]=0, sigma[yz]=0, sigma[xz]=0, sigma[xy]=0];
/* general strain-displacement relation (sdr)*/

equs: subst(assumption,makelist(σ[i][1] = (subst(sdr[3],E).ε)[i][1],i,1,6));
Q: [  sigma[xx],
    epsilon[yy], epsilon[zz],epsilon[yz],epsilon[xz], epsilon[xy]];

sol: ratsimp(solve(equs,Q))[1];
</syntaxhighlight>
}}